[решено] Как выполнить комманду введенную интерактивно?

madmasles · Конфигурация компьютера

Цитата Pozia:

учетка переименовывается в цифру 4 »

Поменяйте

Код:

;...
RunWait("renuser.exe Администратор " & $sNewUserName)
;на
RunWait("renuser.exe Администратор " & GUICtrlRead($sNewUserName))
;...

Pozia · Отправлено: **23:41, 12-07-2012** | #12

madmasles, а сейчас имя учетки становится - 0

madmasles · Конфигурация компьютера

Цитата Pozia:

а сейчас имя учетки становится - 0 »

У Вас сначала удаление окна, а потом чтение, а читать уже нечего. Не обратил внимание на это.

Код:

#include <GUIConstantsEx.au3>

$sUserName = 'Pozia'
$sNewUserName = ''

$hGUI = GUICreate('Seven x64', 292, 150)
GUICtrlCreateLabel('Введи желаемое имя учетной записи ''Администратор''', 10, 10)
$nNewUserName = GUICtrlCreateInput($sUserName, 10, 70, 268, 20)
$nYes_Button = GUICtrlCreateButton('Ok', 10, 100, 130)
$nNo_Button = GUICtrlCreateButton('Cancel', 150, 100, 130)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $nNo_Button, $GUI_EVENT_CLOSE
            Exit
        Case $nYes_Button
            $sNewUserName = GUICtrlRead($nNewUserName)
            ConsoleWrite($sNewUserName & @LF)
            If Not $sNewUserName Then Exit
            ;RunWait('renuser.exe Администратор "' & $sNewUserName & '"')
            Exit
    EndSwitch
WEnd

Pozia · Отправлено: **20:32, 13-07-2012** | #14

madmasles, ваш работает. а вто с таймером никак не получается. Помогите, что я намутил не так?

Код:

#include <GUIConstantsEx.au3>
$sUserName = 'Pozia'
$sNewUserName = ''
Global $iTime_Expired = 0, $iTime_Counter = 100
Global $iWidth = 292, $iHeight = 150
$hGUI = GUICreate('Seven x64', $iWidth, $iHeight)
GUISetBkColor(0xBEBEBE) ;цвет окна
GUICtrlCreateLabel('Введи желаемое имя учетной записи ''Администратор''', 10, 10)
GUICtrlCreateLabel('', 10, 30)
$nNewUserName = GUICtrlCreateInput ($sUserName, 10, 70, 268, 20)
$nYes_Button = GUICtrlCreateButton('Ok', 10, 100, 130)
$nNo_Button = GUICtrlCreateButton('Cancel', 150, 100, 130)
GUISetState(@SW_SHOW, $hGUI)
_Set_YesButton_Timer_Proc()
AdlibRegister('_Set_YesButton_Timer_Proc', 1000)
While 1
    $vMsg = GUIGetMsg()
    If $iTime_Expired Then $vMsg = $nYes_Button
    Switch $vMsg
        Case $nNo_Button, $GUI_EVENT_CLOSE
            Exit
        Case $nYes_Button
            AdlibUnRegister() ;Отключение функции отсчёта
            GUIDelete($hGUI) ;Удаление окна
            $sNewUserName = GUICtrlRead($nNewUserName)
            ConsoleWrite($sNewUserName & @LF)
            If Not $sNewUserName Then Exit
            RunWait('renuser.exe Pozia "' & $sNewUserName & '"')
            Exit
    EndSwitch
WEnd
Func _Set_YesButton_Timer_Proc()
    GUICtrlSetData($nYes_Button, 'Ok (' & $iTime_Counter & ')')
    $iTime_Counter -= 1
    If $iTime_Counter < 0 Then
        AdlibUnRegister()
        $iTime_Expired = 1
    EndIf
EndFunc
exit

Pozia · Отправлено: **20:55, 16-07-2012** | #15

ребята помогите пожалуйста, не получается последний штрих

ferget · Отправлено: **02:33, 17-07-2012** | #16

Код:

#include <GUIConstantsEx.au3>
$sUserName = 'Pozia'
$sNewUserName = ''
Global $iTime_Expired = 0, $iTime_Counter = 100
Global $iWidth = 292, $iHeight = 150
$hGUI = GUICreate('Seven x64', $iWidth, $iHeight)
GUISetBkColor(0xBEBEBE) ;цвет окна
GUICtrlCreateLabel('Введи желаемое имя учетной записи ''Администратор''', 10, 10)
GUICtrlCreateLabel('', 10, 30)
$nNewUserName = GUICtrlCreateInput ($sUserName, 10, 70, 268, 20)
$nYes_Button = GUICtrlCreateButton('Ok', 10, 100, 130)
$nNo_Button = GUICtrlCreateButton('Cancel', 150, 100, 130)
GUISetState(@SW_SHOW, $hGUI)
_Set_YesButton_Timer_Proc()
AdlibRegister('_Set_YesButton_Timer_Proc', 1000)
While 1
    $vMsg = GUIGetMsg()
    If $iTime_Expired Then $vMsg = $nYes_Button
    Switch $vMsg
        Case $nNo_Button, $GUI_EVENT_CLOSE
            Exit
        Case $nYes_Button
            AdlibUnRegister() ;Отключение функции отсчёта
            $sNewUserName = GUICtrlRead($nNewUserName)
			GUIDelete($hGUI) ;Удаление окна
            ConsoleWrite($sNewUserName & @LF)
            If Not $sNewUserName Then Exit
            RunWait('renuser.exe Pozia "' & $sNewUserName & '"')
            Exit
    EndSwitch
WEnd
Func _Set_YesButton_Timer_Proc()
    GUICtrlSetData($nYes_Button, 'Ok (' & $iTime_Counter & ')')
    $iTime_Counter -= 1
    If $iTime_Counter < 0 Then
        AdlibUnRegister()
        $iTime_Expired = 1
    EndIf
EndFunc
exit

Pozia · Отправлено: **20:54, 17-07-2012** | #17

большое спасибо всем откликнувшимся