[Starter1]

Кстати если не получается, то можно эти три символа перенести и в первую строку на первое место то есть перед самим текстом. Без разницы, главное чтобы работало.

[Starter1]

@echo off
setlocal enabledelayedexpansion
Set infile=1.txt
Set find=###
Set replace=Автор Петрович.
@echo off
setlocal enabledelayedexpansion
set COUNT=0
for /F "tokens=* delims=," %%n in (!infile!) do (
set LINE=%%n
set TMPR=!LINE:%find%=%replace%!
Echo !TMPR!>>TMP.TXT
)
move TMP.TXT %infile%le%

[xGETSx]

У меня похожая ситуация, но не такая. Нужно заменить одну строчку на три. Как это сделать?

заменить

Код:

package_extract_dir("boot", "/boot");

на

Код:

assert(package_extract_file("boot.img", "/tmp/boot.img"),
       write_raw_image("/tmp/boot.img", "boot"),
       delete("/tmp/boot.img"));

Можно это как-нибудь реализовать?

[ferget]

У меня похожая ситуация, но не такая. »

насколько не такая? может проще notapad++ использовать

[xGETSx]

может и проще, но нужно так. Я ж не себе пишу, а в программу вставляю.

Не обязательно это делать средствами bat, можно и программу из-под него запустить.

[Iska]

xGETSx, например так (не проверялось):

читать дальше »

Код:

Option Explicit

' IOMode Enum
Const ForReading   = 1
Const ForWriting   = 2
Const ForAppending = 8


Dim strFileName
Dim strContent

Dim strFind
Dim strReplace


strFileName = WScript.Arguments.Item(0)

strFind    = "package_extract_dir(""boot"", ""/boot"");"
strReplace = "assert(package_extract_file(""boot.img"", ""/tmp/boot.img"")," & vbCrLf & _
	"write_raw_image(""/tmp/boot.img"", ""boot"")," & vbCrLf & _
	"delete(""/tmp/boot.img""));"

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FileExists(strFileName) Then
		With .OpenTextFile(strFileName, ForReading)
			strContent = .ReadAll()
			
			.Close
		End With
		
		With .OpenTextFile(strFileName, ForWriting)
			.Write Replace(strContent, strFind, strReplace)
			
			.Close
		End With
	Else
		WScript.Echo "File [" & strFileName & "] not found"
	End If
End With

WScript.Quit 0

Файл для поиска включения указывается аргументом скрипта:

Код:

Script.vbs "c:\Sample folder\Sample file.cfg"

[xGETSx]

Не работает. Может потому что у меня файл не .cfg?

[Iska]

Всё может быть. Кодировка, формат строк и т.д.

Если файл не слишком большого объёма — обязательно упакуйте в rar/7z, выложите на обменник, ссылку сюда или непосредственно в личку. Посмотрим.

[Iska]

Файл получил.

У меня на Вашем файле — работает. В том плане, что ищет, находит и меняет. Результат в итоге получается, но, очевидно не такой, как нужен, ибо Ваш текстовый файл, как Вы верно указали, формата UNIX, следовательно концы строк у него LF, и, соответственно, в приведённом выше коде достаточно заменить:

Код:

strReplace = "assert(package_extract_file(""boot.img"", ""/tmp/boot.img"")," & vbCrLf & _
	"write_raw_image(""/tmp/boot.img"", ""boot"")," & vbCrLf & _
	"delete(""/tmp/boot.img""));"

на:

Код:

strReplace = "assert(package_extract_file(""boot.img"", ""/tmp/boot.img"")," & vbLf & _
	"write_raw_image(""/tmp/boot.img"", ""boot"")," & vbLf & _
	"delete(""/tmp/boot.img""));"

для получения ожидаемого результата.