[Iska]

Maza11,

разве нет такого в XP? »

В Windows XP — нету.

Maza11, покажите результаты исполнения:

Код:

assoc .vbs
ftype VBSFile

только либо просто скопируйте текст из окна консоли, либо не делайте масштабирование на скриншоте.

Кроме того, Вы можете задать в свойствах задания не .vbs, а сам исполняемый файл:

Код:

"%SystemRoot%\System32\wscript.exe" "C:\move.vbs" "\\Backup\box"

[Maza11]

Цитата megaloman:
Настройте планировщик на его выполнение, в XP, мне помнится, это не проблема, сделайте повтор его исполнения с нужной Вам периодичностью, хоть сто раз в день, хоть раз в неделю, месяц итд. Не на чем вспомнить XP. Пытаюсь по Вашему скрину: кажется, в панели управления найти назначенные задания -> кнопка (иконка?) новое задание ->выдаст окно поиска исполнимого файла. Затем настроите расписание. Там всё понятно »
Ваш BAT файл работает, спасибо

[lSVl]

Почему-то не работает. Помогите пожалуйста.

Код:

@Echo On

Set "BoxIn=c:\temp"
Set "BoxOut=c:\temp"

Set "Mask=sshot-20??-??-??-[??-??-??].png"

FOR /F "usebackq delims=" %%f IN (`Dir "%BoxIn%\%Mask%" /b /A:-D 2^>nul`) DO (
	FOR /F "usebackq tokens=3 delims= " %%d IN ('%%f') DO (
		If Not Exist "%BoxOut%\%%d" Md "%BoxOut%\%%d"
		Copy "%BoxIn%\%%f" "%BoxOut%\%%d\" >nul &&Del "%BoxIn%\%%f"
	)
)
pause >nul

Код:

C:\>Set "BoxIn=c:\temp"

C:\>Set "BoxOut=c:\temp"

C:\>Set "Mask=sshot-20??-??-??-[??-??-??].png"

C:\>FOR /F "usebackq delims=" %f IN (`Dir "c:\temp\sshot-20??-??-??-[??-??-??].p
ng" /b /A:-D 2>nul`) DO (FOR /F "usebackq tokens=3 delims= " %d IN ('%f') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\%f" "c:\temp\%d\"   1>nul  && Del "c:\temp\%f"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-20-56].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-20-56].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-20-56].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-20-57].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-20-57].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-20-57].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-20-58].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-20-58].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-20-58].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-20-59].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-20-59].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-20-59].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-21-01].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-21-01].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-21-01].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-21-02].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-21-02].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-21-02].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-21-03].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-21-03].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-21-03].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-21-04].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-21-04].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-21-04].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-21-05].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-21-05].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-21-05].png"
) )

C:\>(FOR /F "usebackq tokens=3 delims= " %d IN ('sshot-2018-03-30-[11-21-07].png
') DO (
If Not Exist "c:\temp\%d" Md "c:\temp\%d"
 Copy "c:\temp\sshot-2018-03-30-[11-21-07].png" "c:\temp\%d\"   1>nul  && Del "c
:\temp\sshot-2018-03-30-[11-21-07].png"
) )

C:\>pause  1>nul

Код:

Microsoft Windows [Version 6.1.7601]
(c) Корпорация Майкрософт (Microsoft Corp.), 2009. Все права защищены.

C:\Users\User>tree.exe c:\temp
c:\temp
|-- sshot-2018-03-30-[11-20-56].png
|-- sshot-2018-03-30-[11-20-57].png
|-- sshot-2018-03-30-[11-20-58].png
|-- sshot-2018-03-30-[11-20-59].png
|-- sshot-2018-03-30-[11-21-01].png
|-- sshot-2018-03-30-[11-21-02].png
|-- sshot-2018-03-30-[11-21-03].png
|-- sshot-2018-03-30-[11-21-04].png
|-- sshot-2018-03-30-[11-21-05].png
`-- sshot-2018-03-30-[11-21-07].png

0 directories, 10 files

C:\Users\User>

[megaloman]

lSVl, Решалась частная задача

скриншоты формата "Snap - 2017-02-06 09.45.00.png" »

Вы пытаетесь частное решение применить к другой задаче

sshot-20??-??-??-[??-??-??].png»

Для этого надо было вникнуть, как работает скрипт. Частное решение именно Вашей задачи

Код:

@Echo Off

Set "BoxIn=Z:\Box_In"
Set "BoxOut=Z:\Box_In"

Set "Mask=sshot-20??-??-??-[??-??-??].png"

FOR /F "usebackq delims=" %%f IN (`Dir "%BoxIn%\%Mask%" /b /A:-D 2^>nul`) DO (
	FOR /F "usebackq tokens=2,3,4 delims=-" %%i IN ('%%f') DO (
		If Not Exist "%BoxOut%\%%i-%%j-%%k" Md "%BoxOut%\%%i-%%j-%%k"
		Copy "%BoxIn%\%%f" "%BoxOut%\%%i-%%j-%%k\" >nul &&Del "%BoxIn%\%%f"
	)
)

Загвоздка в том, чтобы выдернуть дату из имени файла - приходится подстраиваться под формат имени.

Вот более общее решение - дата определяется не по имени файла, а по дате его последнего изменения. Но и тут засада, общности тоже нет: предполагается, что формат отображения даты в системе дд.мм.гггг

Код:

@Echo Off
Set "BoxIn=Z:\Box_In"
Set "BoxOut=Z:\Box_In"

Set "Mask=sshot-20??-??-??-[??-??-??].png"

FOR /F "usebackq delims=" %%f IN (`Dir "%BoxIn%\%Mask%" /b /A:-D /O:D /T:W 2^>nul`) DO Call :Separator "%BoxIn%\%%f" "%BoxOut%"
GoTo :Eof

:Separator
	Set "DName=%~t1"
	Set "DName=%Dname:~6,4%-%Dname:~3,2%-%Dname:~0,2%"
	If Not Exist "%~2\%DName%" Md "%~2\%DName%"
	Copy %1 "%~2\%DName%\" >nul &&Del %1
GoTo :Eof

[lSVl]

megaloman, Спасибо Вам огромное!