[m0nkrus]

Ксеноинженер, вы пробовали проверять свою конструкцию в деле? У меня совмещение двух строк без промежуточного помещения результатов в файл disks.txt:

Код:

ECHO LIST DISK | DISKPART | FINDSTR /r /c:"\*$" > disks.txt
FOR /f "tokens=2" %%i IN (disks.txt) DO ECHO select disk %%i >> diskpart.txt && ECHO detail disk >> diskpart.txt

...в аналог вашего кода:

Код:

for /f "tokens=2" %%I IN ('Echo List Disk ^| Diskpart ^| Findstr /e "Boot Загрузоч"') do echo Select Disk ^%%I > diskpart.txt && echo uniqueid disk >> diskpart.txt

...не проходило - ругается то на команду echo, то на знак |. При помощи ^ вы экранировали символы |, но остаются ли последние после этого работоспособными? Кстати, при применениии конструкции "echo Select Disk ^%%I > diskpart.txt" вы получите перезапись старых значений новыми, а не накопление оных. Это не говоря уже о том, что искать подстроки "Boot Загрузоч" в результатах срабатывания команды List Disk бесполезно - их там нет.

Поиск "{" через команду uniqueid disk действительно может помочь в определении GPT-раздела. Только тут надо каждый раздел подключать и проверять поочередно, а я с помощью команды List Disk нахожу их все одним махом. Да и ничуть uniqueid disk не поможет в определении, есть ли среди GPT-дисков загрузочный, для чего я и использую detail disk.

Если честно, в вашем скрипте столько ошибок и логических нестыковок, что он в таком виде не заработает совершенно точно. Это я могу сказать даже без тестирования.

[Ксеноинженер]

m0nkrus, Вы были корректны. Моё недоразумение в данном случае.
Возвращаюсь к Вашему, правильному, скрипту.
Обойтись одним внешним файлом всё же можно (проверил, работает на GPT и MBR)
каретки "^" обеспечивают целостность строки echo, не разрывая цикл символами "|".

Код:

CD /d %~dp0
for /f "tokens=2" %%I IN ('echo List Disk ^| Diskpart ^| Findstr /r /c:"\*$"') do echo Select Disk %%I >> diskpart.txt && echo detail disk >> diskpart.txt
Diskpart /s diskpart.txt | findstr /e "Boot Загрузоч"
IF ERRORLEVEL 1 (
	ECHO Загрузочный том размещен на MBR-разделе
	) ELSE (
	ECHO Загрузочный том размещен на GPT-разделе
	)
)
del /q diskpart.txt
pause

остаются ли последние после этого работоспособными?

да, остаются, это как с двойным %% для переменной работает

перезапись старых значений новыми

Не подумал о нескольких gpt дисках в системе, был не прав

он в таком виде не заработает совершенно точно.

Что ж, с этим я смирюсь как-нибудь. Важно другое, мастер лучших в рунете сборок Windows Vista/7/8 - это Вы, уважаемый m0nkrus. Дело мастера боится.
Одно пока мне неясно, как скрыть сообщение о найденном GPT диске. @echo off почему-то не сработал?

[Iska]

Нагляднее (не проверялось):

Код:

for /f "tokens=2" %%I IN ('echo List Disk ^| Diskpart ^| Findstr /r /c:"\*$"') do (
    > diskpart.txt (echo Select Disk %%I
    echo detail disk)
)

Также можно использовать такую методику работы с diskpart.exe:

Код:

(echo select disk 0 & echo list volume) | diskpart.exe

т.е. (также не проверялось) наподобие:

Код:

for /f "tokens=2" %%I IN ('echo List Disk ^| Diskpart ^| Findstr /r /c:"\*$"') do (
	(echo Select Disk %%I
	echo detail disk) | diskpart.exe | findstr.exe /e "Boot Загрузоч"
	IF ERRORLEVEL 1 (
		ECHO Загрузочный том размещен на MBR-разделе
	) ELSE (
		ECHO Загрузочный том размещен на GPT-разделе
	)
)

[m0nkrus]

да, остаются, это как с двойным %% для переменной работает »

Это действительно полезная оптимизация.

Одно пока мне неясно, как скрыть сообщение о найденном GPT диске. @echo off почему-то не сработал? »

Это-то как раз просто. В конце команды добавить "> nul". Но в моем конкретном случае это несущественно.

Iska
Спасибо, посмотрю ваши наработки. Потестирую. Оптимально, конечно, совсем отказаться от внешних файлов.

[m0nkrus]

Iska, первая конструкция рабочая, за исключением маленького нюанса. Она у вас тоже предусматривает наличие только одного GPT раздела. Надо так:

Код:

for /f "tokens=2" %%I IN ('echo List Disk ^| Diskpart ^| Findstr /r /c:"\*$"') do (
    >> diskpart.txt (echo Select Disk %%I
    echo detail disk)
)

Вторая конструкция тоже рабочая. Команды вы правда подобрали бессистемно. Команде, начинающейся с list без разницы, какой диск выбран. Но сама идея конструкта интересна.

Третий код снова не учитывает наличия нескольких GPT-разделов. Если их два и система размещена на первом, то на выходе скрипта мы получим, что система у нас, якобы на MBR.

[Iska]

Она у вас тоже предусматривает наличие только одного GPT раздела. »

m0nkrus, у меня и одного-то нет . Я потому и писал — «не проверялось». Я просто брал код из чужого поста и на его основе «лопатил». «Отлопаченное» выделял цветом.

Команды вы правда подобрали бессистемно. Команде, начинающейся с list без разницы, какой диск выбран. »

Второй пример — просто иллюстрация возможности передачи двух (и более) строк по конвейеру на вход «diskpart.exe».

Ежели сделаете на «отлопаченном» проверенный рабочий вариант — поместите его в тему.

[m0nkrus]

m0nkrus, у меня и одного-то нет . Я потому и писал — «не проверялось» »

Дык, у меня тоже нет. Для проверки я просто меняю код "\*$" на "\ $" и в качестве подопытных выступают MBR-разделы.

Ежели сделаете на «отлопаченном» проверенный рабочий вариант — поместите его в тему. »

Пока, на мой взгляд, оптимальный рабочий вариант, это тот, что на основе моего сделал Ксеноинженер.

[m0nkrus]

Iska, хотя можно тоже кое-что и из ваших наработок позаимствовать, немного оптимизировав:

Код:

@ECHO OFF
CD /d %~dp0
FOR /f "tokens=2" %%i IN ('ECHO LIST DISK ^| DISKPART ^| FINDSTR /r /c:"\*$"') DO (>> diskpart.txt (ECHO select disk %%i && ECHO detail disk))
DISKPART /s "diskpart.txt" | FINDSTR /e "Boot Загрузоч" > nul
IF ERRORLEVEL 1 (
    ECHO Загрузочный том размещен на MBR-разделе
) ELSE (
    ECHO Загрузочный том размещен на GPT-разделе
)
PAUSE

Только не знаю, можно ли считать замену конструкции:

Код:

ECHO select disk %%i >> diskpart.txt && ECHO detail disk >> diskpart.txt

... на эту:

Код:

(>> diskpart.txt (ECHO select disk %%i && ECHO detail disk))

...оптимизацией. Если бы команд на каждом витке цикла было больше, то да, это бы подсократило код, но всего с двумя элементами особой разницы нет.

[Iska]

можно ли считать »

m0nkrus, если рассуждать теоретически,

читать дальше »

при большом количестве «echo» — можно: насколько я понимаю (замерял, но не проверял, например, в отладчике), при группировке вывода:

Код:

> Out.txt ( echo …
echo …
…
echo …)

открытие/закрытие файла происходит один раз в отличие от типичного:

Код:

echo …> Out.txt
echo …>> Out.txt
…
echo …>> Out.txt

Иллюстрация…

0001.cmd

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

echo %time%

>"%~n0.txt" (
	for /l %%i in (1, 1, 10000) do (
		echo %%i
	)
)

echo %time%

endlocal
exit /b 0

0002.cmd

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

echo %time%

for /l %%i in (1, 1, 10000) do (
	>>"%~n0.txt" echo %%i
)

echo %time%

endlocal
exit /b 0

Результат:

Код:

E:\Песочница\0244>0001.cmd
14:10:02.20
14:10:02.56

E:\Песочница\0244>0002.cmd
14:10:05.06
14:10:14.06

[m0nkrus]

Iska, согласен. Но, как я уже говорил, это становится сколько-нибудь критичным при много большем количестве вносимых строк.