[campbell]

похоже это настолько просто, что мастерам лень писать ))

[Iska]

Вы определитесь, что Вам конкретно нужно, а то у Вас техзадание чересчур противоречивое:

Код: текст4 текст5 текст6

ориентиром для него тоже служит некое слово или знак "," например.

Давайте не будем гадать: пробел, «некое слово» или «знак ","». Приведите исходные данные, пример реального файла, что нужно получить на выходе.

Про русский язык я уже промолчу.

[campbell]

не знаю как разобрать следующее

пример:

User 150, user-online 50: Anay,Petay,Vasay,Sasha..... User offline- 100 Sergei,Stepan,Misha.......

в итоге
%A= User 150
%B =user-online 50: Anay,Petay,Vasay,Sasha.....
%C=User offline- 100 Sergei,Stepan,Misha.......

за русский язык извиняюсь )

[Iska]

campbell, действительно такой разнобой:

Код:

user-online
User offline-

в логе?

Попробуйте так (без каких-либо проверок):

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sFile=E:\Песочница\0093\0001.txt

set sDelim1=user-online
set sDelim2=User offline-

for /f "usebackq delims==" %%i in ("%sFile%") do (
	set sLine=%%i
	set sDelim1Line=!sLine:%sDelim1%=*!
	set sDelim2Line=!sDelim1Line:%sDelim2%=*!
	
	for /f "tokens=1-3 delims=*" %%j in ('echo !sDelim2Line!') do (
		set sTemp=%%j
		set a=!sTemp:~0,-2!
		set b=%sDelim1%%%k
		set c=%sDelim2%%%l

		echo A = [!a!]
		echo B = [!b!]
		echo C = [!c!]
	)
)

endlocal
exit /b 0

Я использовал приведённый Вами текст:

Код:

User 150, user-online 50: Anay,Petay,Vasay,Sasha..... User offline- 100 Sergei,Stepan,Misha.......

сохранив его в файле «E:\Песочница\0093\0001.txt».

Результат

Код:

A = [User 150]
B = [user-online 50: Anay,Petay,Vasay,Sasha..... ]
C = [User offline- 100 Sergei,Stepan,Misha.......]

[campbell]

Работает спасибо!
Правда не понял, как определяется переменная A.

[Iska]

Правда не понял, как определяется переменная A. »

campbell, через промежуточную переменную отрезаются два «лишних» символа — запятая и пробел — «, ».

Добавьте в:

Код:

		set sTemp=%%j
		set a=!sTemp:~0,-2!

вывод «sTemp»:

Код:

		set sTemp=%%j
		echo sTemp = [!sTemp!]
		set a=!sTemp:~0,-2!

и прочтите о замене текста в:

Код:

set /?