[vahe-91]

Давно интересует такой вопрос - каким образом удалять/устанавливать файлы (в частности DLL) "занятые" ShellExtension не перезагружая explorer ( или подобное ПО, типа TotalCommander и т.п. )? »

сначала удаляешь записи реестра ShellExtension, потом ${RefreshShellIcons}, потом удаляешь dll-ки самой ShellExtension

[MKN]

сначала удаляешь записи реестра ShellExtension, потом ${RefreshShellIcons}, потом удаляешь dll-ки самой ShellExtension »

записи реестра удалются в первую очередь, но толка нет. RefreshShellIcons, по моему вообще здесь не при чём...
DLL занята системой, и хоть тресни никак не освобождается для удаления...

[Serg866]

Serg866, прикрепил архив к этому сообщению. »

Всё равно не получается брендинг-текст кликабельным. Может быть ещё кто-нибудь протестирует на 3 версии?

UPD
В общем сработало только при таком варианте кода:

Код:

Function myGuiInit
FindWindow $0 "#32770" "" $HWNDPARENT
GetDlgItem $0 $HWNDPARENT 1028
EnableWindow $0 1
Linker::link /NOUNLOAD $0 "http://www.forum.oszone.net/ "
FunctionEnd

Function .onGUIEnd
Linker::unload
FunctionEnd

[Flix]

Всё равно не получается брендинг-текст кликабельным. »

Что у вас опять не получается? Вот держите пример сценария:

PHP код:

; NSIS v3.0b - Modern User Interface (MUI2)

; Пример создания кликабельной фирменной надписи при помощи плагина Linker v1.2



#--------------------------------

# Заголовочные файлы



  ; Подключаем тип интерфейса Modern UI

  !include "MUI2.nsh"



#--------------------------------

# Параметры инсталлятора



  ; Название

  Name "$\"Кликабельная надпись$\""

  ; Имя файла

  OutFile "CBL-MUI.exe"

  ; Каталог установки по умолчанию

  InstallDir "$LOCALAPPDATA\Modern UI Test"

  ; Уровень привилегий инсталлятора для Windows Vista

  RequestExecutionLevel user

  

  ; Фирменная надпись

  BrandingText "Моя фирменная надпись" 



#--------------------------------

# Параметры интерфейса

  

  ; Подтверждать отмену установки

  !define MUI_ABORTWARNING

  ; Трехстрочная надпись в заголовке диалога приветствия

  !define MUI_WELCOMEPAGE_TITLE_3LINES



#--------------------------------

# Диалоги инсталлятора



  ; Выполняем подключение плагина для создания кликабельной надписи

  ; при инициализации графической оболочки инсталлятора

  !define MUI_CUSTOMFUNCTION_GUIINIT BrandLink

  

  ; ИНСТАЛЛЯЦИЯ

  !insertmacro MUI_PAGE_WELCOME

  !insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"

  !insertmacro MUI_PAGE_COMPONENTS

  !insertmacro MUI_PAGE_DIRECTORY

  !insertmacro MUI_PAGE_INSTFILES

  !insertmacro MUI_PAGE_FINISH

  

  ; Устанавливаем файл GUI, в котором для элемента управления ID=1028

  ; (фирменная надпись) удалено свойство WS_DISABLED (отключен)

  ChangeUI all "${NSISDIR}\Contrib\UIs\modern_modl.exe"



#--------------------------------

# Язык инсталлятора



  !insertmacro MUI_LANGUAGE "Russian"

  

#--------------------------------

# Секции инсталлятора



Section "Dummy Section" SecDummy



SectionEnd



#--------------------------------

# Описание секций



  ; Строка с текстом описания

  LangString DESC_SecDummy ${LANG_RUSSIAN} "Тестовая секция."



  ; Выводим строку в поле описания секции

  !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN

    !insertmacro MUI_DESCRIPTION_TEXT ${SecDummy} $(DESC_SecDummy)

  !insertmacro MUI_FUNCTION_DESCRIPTION_END

  

# ===============================

# ФУНКЦИИ ИНСТАЛЛЯТОРА

# ===============================



Function .onInit

  ; Инициализация каталога плагинов

  InitPluginsDir

  SetOutPath $PLUGINSDIR

FunctionEnd



# Функция инициализации графической оболочки инсталлятора

Function BrandLink

  GetDlgItem $0 $HWNDPARENT 1028

  ; Вызов библиотеки Linker для создания кликабельной URL-ссылки

  Linker::link /NOUNLOAD $0 "http://forum.oszone.net/thread-248731-132.html"

FunctionEnd



# Функция выгрузки графической оболочки инсталлятора

Function .onGUIEnd

  Linker::unload

FunctionEnd

# =============================== 

Скомпилируйте и проверьте. При необходимости сделайте в сценарии изменения под свою программу.
P.S. На офсайте для ANSI версии плагина Linker v1.2 ошибочно выложена Unicode версия. Поэтому используйте плагин из моего архива (см. сообщение 1309).

[MKN]

Определить версию ( VerifyOSVersion ) новой Windows 10 (как и предыдущие версии ОС ) можно с помощью StdUtils
автор LoRd_MuldeR
http://sourceforge.net/projects/muld...3.zip/download

[MaGoth]

kotkovets,
Не выходило случаем еще обновок для winver2.nsh, по части определения версий для Win 8/8.1/9/10 ?!

[kotkovets]

Не выходило случаем еще обновок для winver2.nsh, по части определения версий для Win 8/8.1/9/10 ?! »

а че телится сразу к Win 8-100 сделаю ))

[Flix]

Встречаем NSIS v3.0b1.
Что нового (изменилось, добавлено) - читаем здесь. Загрузить релиз можно с оффсайта. Отчеты об ошибках сообщаем на форум NSIS.

[Serg866]

Flix, благодарю за готовый скрипт.
Однако, есть баг: Если нажать на ссылку, а потом перейти обратно к окошку инсталлятора, то ссылку "колбасит". На картинке видно что с ней происходит)
У меня WinXP


К сожалению с таким багом не смогу использовать кликабельный брендинг-текст в своём инсталляторе.

Может быть подскажете возможно ли просто ссылку сделать кликабельной в тексте на страницах установщика?

Например текст:
Рекомендуем посетить сайт ввв.мояпрога.ру и чтобы текст ввв.мояпрога.ру был кликабелен?
Не могу никак с этим плагином разобраться(
А сам НСИС текст ссылок в линки не преобразовывает. В справочнике тоже нет инфы о том как ссылки добавлять в текст. Вроде НСИСу уже лет 10, а таких элементарных возможностей почему-то нет...

[MKN]

Serg866,
Попробуй плагин BrandingURL http://nsis.sourceforge.net/BrandingURL_plug-in
Linker плаг всегда странно работал... ( Хотя для этого дела плагин и не оч то нужен. Достаточно ExecShell "open" "http://....." с соответствующей "обвязкой" )

Код:

OutFile BrandingURL_test.exe
!include "MUI2.nsh" 
BrandingText "BrandingURL" 

!define MUI_CUSTOMFUNCTION_GUIINIT onGUIInit 
!insertmacro MUI_PAGE_WELCOME 
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt" 
!insertmacro MUI_PAGE_COMPONENTS 
!insertmacro MUI_PAGE_DIRECTORY 
!insertmacro MUI_PAGE_INSTFILES 
!insertmacro MUI_PAGE_FINISH 
!insertmacro MUI_LANGUAGE "Russian" 
InstallDir "$TEMP" 

Function onGUIInit 
BrandingURL::Set /NOUNLOAD "255" "0" "0" "http://nsis.sourceforge.net/Main_Page" 
FunctionEnd 

Function .onGUIEnd 
BrandingURL::Unload 
FunctionEnd

Section
SectionEnd

Вроде НСИСу уже лет 10, а таких элементарных возможностей почему-то нет... »

Всё давно придумано и давно на форуме расписано. Не хочешь плагин, хочешь кликабельный текст с твоей страницей или кликабельную картинку с твой лэйбой, причём в любом месте страницы - на здоровье, код в теме был. Другое дело, это получится более громоздко...