[Mat_y]

Привет... вопросик:
Можно ли научить инно скачивать с https ? Может *dll-ку какую можно прикрутить?
З.Ы. с http качает без проблем.

[nik1967]

Ivan_009, кстати, вдруг если не заметил, нумерация файлов слайдшоу должна начинаться с 0 - 0.bmp, 1.bmp и так далее. Это так, на всякий случай

[Ivan_009]

кстати, вдруг если не заметил, нумерация файлов слайдшоу должна начинаться с 0 - 0.bmp, 1.bmp и так далее. Это так, на всякий случай »

nik1967, Ну я уже понял . Кстати как на финишной странице к примеру остановить показ слайд-шоу...

[Dodakaedr]

Код:

[Setup] 
AppName=My Program 
AppVerName=My Program 1.5 
DefaultDirName={pf}\My Program 
 
[Languages] 
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl" 
 
[Run] 
Filename: "{app}\MyProg"; Description: "{cm:LaunchProgram, MyProg}"; Flags: nowait postinstall skipifsilent 
 
[ Code] 
var 
  IniCheckBox: TCheckBox; 
 
procedure InitializeWizard(); 
begin 
  IniCheckBox:= TCheckBox.Create(WizardForm); 
  IniCheckBox.Left:= WizardForm.RunList.Left + 4; 
  IniCheckBox.Top:= WizardForm.RunList.Top + 10; 
  IniCheckBox.Width:= WizardForm.RunList.Width; 
  IniCheckBox.Height:= 14 
  IniCheckBox.Caption:=' Изменить язык интерфейса на русский'; 
  IniCheckBox.Parent:= WizardForm.FinishedPage; 
end; 
 
procedure DeinitializeSetup(); 
begin 
  if WizardForm.CurPageID = WpFinished then 
    begin 
      if IniCheckBox.Checked then 
        SetIniString('Language','CurrentLanguage', 'путь к файлу\Language\Russian.ini' ,ExpandConstant('{app}\Settings.ini'))
    end; 
end;

Как сделать чтобы вместо "путь к файлу" было "{pf}\My Program" (надо чтобы брался путь с {app}). Как это изменить? И желательно без чекбокса все это оформить??

[nik1967]

Кстати как на финишной странице к примеру остановить показ слайд-шоу... »

Использовать KillTimer и скрытие AImg - ImgSetVisibility(AImg[i],false); либо AImg[i].Hide; - но не проверял - не уверен в правильности.

Dodakaedr, ну дык

читать дальше »

Код:

[Setup] 
AppName=My Program 
AppVerName=My Program 1.5 
DefaultDirName={pf}\My Program 
 
[Languages] 
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl" 
 
[ Code]  
procedure CurPageChanged(CurPageID: Integer); 
begin 
  if WizardForm.CurPageID = WpFinished then SetIniString('Language','CurrentLanguage','RU',ExpandConstant('{app}\Language\Russian.ini')); 
end;

читать дальше »

Код:

Pascal Scripting: SetIniString
Prototype:
function SetIniString(const Section, Key, Value, Filename: String): Boolean;

Description:
Writes a string to an INI file.

[Ivan_009]

nik1967, Таймер какой то не убиваемый пробовал:

Код:

ImgSetVisibility(AImg[i],false);
KillTimer(0, Timer);

на секунду отключает дальше пошло и поехало...

[nik1967]

Ivan_009, скинь скрип с файлами - посмотрю, как будет время (можно в личку).

[Dodakaedr]

nik1967, не то. Твой скрипт создает

Код:

[Language]
CurrentLanguage=RU

А мне нужно чтобы было так

Код:

[Language]
CurrentLanguage=C:\Program Files\ImageConverter\Language\Russian.ini

И то чтобы C:\Program Files\ImageConverter бралось з инсталятора с константы {app}

[Habetdin]

Как сделать чтобы вместо "путь к файлу" было "{pf}\My Program" (надо чтобы брался путь с {app}). Как это изменить? »

По аналогии с предыдущим параметром, можно было написать:

Код:

ExpandConstant('{app}\Language\Russian.ini')

И желательно без чекбокса все это оформить? »

Убрать весь код, создающий чекбокс и проверяющий его значение? Получаем:

Код:

procedure DeinitializeSetup(); 
begin 
  if WizardForm.CurPageID = WpFinished then 
    begin 
      SetIniString('Language', 'CurrentLanguage', ExpandConstant('{app}\Language\Russian.ini'), ExpandConstant('{app}\Settings.ini'))
    end; 
end;

Хотя, правильнее, по-моему, для данной цели для этого использовать секцию [INI], а не [Code]:

Код:

[INI]
Filename: "{app}\Settings.ini"; Section: "Language"; Key: "CurrentLanguage"; String: "{app}\Language\Russian.ini"

---

Offtopic

Есть Components/Tasks, INI (а еще конструкторы, генерирующие все необходимое), а они пишут всё в Code, при этом не зная основ этого самого Code

[Dodakaedr]

Убрать весь код, создающий чекбокс и проверяющий его значение? Получаем: »

Супер, то что нужно.