[Iska]

И много слов?

[MultiGramen]

6 слов.

[Iska]

На WSH:

Скрытый текст

Код:

Option Explicit

Dim arrWords

arrWords = Array("A", "B", "C", "D", "E", "F")

PRGenerate 0

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub PRGenerate(ByVal intGeneration)
	Dim i
	
	If intGeneration < UBound(arrWords) Then
		For i = intGeneration To UBound(arrWords)
			SwapValues arrWords(intGeneration), arrWords(i)
			PRGenerate intGeneration + 1
			SwapValues arrWords(intGeneration), arrWords(i)
		Next
	Else
		For i = LBound(arrWords) To UBound(arrWords) - 1
			WScript.StdOut.Write arrWords(i) & " "
		Next
		
		WScript.StdOut.WriteLine arrWords(UBound(arrWords))
	End If
End Sub
'=============================================================================

'=============================================================================
Sub SwapValues(Var1, Var2)
	Dim SomeVar
	
	SomeVar = Var1
	Var1 = Var2
	Var2 = SomeVar
End Sub
'=============================================================================

Исполнять под консольным хостом. При желании можете сразу перенаправить вывод в файл, наподобие:

Код:

cscript.exe //nologo "C:\Мои проекты\10\My Script.vbs" >"Out.txt"