[Iska]

Давайте потренируемся:

1. Зачем? «…и переменная my_file становится file3.format» не является ответом на данный вопрос.
2. Что делать, если файлов больше десяти? Больше десяти тысяч?
3. В каталоге присутствуют ещё какие-либо файлы?

[UnrealMalcolm]

Iska,

1. Переменная содержит название файла. Этот файл будет использоваться в строке запуска. Аля "start prog.exe -%my_file%"
2. Больше 1000 вряд ли будет, но больше 100 запросто. А что делать? Так же выводить их в консоль. Так как имена будут в алфавитном порядке, то найти нужный даже при 500 будет не проблемой.
3. Нет.


Давай те немного раскрою карты.

Есть код:

Код:

For /f "tokens=1-3 delims=/." %%a in ('date /t') do (set mydate=%%a-%%b-%%c)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a-%%b)
set day=%mydate:~0,2%
set month=%mydate:~3,2%
set year=%mydate:~6,4%
set record=%year%-%month%-%day%_%mytime%

Переменная record будет кое где в коде использоваться, в результате чего будут создаваться файлы формата %year%-%month%-%day%_%mytime%-кое_что_ещё

Как можно понять, сортировка будет такая: год-месяц-день-время, а значит, при алфавитной сортировке старые файлы будут верху, а новые - снизу. В общем сколько бы их не было, там сложно будет потеряться.

Как я говорил ранее, задача состоит в том, чтобы каждому файлу в папке присвоить номер, при выборе которого создавалась переменная, значение которой было бы названием этого самого файла.

[megaloman]

UnrealMalcolm,

А что делать? »

Выбирайте файл через GUI

Код:

@Echo Off
Cls

For /f "tokens=2 delims=:" %%i in ('chcp') do (Set "sPrevCP=%%i" &>nul Chcp 1251)

For /f "usebackq delims=" %%i in (
	`@"mshta.exe" "about:<FORM><INPUT type='file' name='qq'></FORM><script>document.forms[0].elements[0].click();var F=document.forms[0].elements[0].value;try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(F)};catch (e){};close();</script>"`
) Do Set "sFileName=%%i"

>nul Chcp %sPrevCP%

if Defined sFileName (Echo Выбран файл: "%sFileName%") Else (Echo Файл не был выбран)

Pause
Exit /B 0

И только на рассвете, когда дописаны были последние строки, я вспомнил, что этот стих уже написал А. Пушкин. Такой удар со стороны классика!

[UnrealMalcolm]

megaloman, в целом, решение не плохое! Спасибо!

Правда не могли бы вы ещё мне помочь, как сделать, чтоб окно выбора файла открывалось в определенной директории? И как сделать, чтоб переменная имела не путь до файла, а только его название?


Хотя конечно решение без mshta.exe тоже было бы не плохо. Всё же хочется задействовать минимум программ.

[megaloman]

чтоб окно выбора файла открывалось в определенной директории »

Пока не знаю. Однако, после скрипта последний путь запоминается в системе.

И как сделать, чтоб переменная имела не путь до файла, а только его название »

Код:

@Echo Off
Cls

For /f "tokens=2 delims=:" %%i in ('chcp') do (Set "sPrevCP=%%i" &>nul Chcp 1251)

For /f "usebackq delims=" %%i in (
	`@"mshta.exe" "about:<FORM><INPUT type='file' name='qq'></FORM><script>document.forms[0].elements[0].click();var F=document.forms[0].elements[0].value;try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(F)};catch (e){};close();</script>"`
) Do Set "FileName=%%~nxi"  &Set "PathFileName=%%~dpi"

>nul Chcp %sPrevCP%

if Defined FileName (Echo Выбран файл: "%FileName%"  "%PathFileName%") Else (Echo Файл не был выбран)

Pause
Exit /B 0

[UnrealMalcolm]

Пока не знаю. Однако, после скрипта последний путь запоминается в системе. »

Тогда, к сожалению, такой вариант не подойдёт. Нужно чтоб сразу работа производилась в нужной директории.

[UnrealMalcolm]

В общем я своего добился. Правда получился какой-то говно код, но он работает. Единственный косяк - долго работает цикл. В целом за секунд 10 он покажет ~500 файлов. Но всё же хотелось бы что это было моментально.

Сам код получился таким:

Код:

@Echo Off
set file=11122.txt

dir /b /a-d "C:\Users\Admin\Desktop\ttt\*" > %file%

for /f "usebackq" %%S in (`find /c /v ""^<"%file%"`) do (set /a last_number=%%S)

set num=1
:start_add_pref
for /f "tokens=*" %%i in ('more +%num% "%file%"') do (echo %num% - %%i&goto next)
:next
set /a num=%num%+1
if %num%==%last_number% (goto:end_add_pref) else (goto:start_add_pref)

:end_add_pref
set /p file_select="-> "
for /f "tokens=*" %%i in ('more +%file_select% "%file%"') do (set my_file=%%i&goto final)

:final
del "%file%" 2>NUL
echo my file is %my_file%

pause

Если всё же кто-то подскажет как его ускорить - буду благодарен. Если нет, то "и так сойдёт".

[Iska]

Если всё же кто-то подскажет как его ускорить… »

Не очень понял Ваш код.

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFolder=C:\Users\Admin\Desktop\ttt

>nul 2>&1 pushd "%sSourceFolder%" && (
	set /a iCount = 0
	echo ---------------------------------------------
	
	for /f "usebackq delims=" %%i in (`2^>nul dir /b /a:-d "*.*"`) do (
		set /a iCount += 1
		set sCount=      !iCount!
		set "aChoice!iCount!=%%~i"
			
		echo !sCount:~-6!. %%~i
	)
	
	echo ---------------------------------------------
	set /p sChoice=Enter number of file: 
	echo.
	
	popd
) || (
	echo Can't find folder [%sSourceFolder%].
	exit /b 1
)

if defined aChoice%sChoice% echo [!aChoice%sChoice%!]

endlocal
exit /b 0

Если без выравнивания — можно и короче.

[UnrealMalcolm]

Iska, супер! Прям что нужно, спасибо! Правда до последнего хотел избегать setlocal, но что поделать...