Страница-фейс инсталлятора в виде круга.
С появлением рождественского подарка от винамповцев, библиотеки для перемещения окна за любую точку - можно завершить и затею с круглым фейсом.
Выглядит это так (ессно, как вариант) :
Код:
!addplugindir .
!include nsDialogs.nsh
!include WinMessages.nsh
Page Custom mypagecreate
Page InstFiles
OutFile "CreateRoundRectRgn.exe"
Var dlg
Var button
Function .onInit
InitPluginsDir
File /oname=$PLUGINSDIR\s.bmp "s.bmp"
FunctionEnd
Function .onGUIInit
; вызов DLL для перемещения окна за любую точку
MoveAnywhere::Hook
; окно всегда поверх
System::Call "user32::SetWindowPos(i$HWNDPARENT,i-1,i,i,i,i,i3)"
; убрать заголовок
System::Call `user32::SetWindowLong(i$HWNDPARENT,i${GWL_STYLE},0x9480084C)i.R0`
; убрать пунктирную рамку границы при перетаскивании окна
System::Call "user32::SystemParametersInfo(i0x0025,i0,*i.R0,i0)"
System::Call "user32::SystemParametersInfo(i0x0025,i1,i0,i0)"
FunctionEnd
Function .onGUIEnd
System::Call "user32::SystemParametersInfo(i0x0025,iR0,i0,i0)"
FunctionEnd
Function mypagecreate
nsDialogs::Create 1018
Pop $dlg
; цвет
SetCtlColors $HWNDPARENT "" 0xbde2f4
SetCtlColors $dlg "" 0xbde2f4
${NSD_CreateButton} 33u 35u 80 59 ""
Pop $button
; устанавливаем свой стиль кнопки (помещаем рисунок на кнопку)
StrCpy $0 $PLUGINSDIR\s.bmp
${NSD_AddExStyle} $button ${WS_EX_TRANSPARENT}|${WS_EX_TOPMOST}
${NSD_AddStyle} $BUTTON "${BS_BITMAP}"
System::Call 'user32::LoadImage(i 0, t r0, i ${IMAGE_BITMAP}, i 0, i 0, i ${LR_CREATEDIBSECTION}|${LR_LOADFROMFILE}) i.s'
Pop $6
SendMessage $BUTTON ${BM_SETIMAGE} ${IMAGE_BITMAP} $6
; фейс в виде круга
System::Call "*(i, i, i, i)i.r0"; создать новую структуру
System::Call "User32::GetClientRect(i$HWNDPARENT, ir0)"; Получить новые координаты структуры - в $0
System::Call "*$0(i, i, i.r1, i.r2)"
IntOp $1 $1 + 5
IntOp $2 $2 + 30
System::Call "Gdi32::CreateRoundRectRgn(i0,i0,i200,i200,i200,i200)i.r0"
System::Call "User32::SetWindowRgn(i$HWNDPARENT, ir0, i1)"
${NSD_OnClick} $button done
nsDialogs::Show
FunctionEnd
Function done
SendMessage $hwndparent ${WM_CLOSE} 0 0
FunctionEnd
Section
SectionEnd
Ессно кнопку делаем какую угодно и вешаем на неё что угодно.
Правда хотелось таскать фейс
с рисунком в качестве фона, но что то у меня перетаскивание при этом не работает... Ну да и ладно...
