VBS/WSH/JS - Как определить масштаб изображения в процентах в PowerPoint при помощи VBA

Iska · Отправлено: **10:12, 10-02-2019** | #2

kosmonavtom, для начала хотелось бы понять, как выглядит «изменение размеров слайдов с 4:3 на 16:9»?

kosmonavtom · Отправлено: **20:22, 10-02-2019** | #3

Цитата:

как выглядит «изменение размеров слайдов с 4:3 на 16:9»?

В PowerPoint 2007 команда: Дизайн - Параметры страницы - Размер экрана.

Для наглядности, на всякий случай, сделал две презентации (см. вложения), изначально в размерах 4:3, потом перевел размер экрана (слайдов) в 16:9 рисунок добавленный в размерах 4:3 имел размер (масштаб) 54% на 54% а измененный стал: 41% на 54% вот у презентации 16:9 как то нужно получить вот эти проценты в переменные sHeightOld и sWidthOld. Вопрос: как?

Iska · Отправлено: **21:57, 10-02-2019** | #4

В общем, что я вижу.

1. В результате произведённого изменения пропорций произошло не «растягивание»:

Цитата kosmonavtom:

При изменении размеров слайдов с 4:3, на 16:9 в PowerPoint 2007 изображения растягиваются причем только по ширине слайдов презентации. »

изображений, а сжатие по высоте. Поэтому «растягивание» приведёт только к тому, что рисунки и объекты «уползут» за размеры слайда.

2. Ваш алгоритм работоспособен только при условии, что изображения, помещённые в презентацию изменялись строго пропорционально. Если же изображение до конвертации с 4:3 в 16:9 уже имело иные пропорции, нежели 1x1, что отнюдь не редкость — то весь алгоритм летит к чёрту.

Так что, я бы сделал иначе. Пробуйте:

Скрытый текст

Код:

Option Explicit

Sub ReScaleToHeight()
    Dim objSlide As Slide
    Dim objShape As Shape
    
    Dim intCurrentWidth As Integer
    Dim intCurrentHeigth As Integer
    
    Dim intOriginalWidth As Integer
    Dim intOriginalHeigth As Integer
    
    Dim sngAspectRatio As Single


    For Each objSlide In ActivePresentation.Slides
        For Each objShape In objSlide.Shapes
            With objShape
                If .Type = msoPicture Or .Type = msoEmbeddedOLEObject Then
                    intCurrentWidth = .Width
                    intCurrentHeigth = .Height
                    
                    .ScaleHeight CSng(1), msoTrue
                    .ScaleWidth CSng(1), msoTrue
                    
                    intOriginalWidth = .Width
                    intOriginalHeigth = .Height
                    
                    If intCurrentWidth / intOriginalWidth < intCurrentHeigth / intOriginalHeigth Then
                        sngAspectRatio = intCurrentWidth / intOriginalWidth
                    Else
                        sngAspectRatio = intCurrentHeigth / intOriginalHeigth
                    End If
                    
                    .ScaleHeight sngAspectRatio, msoTrue
                    .ScaleWidth sngAspectRatio, msoTrue
                End If
            End With
        Next
    Next
End Sub

Если всё же хотите по-своему — поменяйте в условии < на >.

kosmonavtom · Отправлено: **08:06, 11-02-2019** | #5

Доброе утро. Iska, во первых огромное спасибо за Ваш код! Все работает и это главное

Цитата:

1. В результате произведённого изменения пропорций произошло не «растягивание» изображений, а сжатие по высоте. Поэтому «растягивание» приведёт только к тому, что рисунки и объекты «уползут» за размеры слайда.

Да это я перепутал и увидел уже после отправки сообщения, но это меня и не волновало сильно.

Цитата:

2. Ваш алгоритм работоспособен только при условии, что изображения, помещённые в презентацию изменялись строго пропорционально. Если же изображение до конвертации с 4:3 в 16:9 уже имело иные пропорции, нежели 1x1, что отнюдь не редкость — то весь алгоритм летит к чёрту.

А) Алгоритм то может и работоспособен, но код нет. (( И можно ли взять и записать процент изображения в переменную я так и не понял. Но мне теперь уже это и не интересно - раз его можно найти другим способом.
Б) Какие пропорции изначально у изображения - не имеет значения, т.к. главное, чтобы оно стало таким-же как и было в презентации 4:3.

Еще раз спасибо.

Iska · Отправлено: **20:49, 11-02-2019** | #6

Цитата kosmonavtom:

И можно ли взять и записать процент изображения в переменную я так и не понял. »

kosmonavtom, нет-нкт, Вы всё правильно поняли — напрямую это значение недоступно (во всяком случае, в моей версии Microsoft Office). Посему, чтобы посчитать его, нужно запомнить текущие размеры, затем сбросить их в оригинальные, затем разделить одно на другое. Что-то подобное приходилось проделывать в первых версиях Automation под Adobe Photoshop, где не было возможности узнать размер существующего выделения (вот не было — и всё тут!), посему приходилось изворачиваться — делать Crop, затем получать размеры получившегося после обрезки изображения, принимать их за размер выделения, после чего исполнять операцию Undo. Вот такие извращения когда-то были в объектной модели Adobe Photoshop

.