[решено] Счётчик файлов - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - [решено] Счётчик файлов (http://forum.oszone.net/showthread.php?t=285167)

Счётчик файлов

Здравствуйте.

Для пронумеровки файлов в папке использую этот код

Код:

setlocal enableextensions enabledelayedexpansion

set /a lCount = 0

for /f "delims=*" %%i in ('dir /b /s "D:\inUse\*.txt"') do (

    set /a lCount += 1

    ren "%%i" "file!lCount!%%~xi"

)

endlocal

На выходе имеем следующее:

file1.txt
file2.txt
file3.txt
....
file30.txt

Подскажите пожалуйста, как сделать так, чтобы нумерация начиналась с конца, то есть file30.txt после применения скрипта стал file1.txt

При условии, что среди них уже нет «fileXXX.txt»:

Код:

@echo off

setlocal enableextensions enabledelayedexpansion



for /f "usebackq delims=" %%i in (

        `dir /b /s /a:-d "D:\inUse\*.txt" ^| find.exe /c /v ""`

) do set /a iTotal = %%i



set /a iCount = iTotal



for /f "usebackq delims=" %%i in (

        `dir /b /s /a:-d "D:\inUse\*.txt"`

) do (

        ren "%%i" "file!iCount!%%~xi"

        set /a iCount -= 1

)



endlocal

exit /b 0