[amel27]

как вариант, хранить спецсимволы в переменной и использовать EnableDelayedExpansion:

Код:

@echo off
setlocal EnableDelayedExpansion

set "$q=""
set "$a="123"

if "!$a:~0,1!"=="!$q!" echo First letter is quote!

[Foreigner]

Код:

@echo off
setlocal

set "a="qwerty"
set "b=%a:~0,1%"
set "b=%b:"=%"

if not defined b echo the first simbol is `"`

[Dragokas]

amel27, можете пояснить, почему тот же код без использования DelayedExpansion выдает синтаксическую ошибку ?

[Iska]

Потому что раскрытие переменных происходит перед разбором строки, и в итоге выходит конструкция вида:

Код:

if """==""" (…) else (…)

на которой интерпретатор и спотыкается. В обратном же случае, сначала делается разбор «if», затем уже происходит отложенное раскрытие переменных окружения.

читать дальше »

По тому же самому принципу не удаётся напрямую использовать отложенное раскрытие переменных окружения, например, в предикатах «skip» и «tokens» команды «for /f» — к моменту разбора они ещё не будут раскрыты:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set /a iCount = 3

for /f "skip=!iCount!" %%i in (0001.txt) do echo %%i

endlocal
exit /b 0

[mavalog]

Есть еще такой вариант:

Код:

@echo off
setlocal

set "a="qwerty"

if "%a:~0,1%%a:~0,1%" == """" echo the first simbol is `"`