[Iska]

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sLogFile=%~1

if not defined sLogFile (
	echo Not specified [Log file]!
	echo.
	call :Usage
	exit /b 1
)

set sRootPath=%~2

if not defined sRootPath (
	echo Not specified [Root path]!
	echo.
	call :Usage
	exit /b 2
) else (
	if not exist "%sRootPath%\." (
		echo Root path [%sRootPath%] not found.
		exit /b 3
	)
)

set sExt=%~3

if not defined sExt (
	echo Not specified any extension!
	echo.
	call :Usage
	exit /b 4
)

set sMasks=

:Repeat
set sExt=%~3

if defined sExt (
	set sMasks=!sMasks! "%sRootPath%\*.!sExt!"
	shift /3
	goto :Repeat
)

echo Log file:  [%sLogFile%]
echo Root path: [%sRootPath%]
echo Masks:     [%sMasks%]

2>nul >"%sLogFile%" dir /s /b %sMasks%
if exist "%sLogFile%" <"%sLogFile%" more

endlocal
exit /b 0

:Usage
	echo Usage:   %~nx0 ^<Log file^> ^<Root path^> ^<Extension^> [^<Extension^> [^<Extension^> ...]]
	echo Example: %~nx0 "E:\Песочница\0333\logfile.txt" "E:\Песочница" "rar" "zip" "7z"
	exit /b 0