[gora]

Есть команда »

Уточните систему. У меня на ХР эта команда выдает

Ошибка: Неправильный параметр или аргумент - '/tn'. Введите "SCHTASKS /QUERY /?" для получения справки по использованию.

В справке такой ключ отсутствует.

[Vadikan]

Уточните систему »

Конфигурация у меня заполнена, и мне не нужно для ХР Там и задания такого нет.

[Petya V4sechkin]

Vadikan, вот, на коленке:

Код:

@Echo Off
SetLocal EnableExtensions

For /F "Tokens=1* Skip=5 Delims=: " %%I In ('Schtasks /Query /Fo List /Tn Microsoft\Windows\Defrag\ScheduledDefrag') Do (
  Set Status=%%J
  GoTo ExitFor
)
:ExitFor
Echo Статус задания: %Status%

Проверял на русской 7 (на английской тоже должно работать).

[Vadikan]

Petya V4sechkin, спасибо, работает!

[amel27]

вот, на коленке »

так должно быть быстрей, переход по метке - очень медленная команда:

Код:

@echo off

for /f "tokens=1* delims=: " %%i in (
'schtasks /query /fo List /tn Microsoft\Windows\Defrag\ScheduledDefrag'
) do if /i "%%i"=="Status" set "STATUS=%%j"

echo Статус задания: %STATUS%
pause>nul

P.S. 7-ки под рукой нет проверить (

[Petya V4sechkin]

if /i "%%i"=="Status"

На русской 7 не получится.

[amel27]

На русской 7 не получится. »

для поддержки 2-го языка можно добавить ELSE IF, для SKIP может быть так:

Код:

@echo off

for /f "skip=5 tokens=1* delims=: " %%i in (
'schtasks /query /fo List /tn Microsoft\Windows\Defrag\ScheduledDefrag'
) do if not defined STATUS set "STATUS=%%j"

echo Статус задания: %STATUS%
pause>nul

...хотя из примера напрашивается SKIP=4...

[Petya V4sechkin]

хотя из примера напрашивается SKIP=4

Там еще пустая строчка в начале.

[Vadikan]

amel27, спасибо, так тоже работает.

Добавлю вариант на PowerShell от Василия Гусева

Код:

$tasks = [xml](schtasks /query /tn Microsoft\Windows\Defrag\ScheduledDefrag /xml one)
$($tasks.Task.settings.enabled)

Сам XML можно посмотреть командой в круглых скобках из первой строки, либо в не очень приглядном виде вывести так: $tasks.outerxml

Я всегда снизу вверх смотрю на гуру этого форума, которым по силу любые задачи на CMD/VBS, но нельзя не отметить, что работа PowerShell с XML значительно упрощает решение

Да, я помню, что задал категорией темы CMD, мне было нужно именно это, но теперь поменял на "разное".