[serg aka lain]

хотите сказать, что за это отвечают данные по адресу HKLM\SYSTEM\CurrentControlSet\Control\ProductOptions\ProductSuite т.е. если ProductSuite - Personal значит это Home, если значения нет Professional »

Не совсем так (были в сети не так давно статьи, как из Хомяка сделать Профессионал)
Но, тем не менее, примерно так.

[Lancer2404]

Скажите как сделать чтобы после установки выдавалось сообщение?

[serg aka lain]

Скажите как сделать чтобы после установки выдавалось сообщение? »

Код:

[Setup]
AppName=My Program
AppVerName=My Program
CreateAppDir=False
Uninstallable=False
OutputDir=userdocs:My Program.

[code]
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssDone then
    MsgBox('Сообщение', mbInformation, MB_OK);
end;

[Lancer2404]

спасибо

[Habetdin]

Проблема решена

читать дальше »

Решение:

Код:

[code]
procedure CurPageChanged(CurPageID: Integer);
begin
	if CurPageID = wpInstalling then
		begin
		if FileExists(ExpandConstant('{src}\File.ext')) then
		FileCopy(ExpandConstant('{src}\File.ext'), ExpandConstant('{app}\File.ext'), False);
	end;
end;

[Serega]

Habetdin, дело в том, что есть только:

Код:

function FileCopy(const ExistingFile, NewFile: string; const FailIfExists: Boolean): Boolean;

Копирует ExistingFile в NewFile, сохраняя временные отметки и атрибуты файла. Если FailIfExists=True и NewFile уже существует, файл не копируется, если FailIfExists=False, существующий файл заменится на NewFile. Если копирование успешно, возвращает True, иначе False.

[lmiol]

у меня трабла , при выборе всех компонентов ставятся все ярлыки, а мне нужно чтобы при выборе компонентов main и browser ставился только ярлык Name: "{userdesktop}\Quake Live", а ставятся оба Name: "{userdesktop}\Quake Live" и Name: "{userdesktop}\QuakeLive.com"
Как нужно выставить компоненты чтобы такого небыло или что нужно сделать?

Код:

[Types]
Name: "full"; Description: "Все компоненты";
Name: "custom"; Description: "Выбрать компоненты"; Flags: iscustom

[Components]
Name: "main"; Description: "Главные файлы Quake Live"; Types: full custom; Flags: fixed
Name: "browser"; Description: "Firefox и дополнение Prism"; Types: full custom
Name: "manual"; Description: "Руководство и Награды"; Types: full custom
Name: "anti"; Description: "Античит PunkBuster"; Types: full custom

[Messages]
BeveledLabel=Copyright © Mio Dark Project

[Tasks]
Name: "desktopicon"; Description: "Создать ярлык на Рабочем Столе"; GroupDescription: "{cm:AdditionalIcons}"

[Files]
Source: "uninstall.ico"; Components: main; DestDir: "{userappdata}\id Software\uninstall"; Flags: ignoreversion
Source: "usercur\*"; Components: main; DestDir: "{userappdata}\id Software"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: "usercur2\*"; Components: manual; DestDir: "{userappdata}\id Software"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: "usercur3\*"; Components: browser; DestDir: "{userappdata}\"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: "programfiles\*"; Components: browser; DestDir: "{pf}\"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: "pk3\*"; Components: main; DestDir: "{userappdata}\id Software"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension nocompression
Source: "pbsvc.exe" ;Components: anti;DestDir: "{tmp}"; Flags: ignoreversion

[Icons]
Name: "{group}\QuakeLive.com"; Filename: "http://www.quakelive.com"; IconFilename: "{userappdata}\id Software\quakelive\home\baseq3\quakelive.dll"; IconIndex: 0; Components: main
Name: "{group}\Руководство к игре"; Filename: "{userappdata}\id Software\quakelive\home\manual\manual.htm"; IconFilename: "{userappdata}\id Software\quakelive\home\links\qlm.ico"
Name: "{group}\Демки"; Filename: "{userappdata}\id Software\quakelive\home\baseq3\demos"; IconFilename: "{sys}\SHELL32.dll";  IconIndex: 126
Name: "{group}\Скриншоты"; Filename: "{userappdata}\id Software\quakelive\home\baseq3\screenshots"; IconFilename: "{sys}\SHELL32.dll";  IconIndex: 127
Name: "{group}\Удалить игру"; Filename: "{uninstallexe}"; IconFilename: "{userappdata}\id Software\uninstall\uninstall.ico"
Name: "{userdesktop}\QuakeLive.com"; Filename: "http://www.quakelive.com"; Tasks: desktopicon; IconFilename: "{userappdata}\id Software\quakelive\home\baseq3\quakelive.dll"; IconIndex: 0; Components: main
Name: "{userdesktop}\Quake Live"; Filename: {pf}\FirefoxPrismQuakeLive\Firefox\Quake Live.exe; WorkingDir: {pf}\FirefoxPrismQuakeLive\Profiles\Clear\extensions\refractor@developer.mozilla.org\prism; Tasks: desktopicon; IconFilename: "{pf}\FirefoxPrismQuakeLive\Firefox\Quake Live.exe"; IconIndex: 0; Components: browser
Name: "{userdesktop}\Руководство к игре"; Filename: "{userappdata}\id Software\quakelive\home\manual\manual.htm"; IconFilename: "{userappdata}\id Software\quakelive\home\links\qlm.ico"

[Run]
Filename: {tmp}\pbsvc.exe; StatusMsg: "Установка античита PunkBuster..."; Parameters: "/i --no-display --i-accept-the-pb-eula /u"; WorkingDir: {tmp}; Flags: runhidden waituntilterminated ; Components: anti;
Filename: {pf}\FirefoxPrismQuakeLive\Firefox\Quake Live.exe; WorkingDir: {pf}\FirefoxPrismQuakeLive\Profiles\Clear\extensions\refractor@developer.mozilla.org\prism; Description: "Войти в игру"; Flags: nowait shellexec postinstall skipifsilent unchecked; Components: browser
Filename: "http://www.quakelive.com/#home"; Description: "Войти в игру"; Flags: nowait shellexec postinstall skipifsilent unchecked; Components: main
Filename: {userappdata}\id Software\quakelive\home\manual\manual.htm; Description: "Прочитать руководство"; Flags: nowait shellexec postinstall skipifsilent unchecked; Components: manual

[ADremLIN]

Скрипты добавляющие/удаляющие ваш путь в переменной %PATH%:

читать дальше »

Код:

///////////////////////////////////////////////////////////////////////////////////////////////////
// Сохранить сей манускрипт как "env-tools.iss" (без кавычек)
//
//  По мотивам сообщения тов. omals и zhe_zho от 02-12-2008 09:21
//  http://forum.ru-board.com/topic.cgi/tools.cgi?action=notifyon&forum=5&topic=27438&start=1685
//
//  Для применения нового значения %PATH% после завершения инсталяции
//  необходимо добавить в секцию:
//
//  [Setup]
//  ChangesEnvironment=yes
//
//  В скрипт подключается так:
//
//  [_Code]                           "_Code" - Из-за ограничений тегов форума. Имеется ввиду секция Code
//  #include "env-tools.iss"
//
//  Процедуры описаны в env-tools.iss:
//
//  SetEnvironmentPath('<ваш_путь>');    // Добавляет <ваш_путь> к системному %PATH% 
//  DeleteEnvironmentPath('<ваш_путь>'); // Удаляет <ваш_путь> из системного %PATH%
//
//  Вызывать по смыслу в нужном месте инсталляции или деинсталяции 
//  Например:
//  {После инсталляции:}
//  procedure CurStepChanged(CurStep: TSetupStep);
//  begin
//    if CurStep = ssPostInstall then
//    begin
//      SetEnvironmentPath(ExpandConstant('{app}\bin'));
//    end;
//  end;
// 
//  {Перед деинсталляцией:}
//  procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
//  begin
//    if CurUninstallStep = usUninstall then
//    begin
//      DeleteEnvironmentPath(ExpandConstant('{app}\bin'));
//    end;
//  end;
//        
///////////////////////////////////////////////////////////////////////////////////////////////////

procedure SetEnvironmentPath(NewPath: String);
var
  PathStr: String;
begin
  {Получаем значение текущего системного %PATH%}
  RegQueryStringValue(HKLM,'SYSTEM\CurrentControlSet\Control\Session Manager\Environment', 'Path', PathStr);
  {Ищем NewPath в текущем системном %PATH%}
  if Pos(NewPath, PathStr) <= 0 then // Если в текущем %PATH% не найдено NewPath;
  begin
    PathStr := NewPath + ';' + PathStr;
    RegWriteStringValue(HKLM,'SYSTEM\CurrentControlSet\Control\Session Manager\Environment', 'Path', PathStr);
  end;
end;

procedure DeleteEnvironmentPath(OldPath: String);
var
  PathStr: String;
  StartPos, Len: Integer;
begin
  {Получаем значение текущего системного %PATH%}
  RegQueryStringValue(HKLM,'SYSTEM\CurrentControlSet\Control\Session Manager\Environment', 'Path', PathStr);

  {Ищем OldPath c ";" в текущем системном %PATH%}
  StartPos := Pos(OldPath + ';', PathStr); //индекс начала вхождения OldPath c ";"
  if StartPos > 0 then // Если в текущем %PATH% найден OldPath;
  begin
    Len := Length(OldPath + ';');   //длина строки OldPath c ";"
    Delete(PathStr, StartPos, Len); // удаляем из текущего системного %PATH% (PathStr) строку OldPath c ";"
    {Записываем изменения в реестр}
    RegWriteStringValue(HKLM,'SYSTEM\CurrentControlSet\Control\Session Manager\Environment', 'Path', PathStr);
    Exit;
  end;

  {Ищем OldPath без ";" в текущем системном %PATH%}
  StartPos := Pos(OldPath, PathStr);
  if StartPos > 0 then // Если в текущем %PATH% найден OldPath без ";"
  begin
    Len := Length(OldPath); //индекс начала вхождения OldPath без ";"
    Delete(PathStr, StartPos, Len); // удаляем из текущего системного %PATH% (PathStr) строку OldPath без ";"
    {Записываем изменения в реестр}
    RegWriteStringValue(HKLM,'SYSTEM\CurrentControlSet\Control\Session Manager\Environment', 'Path', PathStr);
  end;
end;

Может кому пригодится...

Внимание, здесь нет проверки входного параметра функций на "пустую строку" - осторожней с этим... (Доделаю при удобном случае)

ЗЫ: Как принудительно заставить систему обновить(перечитать) измененный %PATH%, ДО ЗАВЕРШЕНИЯ установки?
Дело в том, что ChangesEnvironment=yes срабатывает уже ПОСЛЕ ЗАВЕРШЕНИЯ установки.
А то у меня в постинстале батник не работает т.к. использует уже "новую" %PATH%...

[abc]

Подскажите, как сделать в программе установки проверку на наличие установленного распространяемого пакета ms visual c++ 2008 и в случае отсутствия автоматически (с учётом разрядности системы) загрузить (в ISTool есть модуль закачи файлов) и выполнить файл инсталлятора пакета. Заранее благодарен. Прошу прощение, если это уже где-то обсуждалось.

[Serega]

у меня трабла , при выборе всех компонентов ставятся все ярлыки »

Добавьте проверку на выбранный компонент:

Код:

Name: "{userdesktop}\Quake Live"; Filename: {pf}\FirefoxPrismQuakeLive\Firefox\Quake Live.exe; WorkingDir: {pf}\FirefoxPrismQuakeLive\Profiles\Clear\extensions\refractor@developer.mozilla.org\prism; Tasks: desktopicon; IconFilename: "{pf}\FirefoxPrismQuakeLive\Firefox\Quake Live.exe"; IconIndex: 0; Components: browser; Check: not IsComponentSelected('main')

Дело в том, что ChangesEnvironment=yes срабатывает уже ПОСЛЕ ЗАВЕРШЕНИЯ установки. »

Цитата из Справки

Порядок установки Задания в секциях от начала до завершения установки выполняются в следующем порядке: ·Выполняется [InstallDelete]. ·Параметры секции [UninstallDelete] располагаются в логе деинсталлятора (который на этом этапе находится в оперативной памяти). ·При необходимости создается папка приложения. ·Выполняется [Dirs]. ·При необходимости резервируется имя файла деинсталлятора. ·Выполняется [Files]. (Регистрация файлов не происходит.) ·Выполняется [Icons]. ·Выполняется [INI]. ·Выполняется [Registry]. ·Регистрируются файлы, нуждающиеся в регистрации, если только не требуется перезагрузка системы - в этом случае ни один файл не будет зарегистрирован до тех пор, пока система не перезапустится. . ·При необходимости создается пункт в Установка/Удаление программ. ·Параметры [UninstallRun] располагаются в логе деинсталлятора. ·Завершается создание деинсталлятора и он сохраняется на диске. ·При ChangesAssociations=yes меняются ассоциации для файлов. ·Если ChangesEnvironment=yes, остальные приложения информируются об изменении переменных среды. ·Выполняется [Run], за исключением файлов с флагом postinstall, которые выполнятся после того, как отобразится страница Установка завершена. Все параметры выполняются инсталлятором в том порядке, в котором они располагаются в секции Все изменения отменяются деинсталлятором в порядке, обратном их созданию инсталлятором. Это происходит потому, что лог деинсталлятора выполняется от конца к началу..

если вы запускаете в ssPostInstall батник, то соответственно приложения уже перезагрузились. Видимо что-то не так с батником...