[Sp01LeR]

Можно ли организовать поиск файла через WinAPI Врядли оно будет быстрее (в AutoIt).

В WinAPI есть продвинутая функция FindFirstFileEx(работает только в win2000 и выше) - вот ссылка на мануал

[asdf8]

Можно значительно ускорить поиск файлов, если избавиться от рекурсии.
Много времени уходит на многочисленный вызов функции.

[Creat0R]

Можно значительно ускорить поиск файлов, если избавиться от рекурсии. »

Вот так:

Код:

$sFile = _FileSearch(@DesktopDir, "test.txt")
MsgBox(64, 'Title', $sFile)

Func _FileSearch($sPath, $sMask="*")
    If Not StringInStr(FileGetAttrib($sPath & "\"), "D") Then Return SetError(1, 0, 0)

    Local $hSearch, $sFindNext, $sFilePath, $iPathIsFolder, $i = 0, $sRet = -1
    Local $sRegExpFilter = StringReplace(StringReplace(StringReplace($sMask, ".", "\."), "*", ".*"), "?", ".")
    Local $iMax_Ret_Paths = 10000
    Local $aPathesArr[$iMax_Ret_Paths+1] = [1, $sPath]

    While $i < $aPathesArr[0]
        $i += 1

        $hSearch = FileFindFirstFile($aPathesArr[$i] & "\*")
        If $hSearch = -1 Then ContinueLoop

        While 1
            $sFindNext = FileFindNextFile($hSearch)
            If @error Then ExitLoop

            $sFilePath = $aPathesArr[$i] & "\" & $sFindNext
            $iPathIsFolder = StringInStr(FileGetAttrib($sFilePath & "\"), "D")

            If $iPathIsFolder Then
                If $aPathesArr[0] >= $iMax_Ret_Paths Then
                    $iMax_Ret_Paths *= 2
                    ReDim $aPathesArr[$iMax_Ret_Paths+1]
                EndIf

                $aPathesArr[0] += 1
                $aPathesArr[$aPathesArr[0]] = $sFilePath
            ElseIf StringRegExp($sFindNext, "(?i)\A" & $sRegExpFilter & "\z") Then
                $sRet = $sFilePath
                ExitLoop
            EndIf
        WEnd

        FileClose($hSearch)
        If $sRet <> -1 Then ExitLoop
    WEnd

    Return SetError(Number($sRet = -1), 0, $sRet)
EndFunc

[asdf8]

Вот так: »

Код:

#Include <Array.au3>


$begin1 = TimerInit()
$sFile = FileList(@WindowsDir, "*.ini")
$dif1 = TimerDiff($begin1)
_ArrayDisplay($sFile,$dif1)


Func FileList($sPath, $inFilter = '*', $exFilter = '');$includeFilter='*.txt,*.htm'   $excludeFilter='www,asp,desktop'
	$sPath = StringRegExpReplace($sPath, '\\+$', '')
	Local $aRetArray[1], $sFindNextFile, $sCurrentPath, $iFL
	Global $FolderList[2]
	$aRetArray[0] = 0
	$FolderList[0] = 1
	$FolderList[1] = $sPath
	Local $sFindFirstFile = FileFindFirstFile($sPath & "\*")
	If @error = 1 Then Return SetError(1, 0, -1)
	#Region
	If StringRight($inFilter, 1) = ',' Then $inFilter = StringTrimRight($inFilter, 1)
	$inFilter = StringReplace($inFilter, '^', '\^')
	$inFilter = StringReplace($inFilter, '.', '\.')
	$inFilter = StringReplace($inFilter, '(', '\(')
	$inFilter = StringReplace($inFilter, ')', '\)')
	$inFilter = StringReplace($inFilter, '[', '\[')
	$inFilter = StringReplace($inFilter, ']', '\]')
	$inFilter = StringReplace($inFilter, '+', '\+')
	$inFilter = StringReplace($inFilter, '$', '\$')
	$inFilter = StringReplace($inFilter, '*', '.*')
	$inFilter = '(?i)^' & StringReplace($inFilter, ',', '$|^') & '$'
	If StringInStr($exFilter, ',') > 0 And $exFilter <> '' Then
		If StringRight($exFilter, 1) = ',' Then $exFilter = StringTrimRight($exFilter, 1)
		$exFilter = StringReplace($exFilter, ',', '|')
		$exFilter = StringReplace($exFilter, '.', '\.')
		$exFilter = StringReplace($exFilter, '(', '\(')
		$exFilter = StringReplace($exFilter, ')', '\)')
		$exFilter = StringReplace($exFilter, '[', '\[')
		$exFilter = StringReplace($exFilter, ']', '\]')
		$exFilter = StringReplace($exFilter, '+', '\+')
		$exFilter = StringReplace($exFilter, '$', '\$')
		$exFilter = '(?i)(' & StringReplace($exFilter, '^', '\^') & ')'
	EndIf
	#EndRegion
	$iFL = 1
	Do
		$sFindFirstFile = FileFindFirstFile($FolderList[$iFL] & "\*")
		If @error = 0 Then
			While 1
				$sFindNextFile = FileFindNextFile($sFindFirstFile)
				If @error = 1 Then ExitLoop
				$sCurrentPath = $FolderList[$iFL] & "\" & $sFindNextFile
				If StringInStr(FileGetAttrib($sCurrentPath), "D") Then;папка
					$FolderList[0] += 1
					If UBound($FolderList) < $FolderList[0] + 1 Then ReDim $FolderList[$FolderList[0] + 1000]
					$FolderList[$FolderList[0]] = $sCurrentPath
				Else;файл
					If StringRegExp($sFindNextFile, $inFilter) = 1 And ($exFilter = '' Or StringRegExp($sFindNextFile, $exFilter) = 0) Then
						$aRetArray[0] += 1
						If UBound($aRetArray) < $aRetArray[0] + 1 Then ReDim $aRetArray[$aRetArray[0] + 1000]
						$aRetArray[$aRetArray[0]] = $sCurrentPath
					EndIf
				EndIf
			WEnd
		EndIf
		FileClose($sFindFirstFile)
		$iFL += 1
	Until $iFL > $FolderList[0]
	ReDim $aRetArray[$aRetArray[0] + 1]
	ReDim $FolderList[$FolderList[0] + 1]
	Return $aRetArray
EndFunc   ;==>FileList

Этот скрипт осматривает папку WindowsDir в 6 раз быстрее, чем из предыдущего поста

[semiono]

Будте любезны зделайте мне этот пример по типам *.reg и с запуском $regfiles /s
И не ругайтесь, что я встреваю, но не понял что ищете все файлы ($includeFilter='*.txt,*.htm') чтоли? Зделайте по типам!
(GUI вывод мне не нужен...)

[asdf8]

пример по типам *.reg »

Код:

$path = @ScriptDir
$sFile = FileList($path, "*.reg")

If $sFile[0]>0 Then
	For $i=1 To $sFile[0]
		Run('regedit /s "' & $sFile[$i] & '"')
	Next
EndIf

функция FileList из моего предыдущего поста.
в переменной $path указать, где искать файлы.

[Creat0R]

Этот скрипт осматривает папку WindowsDir в 6 раз быстрее, чем из предыдущего поста »

А так:

Код:

#include <Array.au3>

$begin1 = TimerInit()
$aReturn = _FileSearch(@WindowsDir, "*.ini")
$dif1 = TimerDiff($begin1)

_ArrayDisplay($aReturn, Round($dif1, 2))

Func _FileSearch($sPath, $sFileMask)
    Local $iPID, $sStdOutRead, $aRet

    $iPID = Run(@ComSpec & ' /C Dir "' & $sPath & '\' & $sFileMask & '" /S /B /A RASH', @SystemDir, @SW_HIDE, 6)

    While 1
        $sStdOutRead &= StdoutRead($iPID)
        If @error <> 0 Then ExitLoop
    WEnd

    $aRet = StringSplit(StringStripCR(StringStripWS($sStdOutRead, 3)), @LF)
    Return SetError(@error, 0, $aRet)
EndFunc

?

[madmasles]

Creat0R,

Вот время работы Вашей функции у меня 376.28 - Супер!!!
Результат функции от asdf8 1763.56

PS

Рано еще списывать командную строку.

[asdf8]

А так: »

первый прогон 4037.44
второй прогон 3680.5

для моей функции:
первый прогон 4667.5
второй прогон 1587.21

Интересно - можно еще быстрее?

[Creat0R]

для моей функции »

У себя не замечаю такую разницу, функция с использованием Dir отрабатывает намного быстрее чем всё остальное.

Интересно - можно еще быстрее? »

Сарказм? к чему оно?