Компьютерный форум OSzone.net  

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)
-   Microsoft Windows 2000/XP (http://forum.oszone.net/forumdisplay.php?f=6)
-   -   [решено] вопрос: контроль за службой (http://forum.oszone.net/showthread.php?t=98939)

foxbat 24-01-2008 13:05 724445
вопрос: контроль за службой
 
Добрый час ! Вопрос: можно ли средствами CMD контролировать статус службы (работает, пауза, останов), например может есть команда которая возвращает значение некого кода статуса ? Спасибо.

Petya V4sechkin 24-01-2008 13:17 724457
sc /?
sc query имя_службы

Пример:
sc query wuauserv

foxbat 24-01-2008 13:37 724471
имя службы ? я так понимаю это то что в taskmanager написано ? Вот например данный пример работает, а службу такую я не нашёл wuauserv. С другой стороны так которая есть служба не работает, выдает X:\>sc query lsass
[SC] EnumQueryServicesStatus:OpenService FAILED 1060:

Petya V4sechkin 24-01-2008 13:40 724475
Цитата:
Цитата foxbat
имя службы ? я так понимаю это то что в taskmanager написано ?
Список стандартных служб (столбец Название службы).
Или полный список (служб и драйверов) в разделе реестра HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services

foxbat 24-01-2008 14:57 724529
Большое спасибо, то что надо. Ещё вопрос напоследок, а это применимо только к службам ? а к процессам нет ? т.е. я хочу сказать если у меня в диспетчере "висит" qip.exe, его можно таким образом контролировать ?

Petya V4sechkin 24-01-2008 15:03 724534
foxbat, определить, запущен процесс или нет?
Tasklist /?
Tasklist /V /FI "IMAGENAME eq qip.exe"

foxbat 24-01-2008 15:36 724565
нет немножко не то, в общем я понял что с помощью sc query можно узнать статус службы, теперь надо узнать как его использовать, в общем задача такая, что есть некая служба "Х" и ей по требованию надо сделать останов (net stop X), но она не всегда с первого раза останавливается, надо делать ещё и ещё до тех пор пока не будет остановлена а затем вновь запустить. Мне сказали что такое (батник который контролировал останов службы и вновь её запускал) возможно сделать средствами командного процессора windows. Можно такое сделать ?
P.S. про qip я глупость спросил :)

Vadikan 24-01-2008 21:02 724824
Цитата:
Цитата foxbat
Мне сказали что такое (батник который контролировал останов службы и вновь её запускал) возможно сделать средствами командного процессора windows. Можно такое сделать ? »
Вот пример на VBS - VBScript Scripting Techniques: Services

amel27 25-01-2008 09:09 725104
Цитата:
Цитата foxbat
батник который контролировал останов службы и вновь её запускал »
что-нибудь типа:
Код:
@echo off
If "%1"=="" Exit
Set STATUS=RUNNING

@echo Остановка сервиса "%1"...
:LBL0
SC STOP %1 >nul 2>&1
For /F "Tokens=3 Usebackq Delims=: " %%i in (`SC QUERY %1^|FIND "STATE"`) Do SET STATUS=%%i
If NOT "%STATUS%"=="STOPPED" GOTO :LBL0
SC START %1 >nul 2>&1
@echo Произведен перезапуск сервиса!
имя службы передавать как параметр

foxbat 25-01-2008 15:26 725340
amel27 , у Вас этот скрипт без ошибок отрабатывает ?

HLT 25-01-2008 16:46 725384
Цитата:
Цитата foxbat
amel27 , у Вас этот скрипт без ошибок отрабатывает ? »
Отрабатывает нормально.
Если у Вас выдает ошибку - сообщение об ошибке сюда

SavmiN 29-01-2008 23:39 728566
Цитата:
Цитата Vadikan
Вот пример на VBS »
и что с этим кодом надо сделать!
сохранить как … и в автозагрузку ??? или в реестр ??? хочу знать! ;)

Vadikan 29-01-2008 23:42 728571
Цитата:
Цитата SavmiN
сохранить как … и в автозагрузку ??? »
Если нужно, чтобы код выполнялся при запуске ОС, то да, в автозагрузку.
Цитата:
Цитата SavmiN
или в реестр ??? »
Вообще не понял вопроса...

amel27 30-01-2008 03:32 728646
Цитата:
Цитата Vadikan
Если нужно, чтобы код выполнялся при запуске ОС »
гм, какой смысл перезапускать службу при загрузке?

Vadikan 30-01-2008 04:35 728656
Цитата:
Цитата amel27
гм, какой смысл перезапускать службу при загрузке? »
Да вроде SavmiN в соседней теме пытался что-то накрутить со службами, чтобы поведение службы менялось в зависимости от того, под какой учетной записью осуществляется вход.

amel27 30-01-2008 05:08 728661
Цитата:
Цитата Vadikan
в зависимости от того, под какой учетной записью осуществляется вход »
но тогда не "в автозагрузку" а в Logon-скрипт...
это я к тому, что скрипт отработает только если пользователь - локальный админ

foxbat 30-01-2008 14:44 729036
HLT,
+++
c:\>restar.vbs messenger
+++
Ошибка сценария

Сценарий: c:\resart.vbs
Строка: 1
Символ: 1
Ошибка: недопустимый знак
Код:....
Источник.....

короче ругается на @
Убираем собачку, ругается на Строка 2 Сивол 9 (на кавычки и т.д.). В этих всяких криптах я не чень силён, может тут у меня какой компилятор не правильный ??

Petya V4sechkin 30-01-2008 14:57 729041
foxbat, пост № 9 - скрипт .cmd, а не .vbs.

foxbat 30-01-2008 15:40 729080
:) спасибо большое ! Ошибок нет. :)

SavmiN 30-01-2008 17:31 729172
как я поняв - "сохранить как …" script.cmd ???
Цитата:
Цитата Vadikan
да, в автозагрузку »
- а как еще по другому заставить скрипт сработать автоматически %) ? а реестр упомянул - возможно скрипт загружать как службу
Цитата:
Цитата amel27
смысл перезапускать службу при загрузке »
- не при загрузке ОС, а при сбое службы ... и как понимаю надо ведь запустить скрипт как то! вот и зашла речь про автозапуск
Цитата:
Цитата amel27
Logon-скрипт...
отработает только если пользователь - локальный админ »
там был вопрос в том чтобы скрипт отрабатывал взависимости от имени влогинившегося пользователя (имеется на ПК два локальных админа - под одним нужна чистая система - а под другим полностью настоенная - с запуском службы "Start" ну и прочего мелкополезного софта ;) ...)
а вот как раз про Logon-скрипт - очень любопытно! поясни!
foxbat, - вы запускаете
Цитата:
Цитата foxbat
c:\>restar.vbs messenger »
вручную ??

amel27 31-01-2008 03:56 729526
Цитата:
Цитата SavmiN
Logon-скрипт - очень любопытно! поясни! »
Пуск\Выполнить: gpedit.msc
Путь: Конфигурация пользователя\Конфигурация Windows\Сценарии

сюда можно добавлять любые *.BAT, *.CMD, *.VBS или *.JS скрипты на вход и выход... правда локальные политики (в отличие от доменных) отрабатывают одинаково для всех локальных пользователей, поэтому распознавание пользователей придется встраивать в скрипт... вот доработанный вариант батника, который:

для пользователя USER-1: останавливает и отключает службу Планировщика задач и перегружает "Обозреватель"
для пользователя USER-2: восстанавливает состояние Планировщика и перезапускает службу Диспетчера печати.
Код:
@echo off

IF "%USERNAME%"=="User-1" (
        CALL :SC_STOP SCHEDULE
        CALL :SC_DISABLE SCHEDULE
        CALL :SC_RESTART BROWSER
)

IF "%USERNAME%"=="User-2" (
        CALL :SC_ENABLE SCHEDULE
        CALL :SC_START SCHEDULE
        CALL :SC_RESTART SPOOLER
)

EXIT

:SC_STOP
:: -----
Set STATUS=RUNNING
@echo Остановка сервиса "%1"...
:SC_STOP_LOOP
SC STOP %1 >nul
For /F "Tokens=3 Usebackq Delims=: " %%i in (`SC QUERY %1^|FIND "STATE"`) Do SET STATUS=%%i
If NOT "%STATUS%"=="STOPPED" GOTO :SC_STOP_LOOP
@echo Сервис остановлен!
:: -----
GOTO :EOF

:SC_START
:: -----
Set STATUS=STOPPED
@echo Запуск сервиса "%1"...
:SC_START_LOOP
SC START %1 >nul
For /F "Tokens=3 Usebackq Delims=: " %%i in (`SC QUERY %1^|FIND "STATE"`) Do SET STATUS=%%i
If NOT "%STATUS%"=="RUNNING" GOTO :SC_START_LOOP
@echo Сервис запущен!
:: -----
GOTO :EOF

:SC_RESTART
:: -----
CALL :SC_STOP  %1
CALL :SC_START %1
:: -----
GOTO :EOF

:SC_ENABLE
:: -----
SC CONFIG %1 start= demand >nul
@echo Сервис %1 включен!
:: -----
GOTO :EOF

:SC_DISABLE
:: -----
SC CONFIG %1 start= disabled >nul
@echo Сервис %1 отключен!
:: -----
GOTO :EOF

foxbat 31-01-2008 09:26 729614
Есть подробная информация по возможностям командной строки ? в справочнике параметров по командной строке (v 1.1) я не нахожу описания и поэтому не могу разобрать например такие операторы

@echo off
If "%1"=="" Exit
Set STATUS=RUNNING

@echo Остановка сервиса "%1"...
:LBL0
SC STOP %1 >nul 2>&1
For /F "Tokens=3 Usebackq Delims=: " %%i in (`SC QUERY %1^|FIND "STATE"`) Do SET STATUS=%%i
If NOT "%STATUS%"=="STOPPED" GOTO :LBL0
SC START %1 >nul 2>&1
@echo Произведен перезапуск сервиса!

HLT 31-01-2008 09:54 729636
Цитата:
Цитата foxbat
For /F "Tokens=3 Usebackq Delims=: »
Хорошее описание токенсов и делимсов тут: http://www.robvanderwoude.com/ntfortokens.html

amel27 31-01-2008 10:12 729653
Цитата:
Цитата foxbat
Есть подробная информация по возможностям командной строки ? »
кое-что по-русски:
http://www.windowsfaq.ru/content/category/3/19/57/
http://www.windowsfaq.ru/content/category/3/7/45

SavmiN 01-02-2008 01:57 730350
Цитата:
Цитата amel27
локальные политики (в отличие от доменных) »
ну и попутный вопрос! - для домена на отдельном находящемся ПК - тоже в GP можно настроить для каждого или всех сразу свои сценарии??
а также: USER-1 - это имя учетной записи - а пароль как указывать для автологона? ну и совсем плохой вопрос - что такое в данном случае "%1" = что то припоминаю …

HLT,
Цитата:
описание токенсов и делимсов
- ну раз начали издеваться - то хотя бы на понятном русском языке %))) чтобы прочесть была возможность! ;)

amel27 01-02-2008 05:52 730391
Цитата:
Цитата SavmiN
в GP можно настроить для каждого или всех сразу свои сценарии?? »
в домене GPO привязываются к подразделениям (OU), соответственно политики отрабатывают для всех пользователей, входящих в этот контейнер... а уж сколько создавать OU и как по ним раскидывать пользователей - вопрос планирования.
Цитата:
Цитата SavmiN
USER-1 - это имя учетной записи - а пароль как указывать для автологона? »
скрипт отработает автоматически после регистрации пользователя, пароль не нужен
Цитата:
Цитата SavmiN
что такое в данном случае "%1" »
макрос, заменяемый при выполнении на значение первого параметра, переданного скрипту (или процедуре)

foxbat 01-02-2008 13:12 730657
если не трудно разьясните пож-та эту строку, я что понял сам откаментирую а вы меня поправте если не так:
SC STOP %1 >nul 2>&1
SC - команда cmd
STOP - команда (параметр) команды SC
%1 - параметр командной строки, в данном случае название сервиса
-до этого момента понятно, а дальше
>nul - ?? некое пустое устройство-файл, т.е. перенаправляем вникуда, (отчего ничего не видим в консоли когда выполняем команду)
2>&1 - "2>&1" это дублирование дескрипторов, т.е. выход дескриптора 2 (Ошибка вывода) направляется в дескриптор 1 (Вывод командной строки), так ? только с НУЛом у меня всё равно пустой экран. Вот к примеру пускаю В CMD


X:\>sc stop W32Time

SERVICE_NAME: W32Time
TYPE : 20 WIN32_SHARE_PROCESS
STATE : 3 STOP_PENDING
(NOT_STOPPABLE,NOT_PAUSABLE,IGNORES_SHUTDOWN)
WIN32_EXIT_CODE : 0 (0x0)
SERVICE_EXIT_CODE : 0 (0x0)
CHECKPOINT : 0x1
WAIT_HINT : 0x3e8

X:\>sc stop W32Time >nul

ничего нет

X:\>sc stop W32Time >nul 2&>1

тоже ничего нет

SavmiN 01-02-2008 17:08 730839
amel27, у вас указано: Планировщик - "SCHEDULE", а после Сервер печати - "Spooler" ну и ещё "Browser"
У Планировщика исполняемый файл schedule.exe, у brouser - explorer.exe не знаю по печати, но вот сам вопрос: на Пк установлена оболочка Pshell с исполняемым файлом pshell.exe - как мне указывать его в коде? - это ведь не стандартная служба или сервис Windows … также имеется ещё одна программа за которой требуется наблюдение и перезапуск в случае сбоя или умышленной попытки отключения classic.exe - какое имя требуется задать в коде?
Спасибо!

amel27 01-02-2008 17:12 730841
Цитата:
Цитата foxbat
только с НУЛом у меня всё равно пустой экран »
можешь убрать 2&>1 - подавляет сообщения об ошибках... если ошибок нет то и перенаправлять нечего

Цитата:
Цитата SavmiN
как мне указывать его в коде? »
смотри имя ключа реестра в "HKLM\SYSTEM\CurrentControlSet\Services" (искать можно по полному имени сервиса или имени образа pshell.exe)

SavmiN 03-02-2008 19:26 732132
amel27, отлично! - осталось уточнить - уточняю ;) для "User-2"
Цитата:
Цитата amel27
CALL :SC_ENABLE SCHEDULE
CALL :SC_START SCHEDULE »
- это запуск программы при загрузке - а где наблюдение? - если в случае сбоя произойдЁт отключение SCHEDULE - потребуется его повторный запуск, а при невозможности ребут ОС !!!
поясни пожалуйста !!!
Спасибо!

amel27 04-02-2008 04:17 732348
Цитата:
Цитата SavmiN
а где наблюдение? »
команда запуска не пойдет дальше пока не запустит сервис, поэтому если сервис глюканет и не запустится скрипт зависнет в цикле... для перезагрузки нужно ставить условный выход из цикла по таймауту или количеству проверок

SavmiN 04-02-2008 18:46 732805
Цитата:
Цитата amel27
условный выход из цикла по таймауту или количеству проверок »
вот вот! то что и требовалось! - удели плиз несколько минут, если не сложно - подкоректировать с остановкой и ребутом ПК!
К примеру, если в течении минуты не запученна программа - то ПК перезагружается или отключается (во избежание самопроизвольного ребута)
Спасибо!

amel27 06-02-2008 09:42 734010
Цитата:
Цитата SavmiN
удели плиз несколько минут, если не сложно - подкоректировать с остановкой и ребутом ПК »
что-нибудь типа такого?
Код:
@echo off

Set TIMEOUT=10 Rem таймаут ожидания в секундах
Set MXCOUNT=6  Rem количество попыток запуска/остановки

Set TCOUNT=%MXCOUNT%

IF "%USERNAME%"=="User-1" (
        CALL :SC_STOP SCHEDULE
        CALL :SC_DISABLE SCHEDULE
        CALL :SC_RESTART BROWSER
)
IF "%USERNAME%"=="User-2" (
        CALL :SC_ENABLE SCHEDULE
        CALL :SC_START SCHEDULE
        CALL :SC_RESTART SPOOLER
)
EXIT

:SC_STOP
        CALL :EX_REBOOT %TCOUNT%
        Set TCOUNT=%MXCOUNT%
        Set STATUS=
        @echo Остановка сервиса "%1"...
:SC_STOP_LOOP
        Set /A TCOUNT-=1
        SC STOP %1 >nul
        CALL :EX_SLEEP %TIMEOUT%
        For /F "Tokens=3 Usebackq Delims=: " %%i in (`SC QUERY %1^|FIND "STATE"`) Do SET STATUS=%%i
        If "%STATUS%"=="STOPPED" GOTO :EOF
If %TCOUNT% GTR 0 GOTO :SC_STOP_LOOP

:SC_START
        CALL :EX_REBOOT %TCOUNT%
        Set TCOUNT=%MXCOUNT%
        Set STATUS=
        @echo Запуск сервиса "%1"...
:SC_START_LOOP
        Set /A TCOUNT-=1
        SC START %1 >nul
        CALL :EX_SLEEP %TIMEOUT%
        For /F "Tokens=3 Usebackq Delims=: " %%i in (`SC QUERY %1^|FIND "STATE"`) Do SET STATUS=%%i
        If "%STATUS%"=="RUNNING" GOTO :EOF
If %TCOUNT% GTR 0 GOTO :SC_START_LOOP

:SC_ENABLE
        CALL :EX_REBOOT %TCOUNT%
        SC CONFIG %1 start= demand >nul
        @echo Сервис %1 включен!
GOTO :EOF

:SC_DISABLE
        CALL :EX_REBOOT %TCOUNT%
        SC CONFIG %1 start= disabled >nul
        @echo Сервис %1 отключен!
GOTO :EOF

:SC_RESTART
        CALL :SC_STOP  %1
        CALL :SC_START %1
GOTO :EOF

:EX_SLEEP
        Ping -n %1 127.0.0.1 >nul
GOTO :EOF

:EX_REBOOT
        If %1 EQU 0 (
                Shutdown -r -f -t 10 -c "Превышен таймаут ожидания"
                EXIT
        )
GOTO :EOF

SavmiN 06-02-2008 12:42 734136
Цитата:
Цитата amel27
типа такого »
ну наверное - пойду пробовать - расскажу позже!

SavmiN 08-02-2008 14:24 735856
amel27, рассказываю
при старте ОС кратковременно появляется окошко cmd и усЁ %(
пробую отключать наблюдаемую службу - хм.. отключается и ничего не происходит - не востанавливается, сообщения никакого нет! ребута нет %(
подскажИте ?

amel27 09-02-2008 12:54 736501
Цитата:
Цитата SavmiN
при старте ОС кратковременно появляется окошко cmd и усЁ »
а ты чего хотел - чтобы скрипт крутился бесконечно?.. изначально вопрос стоял о запуске скрипта при загрузке, если тебе нужно перегружать сервис периодически - ставь скрипт в планировщик задач. Кстати, проверить REBOOT можно вбив имя несуществующего сервиса - эффект тот же, что и при потере связи с сервисом.

SavmiN 09-02-2008 18:34 736705
Цитата:
Цитата amel27
запуске скрипта при загрузке »
и наблюдении им за процессом pshell.exe
вот я и пытался его (pshell.exe) отключать - отключаю - но востановления не происходит! %(
Цитата:
Цитата amel27
проверить REBOOT можно вбив имя несуществующего сервиса »
- поясни! в смысле для "User-2" к примеру чтото типа
Цитата:
Цитата amel27
IF "%USERNAME%"=="User-2" (
CALL :SC_ENABLE SCHEDULE 123
CALL :SC_START SCHEDULE 123
CALL :SC_RESTART SPOOLER »
так чтоли ?

amel27 11-02-2008 12:01 737770
Цитата:
Цитата SavmiN
наблюдении им за процессом pshell.exe »
в чем заключается "наблюдение"?.. запустить если остановился?... или периодически перегружать чтобы убедиться что он не завис?.. и какой наконец у него ID (тот что из реестра), т.к. "pshell.exe" это имя образа

Цитата:
Цитата SavmiN
отключаю - но востановления не происходит! »
естественно, так как скрипт стоит в автологоне, т.е. отрабатывает однократно - при регистрации пользователя, для постоянной проверки нужно использовать планировщик задач
Цитата:
Цитата SavmiN
в смысле для "User-2" к примеру чтото типа »
SCHEDULE - ID службы планировщика задач
SPOOLER - ID службы диспетчера печати

:SC_DISABLE - отключить службу;
:SC_ENABLE - включить службу;
:SC_START - запустить службу;
:SC_STOP - остановить службу;
:SC_RESTART - SC_STOP+SC_START

SavmiN 11-02-2008 15:43 737928
Цитата:
Цитата amel27
ID (тот что из реестра »
В общем-то я так и не нашел отдельного ID на "pshell.exe"
Возможно причина в том что именно эта программа не запускается службой ?

Но и даже та программа, которая запускается как служба (в частности - имя службы "GccServ" - это и есть ID? ) не получает наблюдения и рестарта в случае отключения или сбоя во время работы ПК

Цитата:
Цитата amel27
наблюдение"?.. запустить если остановился?... »
или умышлено отключили процесс

Примерно так! Ппрограмма GC.exe управляет включением и остановкой(блокирует) ПК. Программа Pshell.exe - оболочка на ПК - ограничивает возможности пользователя и востанавливает GC.exe при перезапуске ОС - но не в процессе работы.
Тоесть - если отключить процесс pshell.exe то можно остановить процесс GC.exe и службу GCServ - и как следствие играться на ПК без ограничения времени. Вот и требуется наблюдение за процессами pshell.exe; gc.exe и службой GCServ и в случае их отключения или остановки - Вывести сообщение на экран "Чтото типа штраф 200 грн за умышленное отключение служб контроля" и снова их перезапустить или вырубить ПК.
Мда!! надо было сразу так обЪяснить Сорри!

amel27 12-02-2008 11:32 738425
Цитата:
Цитата SavmiN
надо было сразу так обЪяснить »
:yes:
Цитата:
Цитата SavmiN
"GccServ" - это и есть ID? »
мне отсюда не видно, проверь
Код:
NET STOP GccServ
NET START GccServ
Цитата:
Цитата SavmiN
требуется наблюдение за процессами pshell.exe; gc.exe и службой GCServ »
процессы под какой учеткой стартуют?.. смотри в диспетчере задач ("Имя пользователя")

SavmiN 12-02-2008 15:51 738630
В оболочке pshell.exe - есть возможность автологона с правами админа - загрузка происходит под учеткой User-2 (User-1 - это учетка Администратор); после подгружается программа gc.exe (учет времени и трафика) и служба GccServ этой же программы (лично мне не понятно для каких целей ) - и если я наберу "NET STOP GccServ" - то ничего не произойдет! а вот если я отключю к примеру процесс gc.exe - то при следующем входе в систему программа pshell.exe востановит этот gc.exe (имеется там опция) - а нужно чтобы восстанавливался gc.exe сразу или производился shutdown -s

HLT 13-02-2008 09:15 739133
Цитата:
Цитата SavmiN
если я отключю к примеру процесс gc.exe »
Цитата:
Цитата SavmiN
нужно чтобы восстанавливался gc.exe сразу »
Работающий метод:
назначить на каждом компе задание на запуск этого батника каждую минуту
Код:
pslist /accepteula gc -e
if errorlevel 1 start gc.exe
pslist брать тут: http://technet.microsoft.com/ru-ru/s...82(en-us).aspx

Если очень хочется - можно сделать задание, которое будет удаленно проверять статус службы и удаленно запускать её.
Батник запускается на сервере от админской учетной записи, проверяет статус службы на всех нужных компах
Список нужных компов находится в файле computers.lst

Код:
@for /F %%a in (computers.lst) do (
pslist /accepteula \\%%a gc -e
if errorlevel 1 psexec /accepteula \\%%a gc.exe -d -e -s
)
psexec брать там же, где и pslist

SavmiN 13-02-2008 17:31 739505
Цитата:
Цитата HLT
назначить на каждом компе задание »
В смысле назначить через планировщик ? а скрытого метода нет?
и как втаком случае наблюдать за службой GccServ - они одно целое с процессом gc.exe

SavmiN 30-03-2008 01:41 770749
Цитата:
Цитата HLT
сделать задание, которое будет удаленно проверять статус службы и удаленно запускать её »
сорри!!
имя компьютеров ? в каком виде - к примеру группа "Club" там 50 пк от Club-1 … до Club-50 - с такими именами и задавать?
или по ip-адресам? - не совсем ясно - та и не нашел по сайту инструкций чётких (
Спасибо!
и как я понимаю здесь
Цитата:
Цитата HLT
errorlevel 1 psexec »
единица - время в минутах

HLT 02-04-2008 14:08 773095
Цитата:
Цитата SavmiN
имя компьютеров ? в каком виде - к примеру группа "Club" там 50 пк от Club-1 … до Club-50 - с такими именами и задавать? »
Да. В файл, по одному имени в строке

Цитата:
Цитата SavmiN
как я понимаю здесь
Цитата:
Цитата HLT:
errorlevel 1 psexec »
единица - время в минутах »
единица - это код ошибки. Она появляется если предыдущей командой процесс не найден в списке процессов.

Описание команды IF - тут

SavmiN 03-04-2008 23:01 774100
Цитата:
Цитата HLT
по одному имени в строке »
по ip-адресам можно ?
Цитата:
Цитата HLT
процесс не найден в списке процессов »
не получится ли в таком случае загрузка сети - опрос 50 пк займет около 1 минуты
настроить время нового опроса как можно ? к примеру раз в три минуты

HLT 04-04-2008 09:40 774349
Цитата:
Цитата SavmiN
по ip-адресам можно »
В хелпе нет упора на computer name, сказано просто remote computer
Должно работать

Цитата:
Цитата SavmiN
не получится ли в таком случае загрузка сети - опрос 50 пк займет около 1 минуты »
Запуск батника производится из "планировщика заданий". Там и настраивать интервал. Хоть раз в минуту, хоть раз в сутки


Время: 11:26.

Время: 11:26.
© OSzone.net 2001-