[Creat0R]

Пишу так »

Для начала заглините в справку, посмотрите синтаксис кода... «$Path = "E:\" $var = FileSaveDialog» это у вас ошибки не вызывает?

И к тому же FileSaveDialog возвращает полный путь к указанному файлу:

Код:

#include <Inet.au3>

$sSource = _INetGetSource("http://vkontakte.ru/index.php")

$R = 1
$Rezalt_name = "Rezalt" & $R

;MsgBox(0,"",$Rezalt_name)

$sPath = FileSaveDialog("Choose a name.", "", "(*.html)", 2 + 16, $Rezalt_name)
If @error Then Exit

If StringRight($sPath, 4) <> "html" Then $sPath &= ".html"

$hFileOpen = FileOpen($sPath, 2)
FileWrite($hFileOpen, $sSource)
FileClose($hFileOpen)

А если нужно тихо без диалога, то строчка с FileSaveDialog вовсе не нужна, а переменной $sPath присвоить значение от $Rezalt_name.

[Sestrichka]

на счет

«$Path = "E:\" $var = FileSaveDialog» это у вас ошибки не вызывает? »

Это у меня опечатка, в коде все в норме - все обзацы на месте.
Мне действительно без диалога вариант больше подходит, но и тот, и другой , к сожалению, в результате создали пустой файл (хотя и с нужным именем,и в нужной директории).
Можно ли иначе как-то сохранять фаилы? Особенно меня интересует, как сохранить html-страницу с картинками, чтоб ничего со страницы "не потерялось"?

[Creat0R]

Мне действительно без диалога вариант больше подходит »

Код:

#include <Inet.au3>

$sSource = _INetGetSource("http://vkontakte.ru/index.php")

$R = 1
$sPath = @ScriptDir & "\Rezalt" & $R
If StringRight($sPath, 4) <> "html" Then $sPath &= ".html"

$hFileOpen = FileOpen($sPath, 2)
FileWrite($hFileOpen, $sSource)
FileClose($hFileOpen)

как сохранить html-страницу с картинками, чтоб ничего со страницы "не потерялось"? »

Чтобы оно всё локально сохранилось? Это не так уж и просто, нужно будет парсить Html-код страницы и закачивать отдельно файлы.

[Iska]

Sestrichka, если требуется именно содержимое, как таковое, а не отдельные файлы (при использовании описанной ниже методики имена отдельных файлов теряются), то можно получать содержимое страницы и связанных файлов в виде .mht («Веб-архив» в терминологии Microsoft), используя библиотеку Collaboration Data Objects:

читать дальше »

Как правило, эта библиотека уже установлена, если у Вас установлен Microsoft Office 2000/XP/2003; если у Вас установлен Microsoft Office 2007 или вообще не установлен — то надо пройти по вышеуказанной ссылке, загрузить и установить эту библиотеку.

Код:

AutoItSetOption("MustDeclareVars", 1)

Local Const $cdoSuppressNone        =  0 ; Загружать все
Local Const $cdoSuppressImages      =  1 ; Не загружать картинки
Local Const $cdoSuppressBGSounds    =  2 ; Не загружать фоновые звуки
Local Const $cdoSuppressFrames      =  4 ; Не загружать фреймы
Local Const $cdoSuppressObjects     =  8 ; Не загружать объекты
Local Const $cdoSuppressStyleSheets = 16 ; Не загружать таблицы стилей
Local Const $cdoSuppressAll         = 31 ; Не загружать ничего из вышеперечисленного

Local Const $adSaveCreateNotExist   =  1
Local Const $adSaveCreateOverWrite  =  2


Local $objIMessage                  = ObjCreate("CDO.Message")
Local $objIConfiguration            = ObjCreate("CDO.Configuration")

Local $strURL                       = "http://www.yandex.ru"
Local $strUserName                  = ""
Local $strPassword                  = ""


$objIMessage.Configuration = $objIConfiguration
$objIMessage.CreateMHTMLBody($strURL, $cdoSuppressNone, $strUserName, $strPassword)

; Сохранить страницу как веб-архив .MHT
With $objIMessage.BodyPart.GetStream()
	.SaveToFile("c:\Page.mht", $adSaveCreateOverWrite)
	.Close()
EndWith

$objIConfiguration                  = 0
$objIMessage                        = 0

Exit(0)

Источник: Серый форум / JScript: Пример сохранения web-страницы в TXT, HTML и MHT (веб-архив).

[Sestrichka]

Спасибо большое за помощь, нашла более допотопненький вариант:
использую гарячии клавиши браузера.

Код:

Send("!Фк");сохранить файл
Send("!х") 
Sleep(1000)
Send("!ФЗ");закрыть файл

Единственное слабое место этого варианта - надо ставить задержки между командами, т.к. возможна ситуация, когда окошко еще не появилось, а скрипт уже шлет команду окну, которого по сути еще нет.

[Creat0R]

возможна ситуация, когда окошко еще не появилось, а скрипт уже шлет команду окну, которого по сути еще нет »

Для этого есть WinWait которое будет ждать появление нужно окна.

[adima]

Возникла проблема при сохранении содержимого интернет окна с помощью скрипта от Iska (см.три поста выше) сохраняет в .txt иероглифы (на некоторых сайтах). Как туда прикрутить CHARSET, чтобы страницы сохранялись в различных раскладках

[Iska]

adima, приведите примеры таких сайтов (конкретно — адреса страниц).

[adima]

http://russianpost.ru