Цитата AndreyGun:
http://fixila.com/download/FixilaPlus.exe »
|
При запуске Касперский ругается на попытку приложения загрузить вредоносное ПО, предупреждать нужно
Цитата AndreyGun:
1ый Вопрос - Возможно разместить ссылку в описании на странице приветствия? »
|
Какой смысл в ссылке на лицензию? Лучше сделать отдельную страничку, т.к. если пользователь запустит установщик на компе, где нет интернета - смысл ссылки пропадает
Приведу сразу пример кода, т.к. вроде бы не видел ещё данной необходимости у кодеров, может, ещё кому пригодится для других нужд
читать дальше »
Код:
!include "MUI2.nsh" ; Подключаем графический интерфейс средствами nsDialogs
!define MUI_PAGE_CUSTOMFUNCTION_SHOW "WelcomeFinishLink_K.A.V._Example" ; Функция создания ссылки
!insertmacro MUI_PAGE_WELCOME ; Показ странички приветствия
Page custom MyComponents ; Показ странички компонентов
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "russian"
Caption "K.A.V. Example"
Name "K.A.V. Example"
OutFile "TestLink.exe"
Function WelcomeFinishLink_K.A.V._Example ; Функция создания ссылки
StrCpy $0 "175"
; Если используете MUI_WELCOMEPAGE_TITLE_3LINES, поставьте значение "185"
${NSD_CreateLink} 120u $0u 195u 10u "OSZone.net - лучший сайт!" ; Текст и позиция ссылки
Pop $0
SetCtlColors $0 "0x0000A8" "0xFFFFFF" ; Назначаем синий цвет текста (первый параметр) и цвет фона текста (второй параметр)
${NSD_OnClick} $0 "OpenSite_K.A.V._Example" ; Назначаем действие по нажатию на ссылку, выполнение функции
FunctionEnd
Function OpenSite_K.A.V._Example ; Функция, выполняемая при нажатии на ссылку
ExecShell open "http://www.oszone.net/" ; Команда открытия сайта в интернете
FunctionEnd
Function MyComponents ; Показ странички компонентов
nsDialogs::Create 1018
Pop $0
SetCtlColors $0 "" "0xFFFF80" ; Назначаем желтый цвет фона
SetCtlColors $HWNDPARENT "" "0xFFFF80" ; Назначаем желтый цвет фона
${NSD_CreateCheckBox} 0 45u 100u 10u "Тестовый элемент" ; Тестовый элемент чекбокса
Pop $0
SetCtlColors $0 "" "0xFFFF80" ; Назначаем желтый цвет фона каждому создаваемому элементу
nsDialogs::Show
FunctionEnd
Section
SectionEnd
Цитата AndreyGun:
2ой Вопрос - Возможно ли такое сделать в NSIS (несколько страниц выбора компонентов, только на одной странице одна галочка)? »
|
Справочник по NSIS » Описание плагинов » nsDialogs: Создаем собственные страницы инсталлятора
Читали? Походу нет
Цитата AndreyGun:
ну и 3ий Вопрос - Можно ли установить фон, на страницАХ выбора компонентов. »
|
Ответ в примере моего кода выше