[Angry Demon]

[решено] батник для создания папки с текущей датой + время

Создание папки с текущими датой и временем в имени с использованием контекстного меню

[Iska]

Labudico, а для чего Вы создаёте каталог с названием в виде текущих даты/времени?

[Labudico]

[решено] батник для создания папки с текущей датой + время Создание папки с текущими датой и временем в имени с использованием контекстного меню »

Огромное спасибо за ответ!

Labudico, а для чего Вы создаёте каталог с названием в виде текущих даты/времени? »

за день мне могут прислать разные варианты проектов и файлы всегда с одним тем же названием, нужно как то сортировать по папкам разные версий.

[Iska]

Labudico, тогда быстрее и проще скрипт WSH:

Скрытый текст

Код:

Option Explicit

Const strRootFolder = "C:\Мои проекты\0326\Destination"


Dim strSourceFile
Dim strDestFolder

Dim objFSO


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FolderExists(strRootFolder) Then
		If objFSO.FileExists(strSourceFile) Then
			strDestFolder = objFSO.BuildPath(strRootFolder, FormatOwnDateTime())
			
			If Not objFSO.FolderExists(strDestFolder) Then
				objFSO.CreateFolder strDestFolder
			End If
			
			objFSO.MoveFile strSourceFile, strDestFolder & "\"
		Else
			WScript.Echo "Can't find source file [" & strSourceFile & "]."
			WScript.Quit 3
		End If
	Else
		WScript.Echo "Can't find root folder [" & strRootFolder & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0
'=============================================================================

'=============================================================================
Function StrZeroPad(intValue, intCount)
	StrZeroPad = Right(String(intCount, "0") & CStr(intValue), intCount)
End Function
'=============================================================================

'=============================================================================
Function FormatOwnDateTime()
	Dim dtNow
	
	
	dtNow = Now()
	
	FormatOwnDateTime = _
		StrZeroPad(Year(  dtNow), 4) & _
		StrZeroPad(Month( dtNow), 2) & _
		StrZeroPad(Day(   dtNow), 2) & _
		"_" & _
		StrZeroPad(Hour(  dtNow), 2) & _
		StrZeroPad(Minute(dtNow), 2) & _
		StrZeroPad(Second(dtNow), 2)
End Function
'=============================================================================

и ярлык на этот скрипт, помещённый в SendTo:

Скрытый текст

Здесь предполагается, что каталоги, именованные текущим значением даты/времени, создаются в одном и том же предварительно заданном каталоге. Но это поведение можно и изменить.