Имя пользователя:
Пароль:  
Помощь | Регистрация | Забыли пароль?  

Показать сообщение отдельно

Ветеран


Contributor


Сообщения: 2703
Благодарности: 1683

Профиль | Отправить PM | Цитировать


it3, Что Вас не устраивает? Останутся все файлы 20??-??-??.tif? Или что останется единственный нумерованный файл?
it3, Если надо в каждой дате сохранить последний файл (отбор файла по каждой дате по времени последнего изменения)
Код: Выделить весь код
@Echo Off
Set "BoxIn=Z:\Box_In"
Set "BoxOut=Z:\Box_Out"
Set "Mask=20??-??-??*.tif" 

Set "Dtt=0000-00-00"
FOR %%f IN ("%BoxIn%\%Mask%") DO Set Df=%%~nf &Call :LastFile "%%Df:~0,10%%" "%%~xf"
GoTo :Eof

:LastFile
	If "%Dtt%"==%1 GoTo :Eof
	Set "Dtt=%~1"
	Set "MaskData=%BoxIn%\%Dtt%*%~2"

	FOR /F "usebackq skip=1 delims=" %%f IN (`2^>nul Dir "%MaskData%" /B /A:-D /O:-D /T:W`) DO >nul Move "%BoxIn%\%%f" "%BoxOut%\"
GoTo :Eof
А если вообще не привязываться ко времени создания или изменения, а к номеру (но это медленнее)
Код: Выделить весь код
@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion

Set "BoxIn=Z:\Box_In"
Set "BoxOut=Z:\Box_Out"
Set "Mask=20??-??-??*.tif" 

Set "Dtt=0000-00-00"
FOR %%f IN ("%BoxIn%\%Mask%") DO Set Df=%%~nf &Call :LastFile "%%Df:~0,10%%" "%%~xf"

GoTo :Eof

:LastFile
	If "%Dtt%"==%1 GoTo :Eof
	Set "Dtt=%~1"
	Set "MaskData=%BoxIn%\%Dtt%*%~2

	Set /A Max=0
	Set "NF=%~1%~2"
	FOR /F "usebackq tokens=1,2* delims=()" %%i IN (`2^>nul Dir "%MaskData%" /B /A:-D /O:-N`) DO If Not "%%k"=="" If !Max! LSS %%j Call Set /A Max=%%j &Set "NF=%%i(%%j)%%k"
	FOR %%i IN ("%MaskData%") DO If Not "%%~nxi"=="%NF%" Move /Y "%%i" "%BoxOut%\" >nul
GoTo :Eof

-------
Даже самая сложная проблема обязательно имеет простое, лёгкое для понимания, неправильное решение. Каждое решение плодит новые проблемы.

Это сообщение посчитали полезным следующие участники:

Отправлено: 18:32, 09-06-2018 | #32