[amel27]

- ключ /Y работает только для файлов, а не для папок;
- в каталоге батника не должно быть папки "Material3", иначе DIR просто выдаст её содержимое;

вариант через XCOPY и RD:

Код:

if not exist Material3 for /f "delims=" %%a in ('dir /b/s/ad Material3') do (
  xcopy /q/s/y/h/r "%%a\*" "%%~dpb..\..\Material3\" && rd /q/s "%%a"
)

[Tosyk]

дело в том, что общий объём файлов может составлять до 50 гб, поэтому и хотел использовать именно move, так как нет возможности копировать такое количество мегабайт

add:
ваш вариант работает

add2:
а как работает скрипт?

Код:

находит папку -> копирует в нужное место -> удаляет оригинал

так?
либо

Код:

находит папку -> копирует в нужное место -> находит папку -> копирует в нужное место -> ...находит и копирует все папки... -> удаляет оригиналы

так?

если первый вариант, то это вполне нормально (на диске единовременно не будет очень много скопированной информации)

[amel27]

как работает скрипт? »

в цикле перебираются все папки, которые поочередно копируются и сразу удаляются

хотел использовать именно move »

тогда только пофайлово:

Код:

@echo off
SETLOCAL EnableDelayedExpansion

for /f "delims=" %%d in ('dir /b/s/ad "Material3.*"') do if "%%~xd"=="" (
  for /f "delims=" %%f in ('dir /b/s/a-d "%%d"') do (
    set "$d=%%~dpf"& set "$d=!$d:%%~dpd=%%~dpd..\..\!"
    if not exist "!$d!" md "!$d!"
    if exist "!$d!" move "%%f" "!$d!"
))

- исходные папки после перемещения файлов не удаляются;
- операция одноразовая, скрипт поднимает на два уровня каждую папку Material3, 2-й запуск поднимет также и целевую папку, т.к. у них одинаковые имена

[Tosyk]

Большое спасибо, всё работает!

[Tosyk]

появилась проблема, иногда файлы в папках Material3 имеют одинаковое имя, но разный размер (т.е по сути это другие файлы), как сделать так чтобы перед заменой файлов проводилась проверка размера, и если файл *.mat в папке имеет то же имя, но другой размер то к имени нового файла добалялось бы "01,02,03...и.т.д"

[amel27]

Tosyk, как-то так:

Код:

@echo off
SETLOCAL EnableDelayedExpansion

for /f "delims=" %%d in ('dir/b/s/ad "Material3.*"') do if "%%~xd"=="" (
  for /f "delims=" %%f in ('dir/b/s/a-d "%%d"') do (
    set "$d=%%~dpf"& set "$d=!$d:%%~dpd=%%~dpd..\..\!"
    call:MoveRen "%%f" "!$d!"
))

:MoveRen  %source_file% %destin_folder%
::-------------------------------------
 set "$s="& set "$n="& if "%~1"=="" GoTo:EOF
 if not exist "%~2" md "%~2"||exit/b 1
:MoveRen_Loop
 if not exist "%~2%~n1%$s%%~x1" move "%~1" "%~2%~n1%$s%%~x1"& GoTo:EOF
 fc/b "%~1" "%~2%~n1%$s%%~x1">nul&&(del/f/q "%~1"& GoTo:EOF)
 set/a "$n+=1"& set "$s=0!$n!"& set "$s=_!$s:~-2!"
GoTo:MoveRen_Loop

[Tosyk]

проверил, работает, проверяет, изменяет имя, по крайней мере первого уровня (_01.mat)

а как добавить ещё одну (или несколько) папку в обработку помимо Material3, пытаюсь сделать:

Код:

@echo off
SETLOCAL EnableDelayedExpansion

for /f "delims=" %%d in ('dir/b/s/ad "Material3.*"') do if "%%~xd"=="" (
  for /f "delims=" %%f in ('dir/b/s/a-d "%%d"') do (
    set "$d=%%~dpf"& set "$d=!$d:%%~dpd=%%~dpd..\..\!"
    call:MoveRen "%%f" "!$d!"
))

:MoveRen  %source_file% %destin_folder%
::-------------------------------------
 set "$s="& set "$n="& if "%~1"=="" GoTo:EOF
 if not exist "%~2" md "%~2"||exit/b 1
:MoveRen_Loop
 if not exist "%~2%~n1%$s%%~x1" move "%~1" "%~2%~n1%$s%%~x1"& GoTo:EOF
 fc/b "%~1" "%~2%~n1%$s%%~x1">nul&&(del/f/q "%~1"& GoTo:EOF)
 set/a "$n+=1"& set "$s=0!$n!"& set "$s=_!$s:~-2!"
GoTo:MoveRen_Loop


for /f "delims=" %%d in ('dir/b/s/ad "MaterialConst.*"') do if "%%~xd"=="" (
  for /f "delims=" %%f in ('dir/b/s/a-d "%%d"') do (
    set "$d=%%~dpf"& set "$d=!$d:%%~dpd=%%~dpd..\..\!"
    call:MoveRen "%%f" "!$d!"
))

:MoveRen  %source_file% %destin_folder%
::-------------------------------------
 set "$s="& set "$n="& if "%~1"=="" GoTo:EOF
 if not exist "%~2" md "%~2"||exit/b 1
:MoveRen_Loop
 if not exist "%~2%~n1%$s%%~x1" move "%~1" "%~2%~n1%$s%%~x1"& GoTo:EOF
 fc/b "%~1" "%~2%~n1%$s%%~x1">nul&&(del/f/q "%~1"& GoTo:EOF)
 set/a "$n+=1"& set "$s=0!$n!"& set "$s=_!$s:~-2!"
GoTo:MoveRen_Loop

но получается только Material3, остальные скрипт не трогает.

[forsem]

попробуйте программу robocopy . это типа xcopy и просто copy , так же она от Microsoft и имеет КУЧУ пользных и гибких ключей , для копирование и т.п.

[Tosyk]

попробуйте программу robocopy . это типа xcopy и просто copy , так же она от Microsoft и имеет КУЧУ пользных и гибких ключей , для копирование и т.п. »

спасибо, я посмотрел, но с cmd я уже хотя бы более менее разбираюсь, а robocopy для меня сложновато, не нашёл там нужных функция даже