[Mailchik]

Raf-9600, тот же, от Шегората:

читать дальше »

Код:

[Setup]
AppName=My Application
AppVersion=1.5
DefaultDirName={pf}\My Application

[Components]
Name: std; Description: Стандартная; Flags: exclusive disablenouninstallwarning; Types: custom compact full
Name: std\a; Description: Анси; Flags: exclusive disablenouninstallwarning; Types: custom compact full
Name: std\u; Description: Юникод; Flags: exclusive disablenouninstallwarning; Types: custom compact full

Name: ext; Description: Китаяса; Flags: exclusive disablenouninstallwarning; Types: custom compact full
Name: ext\a; Description: Анси; Flags: exclusive disablenouninstallwarning; Types: custom compact full
Name: ext\u; Description: Юникод; Flags: exclusive disablenouninstallwarning; Types: custom compact full

[code]
var
  LastIndex: Integer;

procedure HintStr(Sender: TObject; X: Integer; Y: Integer; Index: Integer; Area: TItemArea);
begin
  if Index<>LastIndex then begin
    LastIndex:= Index;
    WizardForm.ComponentsList.ShowHint:= False;
    WizardForm.ComponentsList.Hint:= '';
    Exit;
  end;

  with WizardForm.ComponentsList do
  case Index of
    0 : Hint := 'Стандартная';
    1 : Hint := 'Стандартная Анси';
    2 : Hint := 'Стандартная Юникод';
    3 : Hint := 'Китаяса';
    4 : begin
     if IsComponentSelected('ext\u') then  // то, что вам нужно.
      Hint := 'Китаяса Анси 2'
      else Hint := 'Китаяса Анси';
     end;
    5 : Hint := 'Китаяса Юникод';
  else
    Hint := 'Наведите на компонент для отображения подсказки';
  end;
  WizardForm.ComponentsList.ShowHint:= True;
end;

procedure InitializeWizard();
begin
  with WizardForm do
  begin
    with ComponentsList do
    begin
      ShowHint := True;
      Hint := '';
      OnItemMouseMove := @HintStr;
    end;
  end;
end;

[SatHan]

привет.

тот же, от Шегората »

а можно сделать чтобы подсказка плавала за курсором мыши в области компонента а не стояла на одном месте?

[Gnom_aka_Lexander]

SatHan, я тоже люблю поиздеваться.

а можно сделать чтобы подсказка плавала за курсором мыши в области компонента а не стояла на одном месте? »

Можно

[R.i.m.s.k.y.]

Можно ли как-то обойти окно выбора языка при старте установщика, задав "насильно" устанавливаемый язык?

[Gnom_aka_Lexander]

R.i.m.s.k.y., только с опорой на язык системы, больше никак.

Код:

[Setup]
ShowLanguageDialog=no
LanguageDetectionMethod=locale

[R.i.m.s.k.y.]

Имеется

Код:

[Setup]
ShowLanguageDialog=no
LanguageDetectionMethod=locale

[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl
Name: english; MessagesFile: compiler:Languages\english.isl

Можно как-то "обощить" инсталлер на множество нерусских языков? если система русская - инсталлер выбирал русский язык (что собственно в секции Setup и указано), но если ОС любая кроме русской (китайская, корейская, бразильская etc) - то принудительно выбирался английский язык? естественно без окна выбора языка

[Mailchik]

R.i.m.s.k.y., поставьте английский первым в списке, то есть:

Код:

[Setup]
AppName=Test
AppVerName=Test v1.1
DefaultDirName={pf}\Test
ShowLanguageDialog=no
LanguageDetectionMethod=locale

[Languages]
Name: english; MessagesFile: compiler:Languages\english.isl
Name: russian; MessagesFile: compiler:Languages\Russian.isl

[SatHan]

Можно »

на ссылку чевото не переходит.

[R.i.m.s.k.y.]

поставьте английский первым в списке »

что-то я сомневаюсь что такое сработает
Что будет если установщик запустят на бразильской или китайской системе?

[Mailchik]

R.i.m.s.k.y., можете сами проверить. панель управления -- часы, язык и регион -- язык и региональные стандарты -- формат.
я думаю вы имеете в виду язык самой системы, но и в том случае должен сработать. инсталлятор, насколько я знаю, выбирает первый язык из списка [languages], если ShowLanguageDialog=no.
из справки:

Код:

3.Если ни один не найден, первый указанный язык в секции [Languages] принимается языком по умолчанию.