[megaloman]

Если тупо сплошная нумерация без учета сортировки по датам и подпапкам

Код:

@Echo Off
cls
	Set "BoxIn=Z:\Box_In"
	Set "Mask=VP-BAI_20*_*.tsc"
	Set "NewExt=txt"

	Set /A N=0
	FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:-D /S`) DO (
		FOR /F "tokens=1,2 delims=_" %%c IN ("%%~nf") DO Call :MyRen "%%f" "%%c" "%%d"
	)
Exit /B

:MyRen
	Set /A N+=1
	Set "dd=%~3"
	Ren %1 "%~2_%dd:~6,2%.%dd:~4,2%.%dd:~0,4%.%N%.%NewExt%"
Exit /B

[megaloman]

Если переименовывать так, чтобы файлы нумеровались от более старой даты к более новой сплошняком по всем папкам

Код:

@Echo Off
	Set "BoxIn=Z:\Box_In"
	Set "Mask=VP-BAI_20*_*.tsc"
	Set "NewExt=txt"

	FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:-D /S`) DO (
		FOR /F "tokens=1,2 delims=_" %%c IN ("%%~nf") DO Set "@@%%d=%%c_%%d_*%%~xf=%%c=%%d"
	)
	
	Set /A N=0
	FOR /F "usebackq tokens=2,3,4 delims==" %%a IN (`2^>nul Set "@@"`) DO (
		FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%BoxIn%\%%a" /B /A:-D /S`) DO (
			Call :MyRen "%%f" "%%b" "%%c" 
		)
	)
Exit /B
:MyRen
	Set /A N+=1
	Set "dd=%~3"
	Ren %1 "%~2_%dd:~6,2%.%dd:~4,2%.%dd:~0,4%.%N%.%NewExt%"
Exit /B

[alpap]

Вова.Неневолин@vk,

и нумерацию делает в скобках »

(мой код приведен в примере, потому и отвечаю)
на другом форуме в скобках вы именно и просили, сложно было попросить там переделать?

Код:

@echo off
set "d0=C:\Papka"
set "ext=txt"
 
for /f "delims=" %%d in ('dir /ad/b/s "%d0%"') do (
 pushd "%%d"
  for /f "tokens=1,2* delims=_" %%a in ('dir /a-d/b') do set /a n+=1& set "odt=%%b"& call :rn "%%a_%%b_%%c" "%%a" "%%n%%" "%ext%"
 popd
)
pause& exit
 
:rn
 set "d=%odt:~6,2%"& set "M=%odt:~4,2%"& set "yy=%odt:~2,2%"
 ren "%~1" "%~2_%d%.%M%.%yy%.%~3.%~4"
exit /b