[DJ Mogarych]

Это не техническая проблема:

Проблема не зависит от принтера, компьютера и версии офиса »

Проблема

В одном из отделов »

А именно - в криворукости сотрудников, не умеющих нормально использовать офис.

[dislike]

Если б я хоть мог понять, ЧТО надо делать с офисом, чтоб получить такой чудовищный результат?!

[sputnikk]

dislike, придётся посмотреть лично как сохраняют документ

[a_axe]

ЧТО надо делать с офисом »

dislike, насколько я понимаю - это не результат работы с офисом?

По словам сотрудников, они что-то куда-то загружают, потом выгружают, »

Возможно - загружают в какую-нибудь систему документооборота, и она изменяет файлы? И тут резонный вопрос - насколько эти изменения в принципе устранимы в "пакетном режиме", существует ли такое решение.

Конструктивных предложений по борьбе со следствиями пока нет, разумно выяснить, куда файлы загружаются и что можно сделать с причиной.
Что происходит, если загружать не docx, а doc?

[Iska]

Если б я хоть мог понять, ЧТО надо делать с офисом, чтоб получить такой чудовищный результат?! »

dislike, может Вас устроит обратное?

Код:

Option Explicit

Const wdPaperA4 = 7
Const wdOrientLandscape = 1


Dim strSourceFile
Dim objFSO


If WScript.Arguments.Count = 1 Then
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	strSourceFile = objFSO.GetAbsolutePathName(WScript.Arguments.Item(0))
	
	If objFSO.FileExists(strSourceFile) Then
		Select Case LCase(objFSO.GetExtensionName(strSourceFile))
			Case "doc", "docx"
				With WScript.CreateObject("Word.Application")
					With .Documents.Open(strSourceFile)
						With .Sections
							With .Item(1).PageSetup
								.PaperSize = wdPaperA4
								.TwoPagesOnOne = False
							End With
							
							With .Item(2).PageSetup
								.PaperSize = wdPaperA4
								.Orientation = wdOrientLandscape
								.TwoPagesOnOne = False
							End With
						End With
						
						.Save
						.Close
					End With
					
					.Quit
				End With
			Case Else
				WScript.Echo "Probably not a Microsoft Word document."
				WScript.Quit 3
		End Select
	Else
		WScript.Echo "Can't find source file [" & strSourceFile & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0

Путь к документу задаётся аргументом скрипта (также можно просто перетащить документ на скрипт или его ярлык).

Я правильно понимаю, что навряд ли данный документ предполагалось печатать по две логических страницы на одной физической?

P.S. И пусть авторы научатся пользовать либо разрыв страниц/разделов, либо свойство абзаца/стиля Начинать с новой страницы (вместо выравнивания по вертикали пустыми абзацами).

P.P.S. А так-то коллеги совершенно правы — надо бить подсвешниками ставить техподдержку того продукта:
.

что-то куда-то загружают, потом выгружают, и в итоге у них получаются эти файлы »

на уши.

[Iska]

Забыл отметить, почему так:

2. При попытке открыть Параметры страницы выдает ошибку "Размер и ориентация страницы являются несовместимыми", но окно настроек всё же открывается. 3. В окне параметров страницы при нажатии на ОК независимо от того, изменялось что-либо из настроек или нет, выбивает другую ошибку "Значение должно быть между 0,26 и 55,87 см". Какое значение, черт его не ведает, идиотские программисты майкрософт в своей гениальности не считают нужным пояснять. »

получается. Дело в том, что:

а) настройки параметров страниц разделов в целом несовместимы, о чём свидетельствует сообщение:


б) некорректные настройки, заданные числами, находятся на второй вкладке, Размер бумаги, а по умолчанию открывается первая вкладка, Поля. Если бы мы «ручками» попытались ввести/задать некорректные значения — сработал бы тот же самый триггер, и нас тупо не выпустило бы за пределы той вкладки, где мы вводили эти значения, пока бы мы их не исправили или не отменили бы. Но, поскольку, в данном случае, некорректные значения заданы явно программным образом (уж не знаю, что там программисты напрограммировали — то ли напортачили в переводе единиц из одной системы в другую, або ещё чего, то ли вообще тупо xml правили. не проверяя, что выйдет), то мы оказываемся в дурацкой ситуации — мы банально не можем попасть на эту вторую вкладку.

Сколько-то лет назад я с подобным поведением уже сталкивался.

[dislike]

может Вас устроит обратное? »

Да вполне. Проверил - работает. Спасибо!