[Nordek]

solid compression — уплотнённое сжатие »

Скрытый текст

SolidCompression Допустимые значения: yes или no Значение по умолчанию: no Описание: Если задано значение yes, то будет задействовано непрерывное сжатие. Это позволит сжать все файлы как один, а не по отдельности. Такое положение может привести к значительно лучшей степени сжатия, если в инсталляторе содержится много файлов с общим содержимым, например текстовых файлов, особенно если такие общие файлы сгруппированы в секции [Files]. Недостаток непрерывного сжатия заключается в том, что все файлы сжимаются единым потоком, инсталлятор не может беспорядочно обращаться к любому из файлов. Это может снизить производительность. Если какой-либо файл не был извлечён в системе пользователя, то для того чтоб получить доступ к этому файлу с последующим его извлечением, в любом случае сначала понадобится извлечение остального содержимого (в память). И если например, при извлечении определённого файла произошла ошибка, и пользователь нажал кнопку "Повторить", инсталлятор не сможет обратиться к файлу, так как все файлы сжаты как единый, и придётся произвести повторную попытку снова. Если включено разбиение на диски, пользователю необходимо будет повторно вставить первый диск. В общем, не рекомендуется применять непрерывное сжатие к большим по размеру инсталляторам (скажем, более 100 МБ) или если используется разбиение на диски. В первую очередь предназначалось для экономии времени при загрузке небольших приложений, распространяемых через Интернет.

А если у меня нет дубликатов файлов? »

Последовательность интересует?

Скрытый текст

Последовательность следует сверху вниз.

Например включено в инсталлятор:

Код:

[Files]
Source: C:\WINDOWS\Fonts\*; DestDir: {app}\Fonts; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: C:\WINDOWS\Cursors\*; DestDir: {app}\Cursors; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: C:\WINDOWS\Help\*; DestDir: {app}\Help; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension

то извлечение будет производиться сначала Fonts, затем Cursors и наконец Help.

Если:

Код:

[Files]
Source: C:\WINDOWS\Help\*; DestDir: {app}\Help; Flags: ignoreversion recursesubdirs createallsubdirs
Source: C:\WINDOWS\Fonts\*; DestDir: {app}\Fonts; Flags: ignoreversion recursesubdirs createallsubdirs
Source: C:\WINDOWS\Cursors\*; DestDir: {app}\Cursors; Flags: ignoreversion recursesubdirs createallsubdirs

- аналогично Help, затем Fonts и наконец Cursors.

Также в таком случае:

Код:

[Files]
Source: MyProg1.exe; DestDir: {app}; Flags: ignoreversion
Source: MyProg2.exe; DestDir: {app}; Flags: ignoreversion
Source: C:\WINDOWS\Help\*; DestDir: {app}\Help; Flags: ignoreversion recursesubdirs createallsubdirs
Source: C:\WINDOWS\Fonts\*; DestDir: {app}\Fonts; Flags: ignoreversion recursesubdirs createallsubdirs

- сначала MyProg1.exe, затем MyProg2.exe, Help и наконец Fonts.

Аналогично:

Код:

Source: C:\WINDOWS\Fonts\*; DestDir: {app}\Fonts; Flags: ignoreversion recursesubdirs createallsubdirs
Source: C:\WINDOWS\Help\*; DestDir: {app}\Help; Flags: ignoreversion recursesubdirs createallsubdirs
Source: MyProg2.exe; DestDir: {app}; Flags: ignoreversion
Source: MyProg1.exe; DestDir: {app}; Flags: ignoreversion

- сначала Fonts, затем Help, MyProg2.exe и наконец MyProg1.exe.

Лучшее сжатие интересует?

Скрытый текст

Совместно с SolidCompression используйте флаг sortfilesbyextension

sortfilesbyextension Этот флаг указывает компилятору сжимать найденные файлы, отсортированные по расширению, прежде чем они будут отсортированы по имени пути. Это уменьшит размер инсталлятора, если используется совместно с директивой "Непрерывное сжатие" (SolidCompression).

Например:

Код:

[Setup]
...
Compression=lzma2/ultra64
SolidCompression=true

[Files]
Source: "C:\WINDOWS\Fonts\*"; DestDir: "{app}\Fonts"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: "C:\WINDOWS\Cursors\*"; DestDir: "{app}\Cursors"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension

Также:

sortfilesbyname Этот флаг указывает компилятору сжимать найденные файлы, отсортированные по имени, прежде чем они будут отсортированы по имени пути. Это уменьшит размер инсталлятора, если используется совместно с директивой "Непрерывное сжатие" (SolidCompression). Если также используется sortfilesbyextension, файлы сначала сортируются по расширению.

Код:

[Setup]
...
Compression=lzma2/ultra64
SolidCompression=true

[Files]
Source: "C:\WINDOWS\Fonts\*"; DestDir: "{app}\Fonts"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension sortfilesbyname
Source: "C:\WINDOWS\Cursors\*"; DestDir: "{app}\Cursors"; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension sortfilesbyname

[Iska]

SolidCompression Допустимые значения: »

Не-не, я, слава богу, технический английский пока ещё понимаю .

А вот про это:

Совместно с SolidCompression используйте флаг sortfilesbyextension »

опять не знал. Давно, давно не брал я шашек в руки . Как перешёл на msi, так и «забил» на InnoSetup.

[vk_k14m@vk]

Лучшее сжатие интересует? »

Значит если использовать SolidCompression вместе с флагом sortfilesbyextension то не нужно вручную группировать однотипные файлы? Достаточно выбрать всю папку, и тот флаг сам их отсортирует?
Так же если у меня включены компоненты, например папка "1" устанавливается в любом случае, а папки "2а" и "2b" ставятся на выбор. То к этим трем папкам нужно добавлять флаги "solidbreak". Что б сэкономить время на распаковку "2а" если ее не нужно устанавливать?

[Nordek]

Значит если использовать SolidCompression вместе с флагом sortfilesbyextension то не нужно вручную группировать однотипные файлы? Достаточно выбрать всю папку, и тот флаг сам их отсортирует? »

Да, файлы будут отсортированы автоматически.

Так же если у меня включены компоненты, например папка "1" устанавливается в любом случае, а папки "2а" и "2b" ставятся на выбор. То к этим трем папкам нужно добавлять флаги "solidbreak". Что б сэкономить время на распаковку "2а" если ее не нужно устанавливать? »

Имеет смысл добавить флаг solidbreak, но при этом степень сжатия будет чуть хуже.

[Iska]

если у меня включены компоненты, например папка "1" устанавливается в любом случае, а папки "2а" и "2b" ставятся на выбор. То к этим трем папкам нужно добавлять флаги "solidbreak". »

К первой — не надо.

[mig73]

vk_k14m@vk,
У вас объёмный инсталлятор и совместно с SolidCompression может имеет смысл использовать флаг solidbreak.

sortfilesbyextension тоже использую, но это наверное эффективно не сработает когда в типе файла информация совсем другая. Например в drv, вовсе не бинарник, а текст.

[vk_k14m@vk]

Народ. У меня проблемы с упаковкой. Inni Setup в секции [Files] игнорирует все дальше второй строчки. Первые две запаковывает остальные пропускает. В чем может быть причина?

Скрытый текст

Код:

; Этот сценарий создан с помощью Мастера Inno Setup.
; ОБРАТИТЕСЬ К СПРАВОЧНОЙ ДОКУМЕНТАЦИИ, ЧТОБЫ ИСПОЛЬЗОВАТЬ ВСЕ ВОЗМОЖНОСТИ INNO SETUP!

#define MyAppName "Artificial Academy 2"
#define MyAppVersion "2.0.1"
#define MyAppPublisher "Illusion"
#define MyAppExeName "AA2Play.exe"

[Setup]
; Примечание: Значение AppId является уникальным идентификатором для этого приложения.
; Не используйте одно и тоже значение AppId для разных приложений.
; (Для создания нового значения GUID, выберите в меню "Инструменты" пункт "Создать GUID".)
AppId={{37EDDB6D-1F9B-474F-8FF4-57CC8277B1A7}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
DefaultDirName=D:\Games\{#MyAppName}
DefaultGroupName={#MyAppName}
AllowNoIcons=yes
OutputDir=D:\Inno Setup
OutputBaseFilename=setup
SetupIconFile=D:\Inno Setup\Installer\ico.ico
WizardImageFile=D:\Inno Setup\Installer\WizardImage.bmp
WizardSmallImageFile=D:\Inno Setup\Installer\WizardSmallImage.bmp
Compression=lzma2/ultra64   
SolidCompression=yes
DiskSpanning=yes
DiskSliceSize=1536000000

[Languages]
Name: "russian"; MessagesFile: "compiler:\Languages\Russian.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Components]
Name: "Main";                     Description: "Artificial Academy 2";           Types: full compact custom; Flags: fixed
Name: "Anticensor";               Description: "Антицензор";                     Types: custom
Name: "Anticensor\MKIII";         Description: "МКIII";                          Types: custom;              Flags: exclusive
Name: "Anticensor\MKIII\clothes"; Description: "Пак одежды для MKIII анцензора"; Types: custom;              Flags: exclusive
Name: "Anticensor\SVII";          Description: "SVII";                           Types: custom;              Flags: exclusive  
Name: "Anticensor\SVII\clothes";  Description: "Пак одежды для SVII анцензора";  Types: custom;              Flags: exclusive  
Name: "Hairstyles";               Description: "Дополнительные прически и лица"; Types: custom;                
Name: "Russification";            Description: "Русификатор";                    Types: custom;                

[Files]
Source: "D:\Inno Setup\Installer\1 Main Files\Artificial Academy 2\AA2Play.exe";                     DestDir: "{app}"; Components: Main;                            Flags: ignoreversion sortfilesbyextension 
Source: "D:\Inno Setup\Installer\1 Main Files\Artificial Academy 2\*";                               DestDir: "{app}"; Components: Main;                            Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension
Source: "D:\Inno Setup\Installer\2a MKIII files and clothes\Artificial Academy 2*";                  DestDir: "{app}"; Components: Anticensor\MKIII;                Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension solidbreak
Source: "D:\Inno Setup\Installer\2b SVII files and clothes\Artificial Academy 2*";                   DestDir: "{app}"; Components: Anticensor\SVII;                 Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension solidbreak
Source: "D:\Inno Setup\Installer\3 Hairstyles files\Artificial Academy 2*";                          DestDir: "{app}"; Components: Hairstyles;                      Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension solidbreak
Source: "D:\Inno Setup\Installer\0 Delete after install\Main\Artificial Academy 2*";                 DestDir: "{app}"; Components: Main;                            Flags: ignoreversion recursesubdirs createallsubdirs deleteafterinstall solidbreak
Source: "D:\Inno Setup\Installer\0 Delete after install\MKIII\Artificial Academy 2*";                DestDir: "{app}"; Components: Anticensor\MKIII;                Flags: ignoreversion recursesubdirs createallsubdirs deleteafterinstall solidbreak
Source: "D:\Inno Setup\Installer\0 Delete after install\SVII\Artificial Academy 2*";                 DestDir: "{app}"; Components: Anticensor\SVII;                 Flags: ignoreversion recursesubdirs createallsubdirs deleteafterinstall solidbreak
Source: "D:\Inno Setup\Installer\0 Delete after install\Hairstyles\Artificial Academy 2*";           DestDir: "{app}"; Components: Hairstyles;                      Flags: ignoreversion recursesubdirs createallsubdirs deleteafterinstall solidbreak
Source: "D:\Inno Setup\Installer\0 Delete after install\MKIII and Hairstyles\Artificial Academy 2*"; DestDir: "{app}"; Components: Anticensor\MKIII and Hairstyles; Flags: ignoreversion recursesubdirs createallsubdirs deleteafterinstall solidbreak
Source: "D:\Inno Setup\Installer\0 Delete after install\SVII and Hairstyles\Artificial Academy 2*";  DestDir: "{app}"; Components: Anticensor\SVII and Hairstyles;  Flags: ignoreversion recursesubdirs createallsubdirs deleteafterinstall solidbreak
; Примечание: Не используйте' флаги "ignoreversion" для общих системных файлов.

[Icons]
Name: "{group}\{#MyAppName}";                       Filename: "{app}\{#MyAppExeName}"
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\{#MyAppName}";               Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon

[Run]  
Filename: "{app}\data\AA2Decrypt_fix.bat"; WorkingDir: {app}/data; Description: Упаковка папок...; Flags: waituntilterminated 

[UninstallDelete]
Name: {app}\data\*.pp; Type: files

[Nordek]

vk_k14m@vk, Рабочий пример. Можете сходу проверить.
Или удалите ненужные файлы пустышки (*.txt, *.exe) из примера и распределите ваше содержимое по каталогам.

[Iska]

Меня лично терзают смутные сомнения насчёт возможно пропущенного обратного слэша, начиная как раз после второй строчки:

Код: [Files] Source: "D:\Inno Setup\Installer\1 Main Files\Artificial Academy 2\AA2Play.exe"; DestDir: "{app}"; Components: Main; Flags: ignoreversion sortfilesbyextension Source: "D:\Inno Setup\Installer\1 Main Files\Artificial Academy 2\*"; DestDir: "{app}"; Components: Main; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension Source: "D:\Inno Setup\Installer\2a MKIII files and clothes\Artificial Academy 2*"; DestDir: "{app}"; Components: Anticensor\MKIII; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension solidbreak Source: "D:\Inno Setup\Installer\2b SVII files and clothes\Artificial Academy 2*"; DestDir: "{app}"; Components: Anticensor\SVII; Flags: ignoreversion recursesubdirs createallsubdirs sortfilesbyextension solidbreak …

[Nordek]

насчёт возможно пропущенного обратного слэша »

Если пользователь укажет:
"C:\Folder\App Files*" то компилятор будет рекурсивно включать файлы с именем "App Files" любых расширений, а также войдут все каталоги с подкаталогами которые находились в текущем каталоге. На выходе будут извлечены файлы с таковыми именами. Также на выходе будут созданы каталоги и подкаталоги, но каталоги с подкаталогами будут пустыми.

Если пользователь укажет:
"C:\Folder\App Files\*" то компилятор рекурсивно включит всё содержимое из каталога App Files.