[amel27]

ags555, вариант на VBS:

Код:

strRoot = "C:\Backup"                ' Путь к каталогу с архивами
strMask = "^(\d{2}\.){2}\d{4}\.zip$" ' Маска имени ZIP-файлов
intWeek = 2                          ' Время хранения файла (в неделях) 

Set objFSO    = CreateObject("Scripting.FileSystemObject")
Set objRegExp = CreateObject("VBScript.RegExp")
Set objRoot   = objFSO.GetFolder(strRoot)
Set colFiles  = objRoot.Files

objRegExp.Pattern = strMask
objRegExp.IgnoreCase = True

For Each objFile In colFiles
   If objRegExp.Test(objFile.Name) And _
     DateDiff("w", objFile.DateLastModified, Date)>=intWeek Then
     objFile.Delete
   End If
Next

[ags555]

Спасибо за то что откликнулись amel27, !!!
Попробую!!!
Разъясните что значит конструкция "^(\d{2}\.){2}\d{4}\.zip$" поподробнее, как я понял она отвечает за маску по которой будут фильтроваться файлы. Чтобы потом можно было самому задавать разные маски!!! Т.е. в зависимости от того какое имя у файла соответственно програмка судит следует его удалять или нет??? Правильно???

А параметр intWeek = 2 отвечает за давность??? Правильно??? т.е. если intWeek = 3 то програмка будет искать за 3 недели соответственно!!!

[amel27]

что значит конструкция "^(\d{2}\.){2}\d{4}\.zip$" »

Код:

^        начинаем проверку с начала строки
(        начало блока
  \d{2}  два знака "цифра"
  \.     один знак "точка"
){2}     конец блока, блок должен примениться дважды
\d{4}    четыре цифры
\.zip    расширение ".zip"
$        тут строка должна закончиться

полностью эквивалентная, но более простая маска: "^\d\d\.\d\d\.\d\d\d\d\.zip$"
для справки: http://ru.wikipedia.org/wiki/%D0%A0%...BD%D0%B8%D1%8F

т.е. если intWeek = 3 то програмка будет искать за 3 недели соответственно »

3 недели и более

[vitaliyboch]

Уже есть решение этого вопроса http://forum.oszone.net/thread-146190.html зачем писать сто раз одну и ту же проблему? Поиск по форуму использовать не судьба?

[ags555]

Спасибо за разъяснения amel27, !!!
А вас vitaliyboch, попрошу не разглогольствовать бестолку!!!