[Georgio]

Любой язык - проверка наличия файла в директории

проверял наличие браузера Mozilla Firefox »

Так что нужно проверять: наличие файла в директории или наличие установленной программы? Если нужно проверять наличие файла в директории, то какого файла и в какой директории?

[icetanker]

Georgio, нужно запускать сайт в Mozilla Firefox,а если его нету,то в Internet Explorer,независимо,есть ли другие браузеры и игнорируя браузер по умолчанию

[Iska]

На WSH:

читать дальше »

Код:

Option Explicit

Const HKEY_LOCAL_MACHINE = &H80000002


Dim strUrl

Dim strCurrentVersion
Dim strPathToExe

Dim boolFound


strUrl = "http://www.ya.ru"

With WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\default").Get("StdRegProv")
	boolFound = False
	
	If .GetStringValue(HKEY_LOCAL_MACHINE, "SOFTWARE\Mozilla\Mozilla Firefox", "CurrentVersion", strCurrentVersion) = 0 Then
		If .GetStringValue(HKEY_LOCAL_MACHINE, "SOFTWARE\Mozilla\Mozilla Firefox\" & strCurrentVersion & "\Main", "PathToExe", strPathToExe) = 0 Then
			If WScript.CreateObject("Scripting.FileSystemObject").FileExists(strPathToExe) Then
				boolFound = True
				
				WScript.CreateObject("WScript.Shell").Run """" & strPathToExe & """ """ & strUrl & """", 1, 0
			Else
				WScript.Echo "Can't find [" & strPathToExe & "]."
			End If
		Else
			WScript.Echo "Can't get [PathToExe] parameter from [HKLM\SOFTWARE\Mozilla\Mozilla Firefox\" & strCurrentVersion & "\Main] subkey of registry."
		End If
	Else
		WScript.Echo "Can't get [CurrentVersion] parameter from [HKLM\SOFTWARE\Mozilla\Mozilla Firefox] subkey of registry."
	End If
End With

If Not boolFound Then
	With WScript.CreateObject("InternetExplorer.Application")
		.Visible = True
		.Navigate strUrl
	End With
End If

WScript.Quit 0

[icetanker]

Iska, токо почему то мозилла есть на компьютере,а он пишет Can't get [PathToExe] parameter from [HKLM\SOFTWARE\Mozilla\Mozilla Firefox\" & strCurrentVersion & "\Main] subkey of registry
и не запускает в ней?почему?

[Iska]

почему? »

Потому что:

Can't get [PathToExe] parameter from [HKLM\SOFTWARE\Mozilla\Mozilla Firefox\" & strCurrentVersion & "\Main] subkey of registry »

Во-первых, что-то не верится, что пишет именно так. Ну, никак не может. Нажмите Ctrl-C в окне сообщения и вставьте текст сюда.

Во-вторых, даже по приведённому можно предположить, что у Вас отсутствует. Там ведь написано, чего не хватает. Также сообщите, какая у Вас ОС, её разрядность, какая версия Firefox, как и где установлена.

[icetanker]

Iska, windows 8 64 bit,остальное на скрине
http://forum.oszone.net/attachment.p...1&d=1413698746

[El Sanchez]

почему? »

icetanker, доступ через WMI к 32-разрядным разделам реестра из 64-разрядной системы немного по-другому делается:

Код:

...
Dim objCtx

strUrl = "http://www.ya.ru"

Set objCtx = CreateObject("WbemScripting.SWbemNamedValueSet")
objCtx.Add "__ProviderArchitecture", 32

With WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\default", "", "", "", "", 0, objCtx).Get("StdRegProv")
...

icetanker, вариант №2:

Код:

@Echo Off
Set URL=google.ru

Start "" /MIN cmd /c "Start "" firefox.exe -new-window %URL%||Start "" iexplore.exe %URL%"

[Iska]

El Sanchez, чей код возврата воспримет «||» — от первого «start», от «cmd.exe», от второго «start» или от «firefox.exe» ?

А теперь вопрос серьёзней: на x64 «AppPath» един для x64 и x86 приложений? Насколько я понимаю, нет. Использует ли x64-приложение данные из x86 раздела «AppPath»?

[El Sanchez]

чей код возврата воспримет «||» — от первого «start», от «cmd.exe», от второго «start» или от «firefox.exe» »

Iska, от второго «start». Или я что-то не знаю? Смайлик как бы напрягает .

на x64 «AppPath» един для x64 и x86 приложений? »

Iska, видимо, един, т.к. и х86-, и х64-приложения регистрируют себя в обоих разделах «App Paths».

Использует ли x64-приложение данные из x86 раздела «AppPath»? »

Iska, да, ведь разделы «App Paths» еще и синхронизированы.