[megaloman]

Patroklos, Как понять "отсортировать"? Что в результате?

Код:

@Echo Off
cls
	Set "BoxIn=Z:\Box_In"
	Set "Mask=*__????__?.?__.mp4"

	FOR /L %%y IN (1900,1,2050) DO (
		Call Set "MMask=%%Mask:????=%%y%%
		FOR /F "usebackq delims=" %%f IN (`2^>nul Dir /B /A:-D "%BoxIn%\%%MMask%%"`) DO (
			Echo %%f
	))
Pause
Exit /B

[Iska]

Patroklos, в Проводнике — стандартными средствами, полагаю, никак. В скрипте WSH — так:

Скрытый текст

Код:

Option Explicit

Const adVarChar  = 200
Const adVarWChar = 202

Dim strSourceFolder

Dim objFSO
Dim objFile

Dim objRegExp
Dim objRecordSet


If WScript.Arguments.Count = 1 Then
	strSourceFolder = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FolderExists(strSourceFolder) Then
		Set objRegExp = WScript.CreateObject("VBScript.RegExp")
		
		objRegExp.Pattern = "^.+__(\d{4})__\d\.\d__\.(?:avi|wmv|flv|3gp|webm|ogv|mpg|mpeg|mp4|mkv|m4v)$"
		
		With WScript.CreateObject("ADODB.RecordSet")
			With .Fields
				.Append "File name", adVarWChar, 255
				.Append "Year",      adVarChar,    4
			End With
			
			.Open()
			
			For Each objFile In objFSO.GetFolder(strSourceFolder).Files
				If objRegExp.Test(objFile.Name) Then
					.AddNew Array("File name", "Year"), Array(objFile.Name, objRegExp.Execute(objFile.Name).Item(0).Submatches.Item(0))
				End If
			Next
			
			.Sort = "Year"
			
			Do Until .EOF
				WScript.Echo .Fields.Item("File name")
				.MoveNext
			Loop
			
			.Close()
		End With
		
		Set objRegExp = Nothing
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source folder>"
	WScript.Quit 1
End If

WScript.Quit 0

На PowerShell должно быть ещё проще — там можно тупо приписать новое свойство к производному классу и отсортировать по нему.

[Patroklos]

Как понять "отсортировать"? Что в результате? »

Прошу прощения что непонятно написал.
В результате хочу получить список фильмов отсортированный по году. От младшего к старшему.

Код:

Manhunter__1986__7.2__.mp4
The Silence of the Lambs__1991__8.6__.mp4
Hannibal__2001__6.8__.mp4
Red Dragon__2002__7.2__.mp4
Hannibal Rising__2007__6.2__.mp4

в Проводнике — стандартными средствами, полагаю, никак. »

Как раз в проводнике это элементарно. mp4 поддерживает теги с которыми проводник хорошо работает.
Но мне удобней накостылить свой лоунчер.

WSH »

Ужас. Я с WSH даже шапочно не знаком. Но спасибо, вот и повод познакомиться.

[Iska]

Как раз в проводнике это элементарно. mp4 поддерживает теги с которыми проводник хорошо работает. »

Так тэги — это тэги, про них ничего не было сказано, а у нас же в техзадании — просто часть имени файла.

[YuS_2]

В результате хочу получить список фильмов отсортированный по году. »

получить где? плейлист, консоль, файл, файловый менеджер?
powershell
самый простецкий вариант:

Код:

dir *.mp4|sort{$_.basename -replace '.*(\d{4}).*','$1'}

[megaloman]

В результате хочу получить список фильмов отсортированный по году. От младшего к старшему.

Код:

@Echo Off
cls
>nul chcp 1251
	Set "BoxIn=Z:\Box_In"
	Set "Mask=*__????__?.?__.mp4"
	Set "OutFile=Z:\Box_In\_Reestr.txt"

	>"%OutFile%" (FOR /L %%y IN (1900,1,2050) DO (
		Call Set "MMask=%%Mask:????=%%y%%
		FOR /F "usebackq delims=" %%f IN (`2^>nul Dir /B /A:-D "%BoxIn%\%%MMask%%"`) DO (
			Echo %%f
	)))
Pause
Exit /B

[Patroklos]

Так тэги — это тэги, про них ничего не было сказано, а у нас же в техзадании — просто часть имени файла. »

Справедливо замечено. Просто я теги рассматривал в первую очередь. Для этого они и придуманы.

получить где? плейлист, консоль, файл, файловый менеджер? »

Консоль. Дальше я уже сам осилю. Надеюсь.
А можно ещё сортировку по оценке?

megaloman, Спасибо большое, всё работает как надо!

[YuS_2]

А можно ещё сортировку по оценке? »

по аналогии:

Код:

dir *.mp4|sort {$_.basename -replace '.*_(\d\.\d)_.*','$1'}

Предполагаю следующий вопрос: "А можно ли совместить?"
- Можно

Код:

dir *.mp4|sort {$_.basename -replace '.*_(\d\.\d)_.*','$1'},{$_.basename -replace '.*_(\d{4})_.*','$1'}

[Patroklos]

Супер, спасибо! А как заставить ПоШ искать рекурсивно и при этом писать в консоль только имя и путь?
Я на сайте МС читаю хелп но он не мне не помог.
Я пишу -Recurse у меня в консоли бардак.
Я пишу -Name -Recurse он не желает искать рекурсивно.
Есть возможность совместить -Name и -Recurse ?