[omegastripes]

а можете обратный код написать, чтобы извлекал ярлык с панели задач? »

Код, собственно, можно использовать тот же, просто вместо строки

Код:

If VerbName = "Закрепить программу в панели задач" Or VerbName = "Закрепить на панели задач" Or VerbName = "Pin to Taskbar" Then

поменять желаемое действие на "Открепить от":

Код:

If VerbName = "Открепить от панели задач" Then

Для моей версии Win7HB вышеуказанное название действия появляется в контекстном меню закрепленного на панели задач файла. Для других версий и языковых пакетов я, к сожалению, не подскажу. Естественно, если названия для тех версий не прописать, то скрипт в них не будет функционировать.

[Dodakaedr]

Iska, Здравствуйте! Нужна Ваша помочь. Можете изменить скрипт чтобы он закреплял ярлык в меню пуск?

читать дальше »

Код:

If WScript.Arguments.Count <> 1 Then
	MsgBox "Drag'n'drop exe file to pin to taskbar", , "bla-bla"
	WScript.Quit
End If

strPath = WScript.Arguments(0)
Set objShell = CreateObject("Shell.Application")
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set objFolder = objShell.NameSpace(objFSO.GetParentFolderName(strPath))
Set objFolderItem = objFolder.ParseName(objFSO.GetFileName(strPath))

If objFolderItem Is Nothing Then
	MsgBox strPath & vbCrLf & "not found", , "bla-bla"
	WScript.Quit
End If

Set colVerbs = objFolderItem.Verbs

bPinned = False
For Each objVerb In colVerbs
	VerbName = Replace(objVerb.Name, "&", "")
	If VerbName = "Закрепить программу в панели задач" Or VerbName = "Закрепить на панели задач" Or VerbName = "Pin to Taskbar" Then
		objVerb.DoIt
		bPinned = True
		Exit For
	End If
Next

[Dodakaedr]

Помогите кто-нибудь с предыдущим постом.

[morozoff]

Dodakaedr, Посмотрите в этой теме. Там есть VBS-скрипты для закрепления на панели задач и закрепления в меню пуск.

[Dodakaedr]

morozoff, тот пример не подходит, мне нужен как у меня только чтобы закреплял в меню "Пуск".

[omegastripes]

Dodakaedr, вот, все аналогично первому скрипту, сохраняйте в виде файла .vbs:

Код:

If WScript.Arguments.Count <> 1 Then
	MsgBox "Перетащите файл, чтобы закрепить его в меню ""Пуск""", , "Закрепление ярлыка в меню ""Пуск"""
	WScript.Quit
End If

strPath = WScript.Arguments(0)

If MsgBox("Закрепить ярлык на [" & strPath & "] в меню ""Пуск""?", vbYesNo + vbInformation, "Закрепление ярлыка в меню ""Пуск""") = vbYes Then
	Set objShell = CreateObject("Shell.Application")
	Set objFSO = CreateObject("Scripting.FileSystemObject")
	
	Set objFolder = objShell.NameSpace(objFSO.GetParentFolderName(strPath))
	Set objFolderItem = objFolder.ParseName(objFSO.GetFileName(strPath))
	
	If objFolderItem Is Nothing Then
		MsgBox strPath & vbCrLf & "Файл не найден", , "Закрепление ярлыка в меню ""Пуск"""
		WScript.Quit
	End If
	
	Set colVerbs = objFolderItem.Verbs
	
	bPinned = False
	For Each objVerb In colVerbs
		VerbName = Replace(objVerb.Name, "&", "")
		If VerbName = "Закрепить в меню ""Пуск""" Or VerbName = "Pin to Start Menu" Then
			objVerb.DoIt
			bPinned = True
			Exit For
		End If
		
	Next
		
	If bPinned Then
		Msgbox "Ярлык закреплен", vbOKOnly + vbInformation, "Закрепление ярлыка в меню ""Пуск"""
	Else
		Msgbox "Ошибка закрепления ярлыка", vbOKOnly + vbCritical, "Закрепление ярлыка в меню ""Пуск"""
	End If
End If

Предвосхищая следующий вопрос - "Как убрать ярлык из меню Пуск?", отвечу: в тексте скрипта выше нужно заменить вот эту строку:

Код:

If VerbName = "Закрепить в меню ""Пуск""" Or VerbName = "Pin to Start Menu" Then

на строку

Код:

If VerbName = "Изъять из меню ""Пуск""" Or VerbName = "Unpin from Start Menu" Then

Ну и по тексту посмотреть - где было "...закрепить..." - заменить на "...изъять...".

P.S.: Напомню, что в зависимости от локализации эти скрипты могут легко Вас подвести. Пока что учтены имена действий только на русском и английском. В идеале нужно бы найти некий системный ресурс, который для всех языковых пакетов находился бы в одном и том же месте, и по определенному индексу из него можно было бы извлечь нужное название действия именно для текущей локализации.

[Dodakaedr]

omegastripes, Огромное Спасибо!

[Dodakaedr]

Подскажите, пожалуйста, как нужно указать файл с параметром, например такой:

Код:

MyProg.exe /Rem

чтобы ярлык закреплялся с параметром запуска программы.
Пробовал по разному не работает.

Код:

[run]
Filename: "{tmp}\1.vbs"; Parameters: """{app}\MyProg.exe /Rem"""; Flags: shellexec waituntilterminated;

Код:

[run]
Filename: "{tmp}\1.vbs"; Parameters: """{app}\MyProg.exe"" /Rem"; Flags: shellexec waituntilterminated;

[Iska]

Dodakaedr, это что? Скрипт установки InnoSetup?

[Dodakaedr]

Iska, да