CMD/BAT

gora · Конфигурация компьютера

IntuitOS, сделайте нуль-копии Ваших папок, заархивируйте и выложите их здесь.

Цитата IntuitOS:

переименовывает файлы в другой папке(E:\папка_2), по этому списку, но оставляя их исходное расширение(*.mp4). »

Непонятно. Берет первый попавшийся файл из "другой папки" и присваивает ему новое имя из списка? Ни как имена в списке и переименованные файлы сопоставлять не надо? А что делать, если число имен в списке и файлов в папке не совпадет в ту или иную сторону?

IntuitOS · Отправлено: **12:17, 28-03-2013** | #4

Цитата IntuitOS:

Ни как имена в списке и переименованные файлы сопоставлять не надо? А что делать, если число имен в списке и файлов в папке не совпадет в ту или иную сторону? »

Переименование файлов в список и обратно - часть другой большой задачи: сжатие большого количества несжатого архивного видео. Т.е. порядок действий такой: создаётся список с именами, файлы в папке Original переименовываются к общему виду с нумерацией, все файлы конвертируются, сконверченное видео сохраняется в папку Video и в ней нужно эти файлы переименовать обратно. Количество файлов будет таким же, ну а если переименование происходит в том же порядке, то сопоставлять по идее не надо.

Цитата gora:

сделайте нуль-копии Ваших папок »

не получается, где должна создаться эта копия?

вот слепил для наглядности:

gora · Конфигурация компьютера

Батник 1:

Код:

@Echo Off
:: Кодировка файла Кириллица DOS (866)
SetLocal EnableDelayedExpansion
Set folder=e:\Temp\Сжатие\DV\Original
Set list=files.txt

Del "%list%">Nul
Set cnt=0
For /F "tokens=* usebackq" %%a In (`Dir /B /A:-D "%folder%"`) Do (
	>>"%list%" Echo %%~na
	Set /A cnt +=1
	Set XX=0!cnt!
	Ren "%folder%\%%a" "Video_!XX:~-2!.avi"
)
Pause

Батник 2:

Код:

@Echo Off
:: Кодировка файла Кириллица DOS (866)
SetLocal EnableDelayedExpansion
Set folder=e:\Temp\Сжатие\DV\Video
Set list=files.txt

Set cnt=0
For /F "tokens=* usebackq" %%a In ("%list%") Do (
	Set /A cnt +=1
	Set XX=0!cnt!
	Set $var!XX:~-2!=%%a
)
Set cnt=0
For /F "tokens=* usebackq" %%a In (`Dir /B /A:-D "%folder%"`) Do Call :_ren "%%a"
Pause
Exit

:_ren
Set /A cnt +=1
Set XX=0!cnt!
Ren "%folder%\%~1" "!$var%XX:~-2%!%~x1"
GoTo :EOF

IntuitOS · Отправлено: **14:26, 28-03-2013** | #6

gora, спасибо огроменное, работает! Я только добавил

PHP код:


@chcp 1251

в начало(не понимал кириллицу) и свой путь прописал.
и без

PHP код:

if

в первом батнике обошлось))

Упс, заметил, 2 батник переименовывает не много не верно: он заменяет имя у файла с расширением avi, т.е. получается так:"1просто.avi.mp4"

Iska · Отправлено: **15:42, 28-03-2013** | #7

Цитата IntuitOS:

Я только добавил

Код:

@chcp 1251

в начало(не понимал кириллицу) »

Вместо этого надо сохранять пакетный файл в кодировке OEM/866.

gora · Конфигурация компьютера

Цитата IntuitOS:

Упс, заметил, 2 батник переименовывает не много не верно: он заменяет имя у файла с расширением avi, т.е. получается так:"1просто.avi.mp4" »

Не должно быть такого. Видимо Вы что-то меняли в первом батнике. Файл-список должен сохраняться в кодировке Кириллица DOS (866) и должен содержать только имена файлов без расширения.
Сами скрипты тоже должны быть сохранены в этой кодировке, если пути, которые Вы правите в них, содержат кириллицу.

IntuitOS · Отправлено: **16:36, 28-03-2013** | #9

Цитата gora:

и должен содержать только имена файлов без расширения. »

сорри, это мой косяк, я на всякий случай делал дубликат списка, прежде чем, bat-ы запускать, вообщем с ним и запутался.

Цитата Iska:

Вместо этого надо сохранять пакетный файл в кодировке OEM/866. »

с помощью NotePad++ это можно сделать? или как лучше?

Iska · Отправлено: **16:57, 28-03-2013** | #10

Цитата IntuitOS:

с помощью NotePad++ это можно сделать? »