[kero]

а неподскажете как:
есть список файлов , их следует заменить нулевым размером (изменить размер файла на 0 ) вместо удаления.

[Iska]

есть список файлов »

В чём? Если текстовый файл — в каком виде (с полными путями, относительными путями, без путей — тогда как определить, в каком каталоге эти файлы), в какой кодировке, какие концы строк?

[kero]

Iska,
текстовый файл , чистые полные пути , один путь-одна строка , кодировка анси .
пример
"C:\11\aa aa\Catalog\06.cab"
"C:\11\aa aa\Catalog\07.cab"
"C:\11\aa aa\Catalog\01.cab"

возможно вы имели ввиду что должен быть задействован текстовый файл, так то не обязательно, пути могу подставить в батнике , , просто интерисует как в пакетном файле выполнить такое.

[Iska]

kero, если ANSI — то лучше WSH:

Скрытый текст

Код:

Option Explicit

Dim strSourceFile

Dim objFSO
Dim strContent
Dim strLine


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FileExists(strSourceFile) Then
		With objFSO.OpenTextFile(strSourceFile)
			strContent = .ReadAll()
			.Close
		End With
		
		For Each strLine In Split(strContent, vbCrLf)
			If objFSO.FileExists(strLine) Then
				objFSO.CreateTextFile(strLine, True).Close
			Else
				WScript.Echo "Can't find file [" & strLine & "]."
			End If
		Next
	Else
		WScript.Echo "Can't find source file [" & strSourceFile & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0

Кавычки в файле не нужны. Путь к целевому файлу с путями к файлам задаётся параметром скрипта (также можно просто перетащить целевой файл на скрипт в Проводнике).

просто интерисует как в пакетном файле выполнить такое. »

При использовании кодировки OEM/866:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFile=%~1

if defined sSourceFile (
	if exist "%sSourceFile%" (
		for /f "usebackq delims=" %%i in ("%sSourceFile%") do (
			if exist "%%~i" (
				>nul copy /y nul "%%~i"
			) else (
				echo Can't find file [%%~i].
			)
		)
	) else (
		echo Can't find source file [%sSourceFile%].
	)
) else (
	echo Usage: %~nx0 ^<Source file^>
)

endlocal
exit /b 0

Путь к целевому файлу с путями к файлам задаётся параметром пакетного файла (также можно просто перетащить целевой файл на пакетный файл в Проводнике).

[kero]

Iska,
Спасибо