CMD/BAT

Iska · Отправлено: **14:32, 20-06-2017** | #2

Цитата rene:

В примерах часто встречаю такое: »

Покажите ссылки на эти примеры.

rene · Отправлено: **16:13, 20-06-2017** | #3

http://scriptcoding.ru/2013/08/20/fu...mandno-stroki/

Код:

@echo off
set var=d:\work\test.bat
call notepad.exe "%var%"
call calc.exe
dir
set var=

Раздел Процедуры. Дословно там написано "Учтите, что вы можете вызвать другую программу и без использования функции call, но в этом случае контроль над дочерним приложением будет утерян."

greg zakharov · Отправлено: **16:41, 20-06-2017** | #4

call никак не может управлять приложением, он лишь может запустить бинарник как пакетный файл и передать ему опредленные параметры, не более. В этом можно убедиться, разобрав код call в дизассемблере.

Iska · Отправлено: **16:42, 20-06-2017** | #5

Да, я вижу, что там именно так и написано. Другое дело, что фраза «контроль над дочерним приложением» бессмысленна по сути и по содержанию. Никакого «контроля» нет. Что с call, что без call. Вся разница заключается только в том, что при использовании call создаётся новый контекст текущего пакетного файла. Каким макаром это может обеспечить некий мифический контроль, а без него этот некий контроль «будет утерян» — остаётся на совести автора. Я лично не могу сказать по этому поводу ничего вразумительного.

Код вида:

Цитата:

Код:

if "%1"=="" (
echo Peredayte parametry scenariju!) & (goto EXIT)

можно смело именовать «убей себя апстену». Потому как должно быть либо:

Код:

if "%1"=="" (
    echo Peredayte parametry scenariju!
    exit /b 1
)

либо:

Код:

if "%1"=="" echo Peredayte parametry scenariju!& exit /b 1

Вместо «exit /b» может быть «goto :eof» — переход на скрытую метку конца пакетного файла — если нам, скажем, принципиально не важно возвращать родительскому процессу код завершения пакетного файла. Посему совершенно нет нужды ни в какой метке в конце пакетного файла. Тем паче, что давать меткам имена внутренних команд — моветон.

rene · Отправлено: **16:52, 20-06-2017** | #6

Большое спасибо за разъяснения

Iska · Отправлено: **17:18, 20-06-2017** | #7

Я, кажется, понял, в чём дело. Автор, как говорится, слышал звон, да не понял, где он, и, поскольку не разобрался — где, начал выдумать свою извращённую логику~~, с игрищами и блудницами~~.

rene, когда мы вызываем из пакетного файла X пакетный файл Y, и нам требуется, чтобы после завершения работы пакетного файла Y управление было возвращено в пакетный файл X, и его обработка продолжилась (а именно так обычно и бывает) — вот тут как раз и следует использовать call <Путь\Имя пакетного файла Y>.

Пример

X.cmd

Код:

@echo off

echo 1. [%~0]
call "Y.cmd"

echo 2. [%~0]
"Y.cmd"

echo 3. [%~0]

exit /b 0

Y.cmd

Код:

@echo off

echo 4.[%~0]

exit /b 0

Как видите, после вызова пакетного файла просто как «"Y.cmd"» — управление в пакетный файл X.cmd не возвращается, посему команда «echo 3. [%~0]» не выполняется.

rene · Отправлено: **18:49, 20-06-2017** | #8

Iska, Я правильно понимаю, что это справедливо только для пакетных файлов, а бинарники после выполнения в любом случае не остановят выполнение скрипта? И потому вызывать бинарник с помощью call не имеет никакого смысла?

Iska · Отправлено: **19:17, 20-06-2017** | #9

Цитата rene:

И потому вызывать бинарник с помощью call не имеет никакого смысла? »

Я не вижу.

rene · Отправлено: **19:23, 20-06-2017** | #10

Поясните пожалуйста конструкцию %~0 и чем она отличается от %0 ?