[megaloman]

В принципе можно и CMD

Решаю задачу: Если за день создаётся несколько файлов бэкапов с разными именами, копирую все файлы, самые старые по дате изменения в каждом месяце. Если самая старая дата изменения файлов в месяце не 01, а например, 05, будут скопированы файлы за 05 число

Код:

@Echo Off
	Set "BoxIn=D:\CMD_Forum"
	Set "MaskIn=*.7z"
 
	Set "BoxOut=Z:\Box_Out" 

	Pushd "%BoxIn%"
	Set "FMes= "
	Set "FDay= "
	FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%MaskIn%" /B /A:-D /O:D /T:W`) DO Call :CopyFirst "%%f" %%~tf  
	Popd
GoTo :Eof

:CopyFirst
	Set "Mes=%2"
	Set "Mes=%Mes:~-7%"
	If Not "%Fmes%"=="%Mes%" (
		Set "FDay=%2"
		Set "FMes=%Mes%"
	)
	If "%FDay%"=="%2" If Not Exist "%BoxOut%\%~1" Echo %1 &Copy %1 "%BoxOut%\" >nul
GoTo :Eof

Если скрипт предполагается выполнять многократно, то, чтобы избежать повторного копирования, перед Copy лучше поставить проверку на существование файла в выходной папке

Код:

rem	Copy %1 "%BoxOut%\" >nul
	If Not Exist "%BoxOut%\%~1" Echo %1 &Copy %1 "%BoxOut%\" >nul

Примечание: отображение месяца и года в системе должны быть мм гггг