[Iska]

Разбираться в чужом неоформленном коде желания мало (особенно умиляет конструкция «Trim(objFolder.Name)»). Опишите вменяемым русским языком, с заглавными буквами в начале и с точками в конце предложений, полное техзадание.

[Anufriev]

изменил тех задание в первом посте

[Iska]

Как-то так (не проверялось):

Код:

Option Explicit


Dim dtCurrDate
Dim strFormattingDate

dtCurrDate = Now()
strFormattingDate = Right("0000" & Year(dtCurrDate), 4) & "." & Right("00" & Month(dtCurrDate), 2) & "." & Right("00" & Day(dtCurrDate), 2)

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists("D:\DAT") Then
		If .FolderExists("C:\bnk\DAT") Then
			If Not .FolderExists("D:\" & strFormattingDate) Then
				.GetFolder("D:\DAT").Name = strFormattingDate
				.CopyFolder "C:\bnk\DAT", "D:\DAT", True
			Else
				WScript.Echo "Folder [D:\" & strFormattingDate & "] already exists"
			End If
		Else
			WScript.Echo "Folder [C:\bnk\DAT] not found"
		End If
	Else
		WScript.Echo "Folder [D:\DAT] not found"
	End If
End With

WScript.Quit 0

[Anufriev]

Спасибо огромное, скрипт работает, в пути только небольшая опечатка была

[Iska]

…в пути только небольшая опечатка была »

Скажете где — я поправлю код в предыдущем посте.

[Anufriev]

.CopyFolder "C:\bnk\DAT ", "D:\DAT", True

а то он берет всю папку BNK и копирует с переименованием в DAT на диск D

и еще вопрос тогда, то что по завершению работы скрипта выдать сообщение о завершении возможно, а возможно ли проконтролировать полное копирование папки, а после выдать сообщение о том что обновление завершено?

p.s. а если это сообщение будет выскакивать на другом ПК (естественно на определенном), то это было бы просто невероятно