[Drongo]

serega355, У вас не отображается путь к Рабочей папке в свойствах ярлыка.

Зачем такая жёсткая привязка?

Код:

DefaultDirName=C:\Program Files\Rockstar Games\Grand Theft Auto Racing Driver

Тему перенесу в соответствующий раздел, вам помогу.

[R.i.m.s.k.y.]

Еще косметический вопрос: как увеличить окошко выбора компонентов и само белое поле с компонентами? А то одна строчка не влезает и из-за нее приходится вниз проматывать.

Авансом спасибо!

[YURSHAT]

Еще косметический вопрос: как увеличить окошко выбора компонентов и само белое поле с компонентами? А то одна строчка не влезает и из-за нее приходится вниз проматывать. »

WizardForm.ComponentsList.Width:= ScaleX(550);
WizardForm.TypesCombo.Width:= ScaleX(550);

[Tukash]

помогите!!! нашел скрипт

Код:

var
  RunProg: TCheckBox;

procedure CheckBoxChecked;
var
  res: Integer;
begin
  if RunProg.Checked then
  // запускаем Grand Theft Auto IV
  Exec(ExpandConstant('{src}\Redistributables\gfwlivesetup.exe'), '',
       ExpandConstant('{src}\Redistributables'), SW_HIDE, ewWaitUntilTerminated, res);
end;

procedure GreatCheckBox;
begin
  RunProg:= TCheckBox.Create(WizardForm);
  with RunProg do
    begin
      Parent := WizardForm;
      Caption := 'Запустить игру?';
      SetBounds(140,330,150,15);
      Cursor:= crHand;
      Checked:= True;
    end;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpFinished then GreatCheckBox;
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssDone then CheckBoxChecked;
end;

это чекбокс на странице завершения, но что то не получаеться, мне надо что-бы этот чекбокс предлогал, запускать установленную программу, но как прописать правильно непойму, это совсем сбило с толку:!

Код:

  Exec(ExpandConstant('{src}\Redistributables\gfwlivesetup.exe'), '',
       ExpandConstant('{src}\Redistributables'), SW_HIDE, ewWaitUntilTerminated, res);

... надо запустить LaunchGTAIV.exe находиться в {app}, папка с игрой, помогите!!!

[A1EXXX]

Tukash, если скрипт верен, то, наверное, так:

Код:

Exec(ExpandConstant('{app\LaunchGTAIV.exe'), '',
       ExpandConstant('{app}'), SW_HIDE, ewWaitUntilTerminated, res);

[Tukash]

A1EXXX
блиииин во я тупанул)))) благодарю!

[Drongo]

Ребята, по возможности посмотрите перенесённое сообщение 869, человек ведь ждёт.

[A1EXXX]

Drongo, serega355, если пути указаны правильно, то вероятней всего, не хватает рабочей папки в свойствах ярлыка - WorkingDir: {app}; , - попробуйте так:

читать дальше »

Код:

; Скрипт создан при помощи мастера создания скриптов.
; СМ. ДОКУМЕНТАЦИЮ ДЛЯ ИЗУЧЕНИЯ ДЕТАЛЕЙ ОТНОСИТЕЛЬНО СОЗДАНИЯ ФАЙЛОВ СКРИПТА INNO SETUP!

[Setup]
AppName=Grand Theft Auto Racing Driver
AppVerName=Grand Theft Auto Racing Driver 1.5
AppPublisher=Rockstar Games
AppPublisherURL=http://rockstargames.ru/
AppSupportURL=http://rockstargames.ru/
AppUpdatesURL=http://rockstargames.ru/
DefaultDirName=C:\Program Files\Rockstar Games\Grand Theft Auto Racing Driver
DefaultGroupName=Grand Theft Auto Racing Driver
LicenseFile=D:\Игромания\Grand Theft Auto Racing Driver\ReadMe\Readme\License.txt
InfoBeforeFile=D:\Игромания\Grand Theft Auto Racing Driver\ReadMe\Readme\info.txt
InfoAfterFile=D:\Игромания\Grand Theft Auto Racing Driver\ReadMe\Readme\files.txt
OutputDir=D:\Игромания\Инсталлятор GTA Racing Driver
OutputBaseFilename=setup
SetupIconFile=D:\Игромания\Grand Theft Auto Racing Driver\data\Icons\app.ico
Password=1345O-9087H-0967K-3555R
Compression=lzma/ultra
SolidCompression=yes
DiskSpanning=yes
SlicesPerDisk=1
DiskSliceSize=999999999
DiskClusterSize=4096
ReserveBytes=0

[Languages]
Name: "russian"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
Name: "quicklaunchicon"; Description: "{cm:CreateQuickLaunchIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "D:\Игромания\Grand Theft Auto Racing Driver\gta_sa.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "D:\Игромания\Grand Theft Auto Racing Driver\unins000.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "D:\Игромания\Grand Theft Auto Racing Driver\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
; ОТМЕТЬТЕ: Не используйте "Флажки: Проигнорировать версию" на любых общедоступных системных файлах

[Icons]
Name: "{group}\Grand Theft Auto Racing Driver"; Filename: "{app}\gta_sa.exe"; WorkingDir: {app};
Name: "{group}\{cm:ProgramOnTheWeb,Grand Theft Auto Racing Driver}"; Filename: "http://rockstargames.ru/"
Name: "{group}\{cm:UninstallProgram,Grand Theft Auto Racing Driver}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\Grand Theft Auto Racing Driver"; Filename: "{app}\gta_sa.exe"; WorkingDir: {app}; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\Grand Theft Auto Racing Driver"; Filename: "{app}\gta_sa.exe"; WorkingDir: {app}; Tasks: quicklaunchicon

[Run]
Filename: "{app}\gta_sa.exe"; WorkingDir: {app}; Description: "{cm:LaunchProgram,Grand Theft Auto Racing Driver}"; Flags: nowait postinstall skipifsilent

[serg aka lain]

человек ведь ждёт. »

Возможно, так:

Код:

[Icons]
Name: "{group}\Grand Theft Auto Racing Driver"; Filename: "{app}\gta_sa.exe"; WorkingDir: "{app}";
Name: "{group}\{cm:ProgramOnTheWeb,Grand Theft Auto Racing Driver}"; Filename: "http://rockstargames.ru/"
Name: "{group}\{cm:UninstallProgram,Grand Theft Auto Racing Driver}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\Grand Theft Auto Racing Driver"; Filename: "{app}\gta_sa.exe"; WorkingDir: "{app}"; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\Grand Theft Auto Racing Driver"; Filename: "{app}\gta_sa.exe";  WorkingDir: "{app}"; Tasks: quicklaunchicon

[Serega]

serega355, немного добавлю...

Секция [Setup]:
1. Исправьте: DefaultDirName={pf}\Rockstar Games\Grand Theft Auto Racing Driver
2. Добавьте: Encryption=yes - не критично, но раз уж шифруете...
Секция [Files]:
Удалите первые две строки, они не нужны, т.е. должно быть так:

Код:

[Files]
Source: "D:\Игромания\Grand Theft Auto Racing Driver\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs

Ну и про секцию [Icons] A1EXXX и serg aka lain уже сказали