[Diamond]

Creat0R,

Скрипт для конвертирования выделенного текста...

Интересный скрипт, правда я не совсем понял в чём конкретно его предназначение...

Вот ещё, как вариант... Скрипт для Транслитерации текста (работает только в одну сторону):

Код:

#NoTrayIcon
$Dict = ObjCreate("Scripting.Dictionary")
$ru = StringSplit("А|Б|В|Г|Д|Е|Ё|Ж|З|И|Й|К|Л|М|Н|О|П|Р|С|Т|У|Ф|Х|Ц|Ч|Ш|Щ|Ъ|Ы|Ь|Э|Ю|Я","|")
$en = StringSplit("A|B|V|G|D|E|E|Zh|Z|I|Y|K|L|M|N|O|P|R|S|T|U|F|H|Ts|Ch|Sh|Sch|'|Y|'|E|Yu|Ya","|")
For $i=1 To $ru[0]
    $Dict.Add($ru[$i],$en[$i])
Next
HotKeySet("^ё", "Translit")
HotKeySet("^й", "Quit")
;~ --------------------------

While 1
    Sleep(1000)
WEnd

Func Translit()
    Local $String, $Key, $CheckStr, $str, $OldSymbol, $NewSymbol
    $CheckStr = ClipGet()
    Send("^{INS}")
    Sleep(10)
    $str = ClipGet()
    If $CheckStr = $str Then Return
    For $i=1 To StringLen($str)
        $OldSymbol = StringMid($str,$i,1)
        $Key = StringUpper($OldSymbol)
        If $Dict.Exists($Key) Then
            If StringIsLower($OldSymbol) Then
                $NewSymbol = StringLower($Dict.Item($Key))
            Else
                $NewSymbol = $Dict.Item($Key)
            EndIf
            $String &= $NewSymbol
        Else
            $String &= $OldSymbol
        EndIf
    Next
    ClipPut($String)
    Sleep(10)
    Send("+{INS}")
EndFunc

Func Quit()
    Exit
EndFunc