[Iska]

Покажите то же самое, только скриншотами Process Explorer'а. Уточните, какие именно исполняемые файлы Вы запускаете для игры и для записи видео. Запишите видео, на котором покажите, как Вы делаете описанные выше действия вручную.

[vk_k14m@vk]

Записать видео процесса запуска записи видео. Хм... Думаю тут нужна вторая прога для записи видео. Сейчас что-то соображу...

[vk_k14m@vk]

А скриншот вот

[Iska]

Покажите свойства того, чем Вы запускаете процессы «Multi Theft Auto.exe» и «bdcam.exe» (например, свойства ярлыков). Конкретно интересуют полный путь к исполняемому файлу, рабочий каталог, требуется ли запуск с административными привилегиями, передаваемые параметры и т.п.

[vk_k14m@vk]

Исполняемые файлы:

"D:\Games\MTA Province\MTA\Multi Theft Auto.exe"

Скрытый текст

"C:\Program Files (x86)\Bandicam\Loader.exe"

Скрытый текст

В свойствах ярлыков галочка "Запуск от имени администратора" нигде не стоит.

Видео

[Iska]

vk_k14m@vk, за мельтешением картинок на Вашем Рабочем столе ничего разглядеть невозможно, ни где Вы возите мышкой, ни где что нажимаете. И большой баннер над панелью задач этому тоже не помогает.

Можете пробовать. На WSH:

Скрытый текст

Код:

Option Explicit

Const strPath2GameProcess = "D:\Games\MTA Province\MTA\Multi Theft Auto.exe"
Const strPath2VideoRecordingProcess = "C:\Program Files (x86)\Bandicam\Loader.exe"
Const strName4StopProcess = "bdcam64.bin"


Dim objSWbemServicesEx
Dim objSWbemObjectEx

Dim objFSO

Dim lngGameProcessID
Dim lngVideoRecordingProcessID
Dim lngVideoRecordingParentProcessID


Set objSWbemServicesEx = WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\cimv2")
Set objSWbemObjectEx   = objSWbemServicesEx.Get("Win32_Process")

Set objFSO             = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strPath2GameProcess) Then
	If objFSO.FileExists(strPath2GameProcess) Then
		If objSWbemObjectEx.Create(strPath2GameProcess, objFSO.GetParentFolderName(strPath2GameProcess), Nothing, lngGameProcessID) = 0 Then
			WScript.Sleep 5 * 1000
			
			If objSWbemObjectEx.Create(strPath2VideoRecordingProcess, objFSO.GetParentFolderName(strPath2VideoRecordingProcess), Nothing, lngVideoRecordingProcessID) = 0 Then
				objSWbemServicesEx.ExecNotificationQuery( _
					"SELECT * FROM __InstanceDeletionEvent WITHIN 1 " & _
					"WHERE TargetInstance ISA 'Win32_Process' AND " & _
					"TargetInstance.ProcessID = " & CStr(lngGameProcessID) & "" _
				).NextEvent
				
				For Each objSWbemObjectEx In objSWbemServicesEx.ExecQuery( _
					"SELECT * FROM Win32_Process WHERE Name = '" & strName4StopProcess & "'" _
				)
					lngVideoRecordingParentProcessID = objSWbemObjectEx.ParentProcessID
					
					If objSWbemObjectEx.Terminate() = 0 Then
						If objSWbemServicesEx.Get("Win32_Process.Handle=" & CStr(lngVideoRecordingParentProcessID)).Terminate() = 0 Then
							
						Else
							WScript.Echo "Can't terminate process with PID [" & CStr(lngVideoRecordingParentProcessID) & "]."
						End If
					Else
						WScript.Echo "Can't terminate process with PID [" & CStr(objSWbemObjectEx.ProcessID) & "]."
					End If
					
					Exit For
				Next
			Else
				WScript.Echo "Can't execute process [" & strPath2VideoRecordingProcess & "]."
				WScript.Quit 4
			End If
		Else
			WScript.Echo "Can't execute process [" & strPath2GameProcess & "]."
			WScript.Quit 3
		End If
	Else
		WScript.Echo "Can't find file [" & strPath2VideoRecordingProcess & "]."
		WScript.Quit 1
	End If
Else
	WScript.Echo "Can't find file [" & strPath2GameProcess & "]."
	WScript.Quit 1
End If

Set objFSO             = Nothing

Set objSWbemObjectEx   = Nothing
Set objSWbemServicesEx = Nothing

WScript.Quit 0

Запускаете скрипт, ждёте запуска игры, ждёте пять секунд, нажимаете F12 (или иную горячую клавишу, какая там у Вас настроена) для начала записи видео. Закончили — нажали F12 для остановки записи видео, затем только закрыли игру.

[vk_k14m@vk]

Запускаете скрипт, ждёте запуска игры, ждёте пять секунд, нажимаете F12 (или иную горячую клавишу, какая там у Вас настроена) для начала записи видео. Закончили — нажали F12 для остановки записи видео, затем только закрыли игру. »

С F12 не понял, зачем мне ее нажимать?

[vk_k14m@vk]

за мельтешением картинок на Вашем Рабочем столе ничего разглядеть невозможно, ни где Вы возите мышкой, ни где что нажимаете. И большой баннер над панелью задач этому тоже не помогает. »

А что там разглядывать? Два раза кликнул на ярлык "MTA Province". Дождался запуска игры. Свернул игру. Два раза нажал на ярлык "Bandicam" (запись началась). Развернул игру. Вышел из игры. Открыл скрытые значки трея. Кликнул на "Bandicam", остановил запись и закрыл приложение. Хотя последние действия были не обязательны. Bandicam записывает видео сразу в *.mp4
Никакие дополнительные действия вроде перекодирования, остановки и сохранения записи не нужны. Если принудительно закрыть программу видео так же не повредится.

Можете пробовать. На WSH: »

А как "собрать" этот скрипт, что б не было такой ошибки




И еще вопрос на будущее. Если я захочу сделать подобный скрипт, но для какой-то другой игры. Мне просто изменить путь в этой строчке

Код:

Const strPath2GameProcess = "D:\Games\MTA Province\MTA\Multi Theft Auto.exe"

на путь к другой запускаемой игре? Или еще что-то переписывать нужно?

[Iska]

С F12 не понял, зачем мне ее нажимать? »

Для начала и остановки процесса захвата видео.

(запись началась). »

Покажите Ваши настройки приложения, которые отвечают за автоматический старт записи.

Хотя последние действия были не обязательны. »

Обязательны. Иначе будет у Вас оборванное видео. Особенно, когда речь идёт об mpeg.

Если принудительно закрыть программу видео так же не повредится. »

Есть большие сомнения на этот счёт.

А как "собрать" этот скрипт, что б не было такой ошибки »

Сохранять в файл с расширением .vbs, а не .wsh (.wsh — файл параметров для сценария скрипта).

И еще вопрос на будущее. Если я захочу сделать подобный скрипт, но для какой-то другой игры. Мне просто изменить путь в этой строчке »

Теоретически — да. Практически же — этого гарантировать нельзя.