[Iska]

Voodooman, для правильного понимания не хватает примеров всех четырёх файлов: что есть и что нужно получить в итоге.

[Voodooman]

4 файла???
2 же))
Я вроде бы доступно все объяснил, не хочу показаться грубым, но чуть выше все разжевано на пальцах так, что можно обойтись и без примеров и все правильно понять.
Но ладно, попробую еще более доступно объяснить:

name.txt

Код:

name 1
name 2
another name
one more name
etc

id.txt

Код:

125162
446
68568
434637
3535

Что я получаю:

Код:

name 1=3535
name 2=3535
another name=3535
one more name=3535
etc=3535

Что нужно получить:

Код:

name 1=125162
name 2=446
another name=68568
one more name=434637
etc=3535

[Foreigner]

Voodooman,

Что нужно получить: Код: name 1=125162 name 2=446 another name=68568 one more name=434637 etc=3535

При условии, что все файлы без пустых строк

Код:

@echo off
setlocal

<id.txt set /p "firstid="
<names.txt set /p "firstname="

echo %firstname%=%firstid%
set "skip=0"
for /f %%i in (id.txt) do set /a cnt+=1

:loop
if %skip% equ %cnt% goto:eof
set /a skip+=1

for /f "skip=%skip% tokens=*" %%i in (id.txt) do (
     
    for /f "skip=%skip% tokens=*" %%j in (names.txt) do echo %%j=%%i && goto:loop

)

[Voodooman]

Я уже справился с задачей сам - решил совсем не использовать дампы со списком имен и айди, так как не нашел нормального способа заставить внутренний цикл for обработать одну строчку и завершиться, вместо прохода по всем строчкам, по этому использовал чтение одного ini файла соответсвующего имени напрямую, так хоть во внутреннем for не появляется десяток лишних циклов:

PHP код:

setlocal enabledelayedexpansion

echo off

call :MainFunction

pause

exit



rem предпочитаю делить код на легко читаемые и понимаемые подпрограммыфункции и вызывать при необходимости

:MainFunction

FOR /F "tokens=* delims=" %%A IN ('dir *.ini /b /o:gn') DO ( 

    FOR /F "usebackq tokens=3* delims=/" %%B IN ("%%~nA.ini") DO (

        SET GameName=%%~nA

        SET GameId=%%B

    ) && SET /a N=!N!+1

    call :Debug

)

exit /b





:Debug

echo !N!=!GameName!=!GameId!

exit /b 

Но меня все еще интересует как сделать первым методом, должен же быть способ выборочного чтения конкретной строчки.
Foreigner, cкрипт работает, но что это за синтаксис такой страшный?
Можно пояснения как он работает и в чем моя ошибка?

Что делает вот это и зачем оно вообще нужно?
<id.txt set /p "firstid="

Зачем выводить первое эхо, ставить две переменных счетка skip и cnt и еще и сравнивать их? Зачем выпрыгивать из цикла for во внешний loop, неужели нет более простого и лаконичного способа прочитать 1 конкретную строку из for и закончить цикл?
Можно в более удобоваримом виде и с комментариями?

[Iska]

4 файла??? 2 же)) Я вроде бы доступно все объяснил, не хочу показаться грубым, но чуть выше все разжевано на пальцах так, что можно обойтись и без примеров и все правильно понять. »

Вот вам и ответ: я воспринял текст не верно, как два исходных и два — результирующих. А оказалось — три файла. Именно их содержание Вы привели далее.

Видите ли, коллега, приведение примеров позволяет дать наглядный образец и помогает лучше воспринимать формальный текст поставленного задания.

P.S. Можно спросить, например, у Foreigner'а — облегчили ли ему приведённые примеры понимание сути вопроса, или же они лишние?

Foreigner, cкрипт работает, но что это за синтаксис такой страшный? »

Нормальный синтаксис . Я не проверял работоспособность, но выглядит всё вполне цивильно и наглядно.

Что делает вот это и зачем оно вообще нужно? Код: <id.txt set /p "firstid=" »

Первая строка файла «id.txt» считывается в переменную окружения «firstid».

Но меня все еще интересует как сделать первым методом, должен же быть способ выборочного чтения конкретной строчки. »

неужели нет более простого и лаконичного способа прочитать 1 конкретную строку из for и закончить цикл? »

В принципе — есть. «more» умеет выводить текст, начиная с указанной строки. Другое дело, что ограничить вывод последующих строк через «more» не представляется возможным, и придётся всё одно отсекать вывод этих последующих строк, например, разбором через FOR и прерыванием цикла разбора на первом шаге. Например, читаем четвёртую строку файла «some.txt»:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "delims=" %%i in ('^<"some.txt" more +3') do set sValue=%%i & goto :lBreak
:lBreak

echo %sValue%

endlocal
exit /b 0

Другой возможный способ прерывания цикла описал amel27 здесь.

[Foreigner]

Что делает вот это и зачем оно вообще нужно? <id.txt set /p "firstid="

Берет первую строчку из файла. что бы потом можно было ее пропустить ( skip ). Т.к. skip=0 выдаст ошибку.

Зачем выпрыгивать из цикла for во внешний loop, неужели нет более простого и лаконичного способа прочитать 1 конкретную строку из for и закончить цикл?

Здесь же два цикла, по одному для каждого файла. Причем они должны быть одновременными. Я не придумал решения проще, чем прерывать оба цикла после прочтения первых строк в файлах и увеличения кол-ва пропущенных строк при каждой итерации в :loop. А переменные сравниваются для того, что бы не уйти в бесконечный цикл. Можно конечно все загнать в коллекцию переменных, а потом их разименовать:

Код:

@echo off
setlocal enabledelayedexpansion

for /f "tokens=*" %%i in (names.txt) do call:set names "%%i"
set "cnt="
for /f "tokens=*" %%i in (id.txt) do call:set id "%%i"

for /l %%i in (1,1,%cnt%) do echo !names_%%i!=!id_%%i!
goto:eof

:set
set /a cnt+=1
set "%1_%cnt%=%~2"

Просто я по возможности избегаю enabledelayedexpansion при echo-выводе текста.

[Iska]

Можно конечно все загнать в коллекцию переменных, а потом их разименовать: »

Кстати, тоже вариант. И, главное — самый быстрый. Лишь бы в ограничения командного процессора на целочисленные переменные число строк уместилось.

Просто я по возможности избегаю enabledelayedexpansion при echo-выводе текста. »

А почему? Я, напротив — всегда использую.

[Foreigner]

А почему? Я, напротив — всегда использую. »

Да что-то как-то так пошло, чистые батники и так с текстом работают "не слишком", а тут еще придется заботится о "!". Правда это не отменяет "%". Есть конечно универсальные решения, но это усложняет код. Имхо

[Voodooman]

Ну я тут на самом деле эхой из дебаг функции заменил кучу других функций и значительно скрипт сократил, чтобы не отвлекались на ненужные вещи, в данном случае меня интересуе соответсвие строк двух переменных.

Вот сейчас в своем решении без дампа списка файлово решил добавить по мимо считывания имени из названия ини файла и считывания айди из самого инишника, еще и считывания параметра с именем иконки, но вот беда все та же случилась - for начинает парсить все строки непрерывно и в итоге выдает мне последнюю по выходу из его цикла.
Я бы мог в 3 форе как и во 2 использовать делиметер с бекслешем и токеном, но вот беда еще в том, что количество бекслешей в искомой строке может различаться в некоорых инишника и соответсвенно я не знаю точно сколько токенов отсчитывать от начала строки, может есть способ отсчитывать токены от конца или число симоволов из нужной строчки от конца отсчитать и взять за переменную?

Дело в том что ваши методы джама из for во вне мне не подходят, так как у меня 3 фложенных for и прыжок прервет все 3, я попробовал сделать функцию внутри for b выпрыгнуть лишь за пределы 3го во второй, но увы обломался, похоже cmd не поддерживает таких джампов внутри цикла из более глубокого в менее без прерывания последнего.

В общем мне все еще надо считать одну строку из файла и прервать наследующий for не прерывая родительский или заменить какой то командой которая однозначно умеет читать только одну строку.
Я поверить не могу что МС выдумывая кучу сложных вещей для бат файла не придумали простого способа задать и исполнить лишь одну строку.


Вот как можно прервать один фор после первого или заданного прохода не прерывая второго? Может можно использовать как то skip относительно конца файла? например так skip=3,-3 - не читать первые и последние 3 строчки, а если между ними всего одна, то как раз получается нужный результат.