[alpap]

Код:

:: На powershell
@echo off
powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()">"file.txt"
exit

Код:

:: На javascript
@echo off
call :# "file.txt"
exit

:#
 mshta "javascript:var x=clipboardData.getData('text');if(x)new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(x);close();">"%~1"
exit /b

Код:

:: На Autoit
@echo off
Bufer_v.exe "file.txt"
exit

Файл 153025

в переменную

Код:

:: На powershell
@echo off
for /f "delims=" %%a in ('powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()"') do echo %%a
pause

Код:

:: На javascript
@echo off
for /f "delims=" %%a in (
 'mshta "javascript:var x=clipboardData.getData('text');if(x)new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(x);close();"'
) do echo %%a
pause

Код:

:: На Autoit
@echo off
Bufer_v.exe $& <$ set /p z=& del $
echo %z%
pause

[Sisin]

:: На powershell @echo off powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()">"file.txt" exit »

Это я находил в поиске. Я не знаю, как это применить к решению задачи.

[alpap]

как это применить »

добавил выше - в переменную

[Sisin]

А как эту переменную скормить curl??

[Iska]

А как эту переменную скормить curl?? »

Для этого было бы желательно понять, в каком месте в командной строке curl.exe Вы планируете её использовать. Предположим, что у Вас есть такая переменная, назовём её, допустим, sVar. Как будет выглядеть командная строка curl.exe с нею?

Где находится:

…свое место. »

?

[Sisin]

Как будет выглядеть командная строка curl.exe с нею? »

curl http://favicon.yandex.net/favicon/oszone.net/ -o "oszone.net.png"

sVar на месте oszone.net

[Iska]

Например:

Код:

@echo off
for /f "delims=" %%a in ('powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()"') do set sVar=%%a
if defined sVar curl.exe http://favicon.yandex.net/favicon/%sVar%/ -o "%sVar%.png"

или:

Код:

@echo off
for /f "usebackq delims=" %%a in (
	`mshta.exe "javascript:var x=clipboardData.getData('text');if(x)new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(x);close();"`
) do set sVar=%%a
if defined sVar curl.exe http://favicon.yandex.net/favicon/%sVar%/ -o "%sVar%.png"