[megaloman]

Если батник запускать в папке, где находятся файлы, то

Код:

@echo off
FOR /F "usebackq delims=" %%d IN (`Dir "*.mp3" /b /A:-D 2^>nul`) DO (
	md  "%%~nd"
	move /Y "%%d" "%%~nd\"
)

Либо

Код:

@echo off
FOR %%f IN (*.mp3) DO md "%%~nf" & move /Y "%%f" "%%~nf\"

Либо из командной строки, например, файл-менеджера FAR
FOR %f IN (*.mp3) DO md "%~nf" & move /Y "%f" "%~nf\"

[Metallor]

Спасибо большое. Второй вариант подошел.

[athlonix4@twitter]

мне нужно тже самое но только у меня файлы имеют имена:
First_2021-10-22.ts
First_2020-01-18.mp4
Third_2016-02-02.flv
Third_2019-04-05.avi
и т.д.
нужно что бы все файлы с именем в начале "First" перенеслись в папку "First", тоесть куча файлов с разными датами в имени слились в одну папку, и расширения у них разные, но в основном видеоформат.

[megaloman]

Код:

@Echo Off
cls
 	Set "BoxIn=Z:\Box_In"

	FOR /F "usebackq delims=" %%f In (`2^>nul Dir /B /A:-D "%BoxIn%\*_20??-??-??.*"`) DO If Exist "%BoxIn%\%%f" (
			Set "Name=%%~nf"
			Call Echo %%Name%%|>nul 2>&1 FindStr/I /R /C:"^.*_20[0-9][0-9]-[0-1][0-9]-[0-3][0-9]$"&& (
				Call Set "Name=%%Name:~0,-11%%"
				Call 2>nul Md "%BoxIn%\%%Name%%"
				Call >nul Move /Y "%BoxIn%\%%Name%%_20??-??-??.*" "%BoxIn%\%%Name%%\"
	))
Pause
Exit /B

То же, чуть проще и быстрее, но менее надёжно

Код:

@Echo Off
cls
 	Set "BoxIn=Z:\Box_In"

	FOR /F "usebackq delims=" %%f In (`2^>nul Dir /B /A:-D "%BoxIn%\*_20??-??-??.*"`) DO If Exist "%BoxIn%\%%f" (
			Set "Name=%%~nf"
			Call Set "Name=%%Name:~0,-11%%"
			Call 2>nul Md "%BoxIn%\%%Name%%"
			Call >nul Move /Y "%BoxIn%\%%Name%%_20??-??-??.*" "%BoxIn%\%%Name%%\"
	)
Pause
Exit /B

[athlonix4@twitter]

megaloman »

че то не работает, ничего не происходит

[athlonix4@twitter]

athlonix4@twitter, вы свой путь прописали вместо моего? Set "BoxIn=Z:\Box_In" Имя файла указали правильно? »

наверное немного недопонимание возникло, у меня как бы имен файлов разных около 1000, все они имеют разное колличество с датами, поэтому хотелось бы без указания.

[megaloman]

athlonix4@twitter, Виноват, Вы должны указать путь папки, где содержатся эти файлы
Вот еще вариант:

Код:

@Echo Off
cls
 	Set "BoxIn=Z:\Box_In"

	If Not "%~1"=="" Set "BoxIn=%~1"

	If "%BoxIn:~-1%"=="\" Set "BoxIn=%BoxIn:~0,-1%
	FOR /F "usebackq delims=" %%f In (`2^>nul Dir /B /A:-D "%BoxIn%\*_20??-??-??.*"`) DO If Exist "%BoxIn%\%%f" (
			Set "Name=%%~nf"
			Call Set "Name=%%Name:~0,-11%%"
			Call 2>nul Md "%BoxIn%\%%Name%%"
			Call >nul Move /Y "%BoxIn%\%%Name%%_20??-??-??.*" "%BoxIn%\%%Name%%\"
	)
Pause
Exit /B

Сохраните где-нибудь батник, на рабочем столе создайте на него иконку и в проводнике затаскивайте на нее обрабатываемую папку.
Можете просто запускать батник, но при этом путь к папке возьмется из батника.
Если поместить батник в обрабатываемую папку и запускать оттуда, то:
Set "BoxIn=%~dp0"

[athlonix4@twitter]

megaloman »

спасибо огромное, все работает, если можно еще один нюанс, оказалось что есть файлы и с таким форматом имени:
Nikolay_2021-08-26_22-23-36_0001.ts
Nikolay_2022-01-21_21-23-25-proxy.ts
Nikolay_2022-01-21_21-23-25_deleted.ts
как быть с этим? редактировать батник под свой формат, я попытался, но что то пошло не так, или есть универсальный способ?

[megaloman]

athlonix4@twitter, "Nikolay" - как я понимаю, имя произвольное. Оно может содержать знак "_" ? Кстати, этот вопрос относится и к предыдущим файлам.