[Johny777]

elmariacci,

необходима проверка в реестре на наличие в системе Microsoft .NET Framewok 3.5 (именно 3.5, а не 4+) »

касательно фреимворка: версия выше 3.5 содержит его в себе, поэтому имеются и соответствующие ключи для ... 3.5, 4.0 ...
можешь забить на "именно 3.5, а не 4+", те тебе нужно от 3.5 и выше
реализовал для фреиворка нужную тебе проверку, но я без понятия что такое Dokan.dll и где она должна лежать. Короче смотри пример. Думаю дальше сам разберёшься

читать дальше »

Код:

[Setup]
AppName=My Application
AppVersion=1.5
DefaultDirName={pf}\My Application

[Components]
Name: comp; Description: I Need Net3.5; Types: full custom;

[Run]
Filename: {app}\dotNetFx35setup.exe; Parameters: /q /norestart; Description: Install Net v3.9; Flags: waituntilterminated; Check: NeedInstall('Net3.5');
Filename: {app}\Dokan.exe; Parameters: ; Description: Install Dokan.dll; Flags: waituntilterminated; Check: NeedInstall('Dokan.dll');

[code]
function NeedInstall(const InputParam: String): boolean;
begin
  case InputParam of
    'Net3.5': Result := IsComponentSelected('comp') and not RegKeyExists(HKEY_LOCAL_MACHINE, 'Software\Microsoft\NET Framework Setup\NDP\v3.5');
    'Dokan.dll': Result := not FileExists(ExpandConstant('{app}\Dokan.dll'));
  end;
end;

==================================================================================================== =

insombia, извиняй, срепов не знаю, помочь не могу

[Mailchik]

insombia, в ISDone ведь наглядный пример даётся, что не понятного?

Код:

if not ISSRepExtract   ( 0, 0, ExpandConstant('{src}\data.srep') {расположение архива который нужно распаковать}, ExpandConstant('{app}\data1024.arc') {Путь распаковки}, true) then break;

[audiofeel]

Здравствуйте, можно ли сделать маленькое окошко "DirEdit" прозрачным и чтобы пользователь смог сменить папку установки только нажав на кнопку "изменить" - то есть строчку о конечной папки не редактируемой

[Mailchik]

audiofeel,

читать дальше »

Код:

[Setup]
AppName=My Application
AppVersion=1.5
DefaultDirName={pf}\My Application

[Code]
procedure InitializeWizard;
 begin
  with WizardForm.DirEdit do begin
   BorderStyle := bsNone;
   AutoSelect := False;
   ReadOnly := True;
   Color := clBtnFace;
  end;
end;

[audiofeel]

Mailchik, все получилось, но я так понял что на "прозрачность" мне надеется не стоит = белый фон остался. Млин и "transparent" выдает ошибку = оставить что ли как есть, как вы думаете или есть другой способ

[Johny777]

audiofeel, предлагаю так:

читать дальше »

Код:

[Setup]
AppName=My Program
AppVerName=My Program
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputBaseFilename=setup
OutputDir=.

[code]
#ifdef UNICODE
    #define A "W"
#else
    #define A "A"
#endif

const
  MAX_PATH = 260;
  MAX_PATH_LEN = 55;

var
  PathLabel: TLabel;

function PathCompactPathEx(pszOut: String; pszSrc: String; cchMax: UINT; dwFlags: DWORD): BOOL; external 'PathCompactPathEx{#A}@shlwapi.dll stdcall';

function ShortPath(Input: String; Length: Integer): String;
begin
  Result := StringOfChar(#32, MAX_PATH);
  PathCompactPathEx(Result, Input, Length, 0);
end;

procedure DirEditOnChange(Sender: TObject);
begin
  PathLabel.Caption := ShortPath('Install Path:' + #32 + TEdit(Sender).Text, MAX_PATH_LEN);
end;

procedure InitializeWizard();
begin
  with WizardForm do
  begin
    PathLabel := TLabel.Create(WizardForm)
    with PathLabel do
    begin
      Parent := DirEdit.Parent;
      Caption := ShortPath('Install Path:' + #32 + DirEdit.Text, MAX_PATH_LEN);
      Transparent := True;
      Font.Size := 10;
      Left := DirEdit.Left;
      Top := DirEdit.Top + Round((DirEdit.Height - Height) div 2);
    end;
    DirEdit.OnChange := @DirEditOnChange;
    DirEdit.Hide;
  end;
end;

только значение константы MAX_PATH_LEN настрой при необходимости

[audiofeel]

Johny777, Всё ОК. когда компилируешь - но стоит объединить с "моим скриптом" = результат DirEdit отображается на первой странице по верх моих каракуль, а мой не прозрачный как был так и есть на своем месте. P.S. по моему хватит, заброшу я его или сделаю на "адвансед инсталлер 9.8"

[Johny777]

audiofeel, дай исходник с файлами, посмотрю что не так

заброшу я его или сделаю на "адвансед инсталлер 9.8" »

не советую менять инно на всякую фигню
инно - это тот же объект-паскаль/делфи - то бишь язык программирования, хотя и нехило урезанный. Думаю о проистекающих отсюда возможностях нетрудно догадаться (сейчас те кто знают СИ и ассемблер посмеются). Переломайся, изучи и не пожалеешь!
вот тебе демо возможностей (далеко не всех):
1. http://sendfile.su/748778
2: http://sendfile.su/748248
скачай, положи обе программы рядом, поиграйся и садись снова за инно. Будут проблемы спрашивай - чем смогу помогу

[R.i.m.s.k.y.]

Johny777, второй не качаиццо

[Johny777]

R.i.m.s.k.y.,
1. у меня всё качается (только-что скачал для проверки) - у тебя что-то с нетом
2. Там нет ничего, что ты не видел (те инсталл халфы - относительно старая версия)