[saurn]

здравствуйте, помогите со скриптом. на "SelectProgramGroupPage" вместо кнопки "GroupBrowseButton" хотелось чтоб было как в примере, небольшое "окно" (рисунок во влажении) »

Пример ниже:

читать дальше »

Код:

[*Setup]
AppName=MyApp
AppVerName=MyApp
DefaultDirName={pf}\MyApp
DefaultGroupName=MyApp
AllowNoIcons=true
Compression=none
DiskSpanning=true
DiskSliceSize=736000000

[*Icons]
Name: "{group}\My Program"; Filename: "{app}\MyProg.exe"

[*Code]
var
  SelectFolderInStartMenuLabel, SelectFolderInStartMenuLabel2: TLabel;
  StartMenuFolderTreeView: TStartMenuFolderTreeView;


procedure StartMenuFolderOnChange(Sender: TObject);
begin
WizardForm.GroupEdit.Text:= AddBackslash(StartMenuFolderTreeView.Directory)+ ExpandConstant('{#SetupSetting("DefaultGroupName")}');
end;

procedure DisableCreateStartMenuFolderOnClick(Sender: TObject);
begin
   case TObject(Sender) of
      WizardForm.NoIconsCheck:
      begin
         WizardForm.GroupEdit.Enabled:= not(WizardForm.GroupEdit.Enabled);
         StartMenuFolderTreeView.Enabled:= WizardForm.GroupEdit.Enabled;
      end;
   end;
end;

procedure InitializeWizard();
begin

  with WizardForm.SelectGroupBitmapImage do
  begin
    Visible := False;
  end;

  SelectFolderInStartMenuLabel := TLabel.Create(WizardForm);
  with SelectFolderInStartMenuLabel do
  begin
    Parent := WizardForm.SelectProgramGroupPage;
    Caption := 'Текущая папка:';
    SetBounds(ScaleX(0), ScaleY(0), ScaleX(85), ScaleY(13));
    Transparent := False;
    WordWrap := True;
  end;

  SelectFolderInStartMenuLabel2 := TLabel.Create(WizardForm);
  with SelectFolderInStartMenuLabel2 do
  begin
    Parent := WizardForm.SelectProgramGroupPage;
    SetBounds(ScaleX(0), ScaleY(47), ScaleX(118), ScaleY(13));
    Caption := 'Существующие папки:';
    Transparent := False;
  end;


  with WizardForm.GroupBrowseButton do
  begin
    Visible := False;
  end;

  with WizardForm.GroupEdit do
  begin
    SetBounds(ScaleX(0), ScaleY(17), ScaleX(417), ScaleY(21));
    ReadOnly := True;
  end;

  with WizardForm.SelectStartMenuFolderBrowseLabel do
  begin
    Visible := False;
  end;

  with WizardForm.SelectStartMenuFolderLabel do
  begin
    Visible := False;
  end;

  with WizardForm.NoIconsCheck do
  begin
    Caption := 'Отключить создание папки в меню "Пуск"';
    WizardForm.NoIconsCheck.OnClick:= @DisableCreateStartMenuFolderOnClick;
  end;

  StartMenuFolderTreeView := TStartMenuFolderTreeView.Create(WizardForm);
  with StartMenuFolderTreeView do
  begin
    Parent := WizardForm.SelectProgramGroupPage;
    SetBounds(ScaleX(0), ScaleY(64), ScaleX(417), ScaleY(142));
    SetPaths(ExpandConstant('{userprograms}'),ExpandConstant('{commonprograms}'),ExpandConstant('{userstartup}'),ExpandConstant('{commonstartup}'));
    OnChange:= @StartMenuFolderOnChange;
  end;
end;

P. S.
Это просто пример. Под свой скрипт адаптируете его сами.