[shadowbat]

правда что то я не расмотрел там 800 ссылок

на одном 1990 ссылок, на втором около 3000 ссылок
главное, что нашли решение - уверен не только мне пригодится, ибо я в сети ничего подходящего за день не нашел. благо OAC облегчает копирование самих ссылок со страниц

[shadowbat]

читать дальше »

Dim $aUrl = StringSplit( _ 'http://iqcomp.ru/v/e2545|' & _ 'http://teachvideo.ru/v/5471', _ '|') $sLinks = "" For $i = 1 To $aUrl[0] $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i])) $sLinks &= StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1') & @CRLF Next $sLinks = StringStripWS($sLinks, 3) ;В буфер обмена ClipPut($sLinks) ;В файл FileWrite(@ScriptDir & '\MySuperLinks.txt', $sLinks)

тяжко забивать все ссылки
как сделать, чтобы ссылки брались из txt-списка? (в той же папке, где сам .au3 находится)

[madmasles]

shadowbat,
Пример файла со списком ссылок приведите.

[shadowbat]

обычный файл

[madmasles]

shadowbat,
Попробуйте так:

Код:

#include <Array.au3>

Dim $aUrl[1]
$j = 0
$sFile = @ScriptDir & '\list.txt'

$hFile = FileOpen($sFile, 0)
$sText = FileRead($hFile)
FileClose($hFile)

$aUrlTemp = StringSplit($sText, @LF)

For $i = 1 To $aUrlTemp[0]
    If StringInStr($aUrlTemp[$i], 'http:') Then
        $j += 1
        ReDim $aUrl[UBound($aUrl) + 1]
        $aUrl[$j] = StringStripWS(StringStripCR($aUrlTemp[$i]), 8)
    EndIf
Next
$aUrl[0] = UBound($aUrl) - 1
_ArrayDisplay($aUrl)

[Creat0R]

как сделать, чтобы ссылки брались из txt-списка? »

Код:

Dim $aUrl = StringSplit(StringStripCR(FileRead(@ScriptDir & "\List.txt")), @LF)

[madmasles]

Creat0R,
А если есть пустые строки или случайные пробелы в ссылках или в конце строки со ссылкой?
Как-то , наверное, можно ссылки через StringRegExp() выдрать.

[shadowbat]

1. я неправильный список дал, уже с готовыми ссылками, а не с первичными. правильный прикрепил

2. madmasles, я не те ссылки дал, ваш скрипт их просто копирует в окошко и выдает пользователю, не пропуская их через сайт
нужен ведь аналог этого,

читать дальше »

Код:

Dim $aUrl = StringSplit( _
        'http://iqcomp.ru/v/e2545|' & _
        'http://teachvideo.ru/v/5471', _
        '|')

$sLinks = ""

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $sLinks &= StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1') & @CRLF
Next

$sLinks = StringStripWS($sLinks, 3)

;В буфер обмена
ClipPut($sLinks)

;В файл
FileWrite(@ScriptDir & '\MySuperLinks.txt', $sLinks)

только с забором ссылок для посылки на сайт не из самого тела скрипта, а из внешнего файла. что похоже и сделал Creat0R

3. Creat0R
подставил строку,

читать дальше »

Код:

Dim $aUrl = StringSplit(StringStripCR(FileRead(@ScriptDir & "\List.txt")), @LF)

$sLinks = ""

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $sLinks &= StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1') & @CRLF
Next

$sLinks = StringStripWS($sLinks, 3)

;В буфер обмена
ClipPut($sLinks)

;В файл
FileWrite(@ScriptDir & '\MySuperLinks.txt', $sLinks)

выдается странный MySuperLinks.txt в итоге. прикрепил к сообщению
(похоже копирует код html странички. в принципе можно брать из него ссылки из самого начала, а остальной код удалять )

[Creat0R]

Как-то , наверное, можно ссылки через StringRegExp() выдрать. »

Код:

Dim $aUrl = StringSplit(StringStripWS(StringRegExpReplace(FileRead(@ScriptDir & "\List.txt"), '(?s).*?(https?://.*?)\r?\n.*?', '\1' & @LF), 3), @LF)

выдается странный MySuperLinks.txt в итоге »

Там видимо содержимое страницы, можно добавить “предохранитель” от подобных ситуаций:

Код:

Dim $aUrl = StringSplit(StringStripWS(StringRegExpReplace(FileRead(@ScriptDir & "\List.txt"), '(?s).*?(https?://.*?)\r?\n.*?', '\1' & @LF), 3), @LF)

$sLinks = ""

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $sLink = StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1')

    If @extended > 0 And $sLink <> $sHtml Then
        $sLinks &= $sLink & @CRLF
    EndIf
Next

$sLinks = StringStripWS($sLinks, 3)

;В буфер обмена
ClipPut($sLinks)

;В файл
FileWrite(@ScriptDir & '\MySuperLinks.txt', $sLinks)

[shadowbat]

Creat0R
Благодарю! то, что нужно