[TERMINAL]

Creat0R, Возможно ли как то узнать серийный номер жёсткого диска, CD-ROMa, материнской платы....?
Возможно ли с помощью скрипта писать диски?
Возможно ли с помощью скрипта, зная название программы, к примеру 1С, узнать на какой сетевой адрес и через какой порт она подключена?

[SvetlanaK]

Можно ли с пом скрипта определить момент появления флэшки в компьютере?
в хелпе отыскала $var = DriveGetDrive( "REMOVABLE" ). но как сделать именно отслеживание? проверку в реальном времени, а не появилась ли флэш...и если появилась то выдать например сообщение типа "проверьте товарисч ее на вирусы, а не тоооооооо...." можно?

[Creat0R]

VovaVolk,

потом надо вводить имя и пароль »

Диалог отображается куда можно вводить данные?

DENoszone,

пишу сайт...а скрипт парсит его с верху до низу »

Одну страничку?

TERMINAL,

Возможно ли как то узнать серийный номер жёсткого диска, CD-ROMa, материнской платы....? »

Возможно, но это не ко мне, никогда не сталкивался.

Возможно ли с помощью скрипта писать диски? »

Полагаю что тоже возможно.

Возможно ли с помощью скрипта, зная название программы, к примеру 1С, узнать на какой сетевой адрес и через какой порт она подключена? »

Опять, это не ко мне
Я административными задачами не занимался, за исключением мелких, которые были любопытны мне.

SvetlanaK,

как сделать именно отслеживание? »

Я как то приводил пример:

Код:

#include <GuiConstants.au3>

Global $aDrives = 0

GUICreate("USB Ejector & Monitor", 300, 210)

$List = GUICtrlCreateList("", 20, 20, 260, 140)

$EjectDrive_Button = GUICtrlCreateButton("Eject Drive", 20, 170, 70, 20)
$RefreshList_Button = GUICtrlCreateButton("Refresh List", 210, 170, 70, 20)

_Check_Drives()
AdlibEnable("_Check_Drives", 1000)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $EjectDrive_Button
            $sDrive = GUICtrlRead($List)

            _EjectDrive(StringLower($sDrive))
        Case $RefreshList_Button
            $aCheckDrives = DriveGetDrive("Removable")
            _SetUSBDrivesList_Proc($List)
    EndSwitch
WEnd

Func _Check_Drives()
    $aCheckDrives = DriveGetDrive("Removable")

    If Not _aDrivesIsIdent($aDrives, $aCheckDrives) Then
        $aDrives = $aCheckDrives
        _SetUSBDrivesList_Proc($List)
    EndIf
EndFunc

Func _SetUSBDrivesList_Proc($iCtrlID=-1)
    GUICtrlSetData($iCtrlID, "")

    For $i = 1 To UBound($aDrives)-1
        If Not _IsFloppyDrives($aDrives[$i]) And DriveStatus($aDrives[$i]) = "READY" Then _
            GUICtrlSetData($iCtrlID, StringUpper($aDrives[$i]) & "\")
    Next
EndFunc

Func _aDrivesIsIdent(ByRef $avArray1, ByRef $avArray2)
    Local $iUbound1 = UBound($avArray1), $iUbound2 = UBound($avArray2)

    If $iUbound1 <> $iUbound2 Then Return False

    For $i = 1 To $iUbound1-1
        If Not _IsFloppyDrives($avArray1[$i], $avArray2[$i]) And _
            ($avArray1[$i] <> $avArray2[$i] Or DriveStatus($avArray1[$i]) <> "READY" Or _
            DriveStatus($avArray2[$i]) <> "READY") Then Return False
    Next

    Return True
EndFunc

Func _IsFloppyDrives($sDrive1, $sDrive2="")
    Return StringRegExp($sDrive1, "(?i)[a-b]") Or ($sDrive2 <> "" And StringRegExp($sDrive2, "(?i)[a-b]"))
EndFunc

Func _EjectDrive($sdLetter, $sVerb="&Извлечь") ;Для английской Winndows $sVerb = "E&ject"
    ;Раскомментируйте эти строчки для Варианта № 1 :)
;~  Run("rundll32.exe shell32.dll,Control_RunDLL hotplug.dll", @SystemDir)
;~  Return

    If $sdLetter = "" Then Return 0

    Local Const $SSF_DRIVES = 17
    Local $oShell, $oNameSpace, $oDrive

    Local $oEvent = ObjEvent("AutoIt.Error", "Error_Handler")

    Local $oShell = ObjCreate("Shell.Application")
    If Not IsObj($oShell) Then Return SetError(1, 0, 0)

    Local $oNamespace = $oShell.NameSpace($SSF_DRIVES)
    Local $oDrive = $oNamespace.ParseName($sdLetter)

    $oDrive.InvokeVerb($sVerb)
    If @error Then Return 0

    If DriveStatus($sdLetter) <> "READY" Then
        Local $strName = DriveGetLabel($sdLetter) & " (" & StringUpper($sdLetter) & ")"
        TrayTip("USB Drive " & $strName & " ejected", "You can now remove the device safely.", 5, 1)
    EndIf
Endfunc

Func Error_Handler()
    SetError(1)
EndFunc

[Maza Faka]

TERMINAL

Возможно ли как то узнать серийный номер жёсткого диска, CD-ROMa, материнской платы....?

Очень сложно, если не сказать невозможно. Эти данные можно получить из BIOS-а. Поищи в Googl-е.

Возможно ли с помощью скрипта писать диски?

Можно, для этого есть WinAPI функции.

[SvetlanaK]

Creat0R, большое спасибо!

[NikLok]

Имеем код типа

Код:

GuiCtrlCreateTab($x, $y, $w, $h
GuiCtrlCreateTabItem("Tab1")
....
GuiCtrlCreateTabItem("Tab2")
...
GuiCtrlCreateTabItem("Tab3")
..
GuiCtrlCreateTabItem("Tab4")
.
GuiCtrlCreateTabItem("")

В некоторых табах имеет ListView. Выбираем в каком нибудь алимент. Переключаемся в другой таб что-то делаем, возвращаемся а выбранный алимент сброшен.
Что значит надо самому запоминать его состояние и восстанавливать при переключении на данную вкладку? Мне кажется много кода будет!
Кто нибудь подскажет имена событий связанные с переключением вкладок. А еще лучше пример обработчика.
Или я опять все привратно трактую, в силу недопонимания?!

И кстатит на что влияет заключительная контсрукция GuiCtrlCreateTabItem("").
Я сначала без неё усе написал а потом у хелпе выглядел!

[Котяра]

Creat0R, Возможно ли как то узнать серийный номер жёсткого диска, CD-ROMa, материнской платы....? Возможно ли с помощью скрипта писать диски? Возможно ли с помощью скрипта, зная название программы, к примеру 1С, узнать на какой сетевой адрес и через какой порт она подключена? »

1. Я думаю, да.
2. Я думаю, нет, запись дисков не является функцией Windows, она появилась лишь в Windows XP. Только если подключить какой-нибудь command-line прожигатель дисков.
3. Не знаю

[Creat0R]

NikLok,

Выбираем в каком нибудь алимент. Переключаемся в другой таб что-то делаем, возвращаемся а выбранный алимент сброшен. »

Про какой элемент речь? строка в ListView?

Кто нибудь подскажет имена событий связанные с переключением вкладок. А еще лучше пример обработчика. »

Что именно требуется? проверить переключение вкладки?

Код:

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 300, 200)

$Main_Tab = GUICtrlCreateTab(20, 10, 260, 140)

$TabItem1 = GUICtrlCreateTabItem("Tab 1")
$TabItem2 = GUICtrlCreateTabItem("Tab 2")

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Main_Tab
            Switch GUICtrlRead($Main_Tab)
                Case 0
                    MsgBox(0, "", "Переключение на Tab 1")
                Case 1
                    MsgBox(0, "", "Переключение на Tab 2")
            EndSwitch
    EndSwitch
WEnd

на что влияет заключительная контсрукция GuiCtrlCreateTabItem(""). »

На закрытие табов, чтобы создаваемые далее контроли не попадали под последний созданный таб.

[NikLok]

Про какой элемент речь? строка в ListView? »

Именно, именно!

В принципе на все ответил. Только момент не совсем ясен:

Case 0 MsgBox(0, "", "Переключение на Tab 1") Case 1 MsgBox(0, "", "Переключение на Tab 2") »

Я так понимаю 0 и 1 это внутренние ( скрытые внутрях) идентификаторы табов в соотв с порядком их создания?
Наверное вместо них так же можно использовать $TabItem1 и $TabItem2 ?

А что с сохранением позций listview в табах?

[Creat0R]

NikLok,

Я так понимаю 0 и 1 это внутренние ( скрытые внутрях) идентификаторы табов в соотв с порядком их создания? »

Да, 0 первый таб, 1 (в этом случае) последний.

Наверное вместо них так же можно использовать $TabItem1 и $TabItem2 ? »

Нет, это идентификаторы контроля, а нам нужно проверять свойства текущего Tab'а.

что с сохранением позций listview в табах? »

У меня работает:

Код:

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 300, 200)

$Main_Tab = GUICtrlCreateTab(20, 10, 260, 140)

$TabItem1 = GUICtrlCreateTabItem("Tab 1")

$ListView = GUICtrlCreateListView("Column", 40, 40, 220, 100)
GUICtrlCreateListViewItem("Item", $ListView)

$TabItem2 = GUICtrlCreateTabItem("Tab 2")

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Приведи пример что конкретно имеется в виду.