В последней версии
3.3 опять сделали тихую установку.
Ключи установки:
читать дальше »
Цитата:
Usage:
<Setup package fullpath>
-d Install the program as default.
-p Change file installation path.
-dt Enable desktop shortcut.
-udt Disable desktop shortcut.
-ql Enable quick launch.
-uql Disable quick launch.
-sm Add to the Start menu.
-usm Don't add to the Start menu.
-a Install for all users.
-ua Install for current user only.
-fp Install Firefox Plug-in.
-ufp Don't install Firefox Plug-in.
|
Например, если мы хотим установить программу для всех пользователей, не создавая ярлыков на рабочем столе и в быстром запуске, но создать группу в меню "пуск", то ставим так:
Код:
start /wait "" "FoxitReader.exe" -udt -uql -sm -a -ufp
Но есть проблемы: ставится панель Ask для эксплорера. Через .bat, видимо этого не избежать. Плюс ярлыки на ebay создаются аж в трех местах...
Далее как я пошагово решал проблемы (можно не читать)
читать дальше »
...но это удалить просто. Например, для русской XP:
Код:
del /Q /F "%ALLUSERSPROFILE%\Рабочий стол\eBay.url"
del /Q /F "%ALLUSERSPROFILE%\Главное меню\Программы\ebay.url"
del /Q /F "%AppData%\Microsoft\Internet Explorer\Quick Launch\ebay.url"
Добавлено:
Панель Ask можно удалить после установки фоксита, прописав такой код:
Код:
MsiExec.exe /uninstall {86D4B82A-ABED-442A-BE86-96357B70F4FE} /qb
Панель мы победим, но Ask останется поисковой службой по умолчанию. Это я пока не устранил, но примерный план есть. Для устранения, нужно до установки фоксита запомнить значение параметра
DefaultScope в ветке
[HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\SearchScopes], а после установки фоксита и удаления аска надо удалить всю ветку
[HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\SearchScopes\{171DEBEB-C3D4-40b7-AC73-056A5EBA4A7E}] и записать старое значение
DefaultScope. Сейчас попробую это реализовать.
Добавлено:
Вроде закончил. Тестировал на XP x86 и семерке x64:
Итоговый bat файл установки:
читать дальше »
PHP код:
:: Автоустановка FoxitReader 3.3.0.430
@echo off
:: Запоминаем стартовую страницу и поисковик
For /F "Tokens=2*" %%a In ('Reg Query "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\SearchScopes"^|Find /I "DefaultScope"') Do Set DSearch=%%b
For /F "Tokens=3*" %%a In ('Reg Query "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main"^|Find /I "Start Page"') Do Set SPage=%%b
:: Устанавливаем
start /wait "" "FoxitReader.exe" -dt -uql -sm -a -ufp
:: Стираем ярлыки eBay (так много, потому что учел разные пути на XP и семерке, а также установку для одного и всех юзеров)
del /Q /F "%ALLUSERSPROFILE%\Рабочий стол\eBay.url"
del /Q /F "%ALLUSERSPROFILE%\Главное меню\Программы\ebay.url"
del /Q /F "%USERPROFILE%\Рабочий стол\eBay.url"
del /Q /F "%USERPROFILE%\Главное меню\Программы\ebay.url"
del /Q /F "%AppData%\Microsoft\Internet Explorer\Quick Launch\ebay.url"
del /Q /F "%ALLUSERSPROFILE%\Microsoft\Windows\Start Menu\Programs\ebay.url"
del /Q /F "%PUBLIC%\Desktop\ebay.url"
del /Q /F "%USERPROFILE%\Desktop\ebay.url"
del /Q /F "%AppData%\Microsoft\Windows\Start Menu\Programs\ebay.url"
:: Удаляем тулбар Ask.com
MsiExec.exe /uninstall {86D4B82A-ABED-442A-BE86-96357B70F4FE} /qb
:: Возвращаем исходную стартовую страницу и службу поиска
reg add "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\SearchScopes" /v DefaultScope /d %DSearch% /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main" /v "Start Page" /d "%SPage%" /f
:: Удаляем поиск от Ask.com
reg delete "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\SearchScopes\{171DEBEB-C3D4-40b7-AC73-056A5EBA4A7E}" /f
exit
Habetdin, Ошибочку исправил, спасибо
