[Iska]

Значит, не находит. Ибо, если бы нашёл — писал бы ещё кроме пути, как я уже сказал выше, следующее:

Template found in document [bla-bla-bla]

Давайте-ка посмотрим, какие на самом деле там прикреплённые шаблоны. Выполните такой скрипт:

Код:

Option Explicit

Dim strDocumentList
Dim strDocument

Dim objFSO
Dim objWord


strDocumentList = "E:\Песочница\0116\DocumentList.txt"


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strDocumentList) Then
	Set objWord = WScript.CreateObject("Word.Application")
	
	With objFSO.OpenTextFile(strDocumentList)
		Do Until .AtEndOfStream
			strDocument = .ReadLine()
			
			If objFSO.FileExists(strDocument) Then
				WScript.Echo strDocument
				
				With objWord.Documents.Open(strDocument)
					WScript.Echo "  " & .AttachedTemplate
					
					.Close
				End With
			Else
				WScript.Echo "Document [" & strDocument & "] not found"
			End If
		Loop
		
		.Close
	End With
	
	objWord.Quit
	
	Set objWord = Nothing
Else
	WScript.Echo "Document list [" & strDocumentList & "] not found"
End If

Set objFSO = Nothing

WScript.Quit 0

в виде:

Код:

cscript.exe //nologo "<Путь к скрипту>" >c:\0001.txt

опять указав в «strDocumentList» путь к Вашему списку. Полученный в результате исполнения скрипта файл «c:\0001.txt» упакуйте в архив и прикрепите к сообщению (либо выложите на обменник, а сюда — ссылку).