[Iska]

* это примерно этот скрипт? »

Именно что «примерно».

запускаю скрипт »

Как именно «запускаю»?

создается папка с именем машины(для примера лада) »

Где будет создаваться каталог с именем машины (учитывая то, что полного пути в буфере обмена нет)?

[madars1]

есть каталог "коллекция" (путь: f:\модели\машины\коллекция\ )
скрипт name.vbs будет лежать в каталоге коллекция (запускать буду в окне total commander )
каталог будет создаваться в папке коллекция ( f:\модели\машины\коллекция\)

[Iska]

madars1, ага, теперь ясно — заранее известный каталог, это другое дело.

Особого смысла в:

что бы в этот текстовый файл вставился полный путь в свежесозданную папку »

я не вижу, но как скажете:

Скрытый текст

"C:\Мои проекты\0248\0003.vbs"

Код:

Option Explicit

Const strParentPath = "C:\Мои проекты\0248"
'Const strParentPath = "F:\модели\машины\коллекция"

Dim strClipboardContent

Dim strSourceFolder
Dim objFolder

Dim strSourceFile


With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists(strParentPath) Then
		strClipboardContent = Trim(WScript.CreateObject("htmlfile").parentWindow.clipboardData.getData("text"))
		strSourceFolder = .BuildPath(strParentPath, strClipboardContent)
		
		If Not .FolderExists(strSourceFolder) Then
			Set objFolder = .CreateFolder(strSourceFolder)
		Else
			Set objFolder = .GetFolder(strSourceFolder)
		End If
		
		strSourceFile = .BuildPath(objFolder.Path, strClipboardContent & ".txt")
		
		If Not .FileExists(strSourceFile) Then
			With .CreateTextFile(strSourceFile)
				.WriteLine objFolder.Path
				.Close
			End With
		End If
		
		With WScript.CreateObject("Shell.Application")
			.Explore objFolder.Path
			.NameSpace(objFolder.Path).Items.Item(strClipboardContent & ".txt").InvokeVerb("Open")
			WScript.Sleep 1000
		End With
		
		Set objFolder = Nothing
	Else
		WScript.Echo "Can't find source path [" & strParentPath & "]."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

Замените мои пути своими.

[madars1]

Выдает ошибку (сделал на всякий случай тестовый каталог как у вас)

Как я делал:
1. total commander \ меню тотала командера \ настройка меню "'запуск" \ там указал директорию к скрипту

тело скрипта

Код:

Option Explicit

Const strParentPath = "c:\Мои проекты\0248\"
'Const strParentPath = "F:\\\"

Dim strClipboardContent

Dim strSourceFolder
Dim objFolder

Dim strSourceFile


With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists(strParentPath) Then
		strClipboardContent = Trim(WScript.CreateObject("htmlfile").parentWindow.clipboardData.getData("text"))
		strSourceFolder = .BuildPath(strParentPath, strClipboardContent)
		
		If Not .FolderExists(strSourceFolder) Then
			Set objFolder = .CreateFolder(strSourceFolder)
		Else
			Set objFolder = .GetFolder(strSourceFolder)
		End If
		
		strSourceFile = .BuildPath(objFolder.Path, strClipboardContent & ".txt")
		
		If Not .FileExists(strSourceFile) Then
			With .CreateTextFile(strSourceFile)
				.WriteLine objFolder.Path
				.Close
			End With
		End If
		
		With WScript.CreateObject("Shell.Application")
			.Explore objFolder.Path
			.NameSpace(objFolder.Path).Items.Item(strClipboardContent & ".txt").InvokeVerb("Open")
			WScript.Sleep 1000
		End With
		
		Set objFolder = Nothing
	Else
		WScript.Echo "Can't find source path [" & strParentPath & "]."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

Выдает ошибку:

[Iska]

Давайте попробуем вывести путь нашего каталога:

Код: strSourceFolder = .BuildPath(strParentPath, strClipboardContent) WScript.Echo "[" & strSourceFolder & "]" If Not .FolderExists(strSourceFolder) Then

[madars1]

Давайте попробуем вывести путь нашего каталога: »

Извините пожалуйста, а куда вышеприведенный код вставлять?

[Iska]

madars1, выделенное вставить между двумя невыделенными инструкциями.

[madars1]

что у меня получилось

Код:

Option Explicit

Const strParentPath = "c:\Мои проекты\0248\"

Dim strClipboardContent

Dim strSourceFolder
Dim objFolder

Dim strSourceFile


With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists(strParentPath) Then
		strClipboardContent = Trim(WScript.CreateObject("htmlfile").parentWindow.clipboardData.getData("text"))
		strSourceFolder = .BuildPath(strParentPath, strClipboardContent)
		
		WScript.Echo "[" & strSourceFolder & "]"
		
		If Not .FolderExists(strSourceFolder) Then
			Set objFolder = .CreateFolder(strSourceFolder)
		Else
			Set objFolder = .GetFolder(strSourceFolder)
		End If
		
		strSourceFile = .BuildPath(objFolder.Path, strClipboardContent & ".txt")
		
		If Not .FileExists(strSourceFile) Then
			With .CreateTextFile(strSourceFile)
				.WriteLine objFolder.Path
				.Close
			End With
		End If
		
		With WScript.CreateObject("Shell.Application")
			.Explore objFolder.Path
			.NameSpace(objFolder.Path).Items.Item(strClipboardContent & ".txt").InvokeVerb("Open")
			WScript.Sleep 1000
		End With
		
		Set objFolder = Nothing
	Else
		WScript.Echo "Can't find source path [" & strParentPath & "]."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

1. теперь после запуска скрипта выскакивает сначала это:



2. а затем вот это:

[mwz]

madars1

"— Пролетаем Баден-Баден.
— Ну чо мы, лохи что ли? Зачем два раза-то повторять??"

Обратите внимание на свой первый скриншот.