CMD/BAT - Поиск строки по слову и добавление новой строки после найденой.

Iska · Отправлено: **00:06, 26-05-2013** | #2

Пробуйте:

Mikhael2011 · Отправлено: **00:19, 26-05-2013** | #3

Супер! Спасибо большое!
Работает!
Единственно, что добавляет запись в ту же строку.
Попробую добавить перевод строки.

еще раз благодарю!

Iska · Отправлено: **00:54, 26-05-2013** | #4

Цитата Mikhael2011:

Единственно, что добавляет запись в ту же строку. »

Э… Я понял фразу:

Цитата Mikhael2011:

и добавить после каждой такой строки строку с определенным текстом. »

именно как «добавить в конец той же строки».

Пробуйте:

Mikhael2011 · Отправлено: **01:12, 26-05-2013** | #5

Теперь просто идеально.
Не знаю как и благодарить.
Вы мне очень помогли. Спасибо!

Mikhael2011 · Отправлено: **02:07, 26-05-2013** | #6

К сожалению возникла еще одна проблема.
Если в тексте встречается символ &, то батник, судя по всему, считает следующее за ним слово командой.
И соответственно в каждом случае выдает сообщение, что это не является внутренней или внешней командой, исполняемым или пакетным файлом.

Iska · Отправлено: **06:27, 26-05-2013** | #7

Mikhael2011, поздравляю! Вы созрели для WSH:

Код:

Option Explicit

Dim objFSO
Dim objTSSource
Dim objTSDest

Dim strString4Find
Dim strString4Append

Dim strSourceFile
Dim strTempFile
Dim strBackupFile

Dim strLine


If WScript.Arguments.Count = 3 Then
	With WScript.CreateObject("Scripting.FileSystemObject")
		strSourceFile = .GetAbsolutePathName(WScript.Arguments.Item(0))
		
		If .FileExists(strSourceFile) Then
			strString4Find   = WScript.Arguments.Item(1)
			strString4Append = WScript.Arguments.Item(2)
			
			strTempFile = GetTemporaryName()
			
			Set objTSSource = .OpenTextFile(strSourceFile)
			Set objTSDest   = .CreateTextFile(strTempFile)
			
			Do Until objTSSource.AtEndOfStream
				strLine = objTSSource.ReadLine()
				
				objTSDest.WriteLine strLine
				
				If InStr(1, strLine, strString4Find, vbTextCompare) > 0 Then
					objTSDest.WriteLine strString4Append
				End If
			Loop
			
			objTSDest.Close
			objTSSource.Close
			
			Set objTSDest   = Nothing
			Set objTSSource = Nothing
			
			strBackupFile = .BuildPath(.GetParentFolderName(strSourceFile), .GetBaseName(strSourceFile) & ".bak")
			
			.CopyFile strSourceFile, strBackupFile, True
			.CopyFile strTempFile, strSourceFile, True
		Else
			WScript.Echo "Can't find source file [" & strSourceFile & "]."
		End If
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Source file> <String for find> <String for append>"
End If

WScript.Quit 0

'=============================================================================
' Серый форум / vbscript: генерация пути для временного файла или папки
' (http://forum.script-coding.com/viewtopic.php?id=1221)
'=============================================================================
Function GetTemporaryName()
	Const TemporaryFolder = 2
	
	Dim strTempName
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		Do
			strTempName = .BuildPath(.GetSpecialFolder(TemporaryFolder), .GetTempName)
		Loop While .FileExists(strTempName) Or .FolderExists(strTempName)
	End With
	
	GetTemporaryName = strTempName
End Function
'=============================================================================

Georgio · Отправлено: **15:35, 26-05-2013** | #8

Код:

@ECHO OFF
SET File=My_File.txt
FOR /F "tokens=1* delims=:" %%I IN ('FINDSTR /N /R . %File%') DO (
 ECHO %%J|((FINDSTR DBXL>nul&&ECHO %%J>>New_File.txt&&ECHO ;VSTAVKA>>New_File.txt)||ECHO %%J>>New_File.txt)
)
REN %File% %File%.old&&REN New_File.txt %File%

К сожалению, зтот скрипт также "чувствителен" к символу "&". Но эту проблему можно решить, заменив при помощи "Блокнота" все символы "&" в тексте на какой-нибудь другой символ, который не встречается в тексте, или на сочетание символов, которое точно не будет фигурировать в тексте, а после применения скрипта в полученном тексте поменять этот символ или это сочетание символов снова на "&". Только не используйте для замены символы "%", "^", "|" и. т. п., так как они также могут привести к аналогичной ошибке.

Кстати, ещё возникала проблема с точкой с запятой (";") в начале строк, но она была решена.

Iska · Отправлено: **18:55, 26-05-2013** | #9

Цитата Georgio:

возникала проблема с точкой с запятой (";") »

Код:

"eol="

В документации ни Windows XP, ни Windows 7 об этом не сказано, но действует умолчание — «;»: For /f - Loop through text | SS64.com.

Georgio · Отправлено: **03:46, 27-05-2013** | #10

"Поборол" "противный" амперсанд (&), а заодно и большинство других "нежелательных" символов. При данном методе "выжили" только кавычки ("), да и то непарные (парные кавычки в середине строк корректно реплицируются, а вот по краям строк "самоликвидируются", что тоже не очень хорошо). Остались также нерешенными проблемы репликации пустых строк и пробелов в начале строк (в т. ч. строк, состоящих из пробелов). Думаю их можно решить другими методами.

Код:

@ECHO OFF
SET File=My_File.txt
FOR /F "tokens=1* delims=:" %%I IN ('FINDSTR /N /R . %File%') DO ((
SET /P "VAR=%%J" 0>nul|FINDSTR DBXL>nul&&((SET /P "VAR=%%J" 0>nul&ECHO.&ECHO ;VSTAVKA)>>New_File.txt))||((SET /P "VAR=%%J" 0>nul&ECHO.)>>New_File.txt
))
REN %File% %File%.old&&REN New_File.txt %File%